Unexpected tokens

[just-ero]

Sorry for the non-descript title. I didn't know what else to go with.

I have the below grammars:

CSharp.g4

lexer grammar CSharp;

fragment DECIMAL_DIGIT
  : [0-9]
  ;

fragment HEXADECIMAL_DIGIT
  : [a-fA-F]
  | DECIMAL_DIGIT
  ;

HexadecimalIntegerLiteralToken
  : ('0x' | '0X') HEXADECIMAL_DIGIT+
  ;

fragment SIMPLE_ESCAPE_SEQUENCE
  : '\\' [0abfnrtv'"\\]
  ;

fragment HEXADECIMAL_ESCAPE_SEQUENCE
  : '\\x' HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT? HEXADECIMAL_DIGIT? HEXADECIMAL_DIGIT?
  ;

fragment UNICODE_ESCAPE_SEQUENCE
  : '\\u' HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT
  | '\\U' HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT HEXADECIMAL_DIGIT
  ;

fragment SINGLE_CHARACTER
  : ~['\\\u000D\u000A\u0085\u2028\u2029]
  ;

fragment REGULAR_STRING_LITERAL_CHARACTER
  : HEXADECIMAL_ESCAPE_SEQUENCE
  | SIMPLE_ESCAPE_SEQUENCE
  | UNICODE_ESCAPE_SEQUENCE
  | SINGLE_CHARACTER
  ;

RegularStringLiteralToken
  : '"' REGULAR_STRING_LITERAL_CHARACTER* '"'
  ;

fragment VERBATIM_STRING_LITERAL_CHARACTER
  : '""'
  | ~('"')
  ;

VerbatimStringLiteralToken
  : '@"' VERBATIM_STRING_LITERAL_CHARACTER* '"'
  ;

StringLiteralToken
  : RegularStringLiteralToken
  | VerbatimStringLiteralToken
  ;

fragment COMBINING_CHARACTER
  : [\p{Mn}\p{Mc}]
  | UNICODE_ESCAPE_SEQUENCE
  ;

fragment CONNECTING_CHARACTER
  : [\p{Pc}]
  | UNICODE_ESCAPE_SEQUENCE
  ;

fragment DECIMAL_DIGIT_CHARACTER
  : [\p{Nd}]
  | UNICODE_ESCAPE_SEQUENCE
  ;

fragment FORMATTING_CHARACTER
  : [\p{Cf}]
  | UNICODE_ESCAPE_SEQUENCE
  ;

fragment LETTER_CHARACTER
  : [\p{L}\p{Nl}]
  | UNICODE_ESCAPE_SEQUENCE
  ;

fragment IDENTIFIER_START_CHARACTER
  : LETTER_CHARACTER
  | '_'
  ;

fragment IDENTIFIER_PART_CHARACTER
  : COMBINING_CHARACTER
  | CONNECTING_CHARACTER
  | DECIMAL_DIGIT_CHARACTER
  | FORMATTING_CHARACTER
  | LETTER_CHARACTER
  ;

IdentifierToken
  : '@'? IDENTIFIER_START_CHARACTER IDENTIFIER_PART_CHARACTER*
  ;

Asl.g4

grammar Asl;

import CSharp;

WS : [ \t\r\n\u000C\u00A0]+ -> skip ;

StateTypeToken
  : 'sbyte'
  | 'byte'
  | 'bool'
  | 'short'
  | 'ushort'
  | 'char'
  | 'int'
  | 'uint'
  | 'long'
  | 'ulong'
  | 'float'
  | 'double'
  | 'decimal'
  | 'byte' DECIMAL_DIGIT+
  | 'string' DECIMAL_DIGIT+
  ;

// Parser rules
state_variable
  : StateTypeToken IdentifierToken ':' (StringLiteralToken ',')? HexadecimalIntegerLiteralToken (',' HexadecimalIntegerLiteralToken)*
  ;

state_content
  : (state_variable ';')* state_variable ';'?
  ;

state
  : 'state' '(' StringLiteralToken (',' StringLiteralToken)? ')' '{' state_content? '}'
  ;

When debugging the Asl.g4 grammar on this input:

state("Foo")
{
    int x : 0x0;
}

I end up with this output:

Parser error (1, 7): mismatched input '"Foo"' expecting StringLiteralToken
<unknown>:1
Tokens:
[@0,0:4='state',<'state'>,1:0]
[@1,5:5='(',<'('>,1:5]
[@2,6:10='"Foo"',<RegularStringLiteralToken>,1:6]
[@3,11:11=')',<')'>,1:11]
[@4,14:14='{',<'{'>,2:0]
[@5,21:23='int',<StateTypeToken>,3:4]
[@6,25:25='x',<IdentifierToken>,3:8]
[@7,27:27=':',<':'>,3:10]
[@8,29:31='0x0',<HexadecimalIntegerLiteralToken>,3:12]
[@9,32:32=';',<';'>,3:15]
[@10,35:35='}',<'}'>,4:0]
[@11,38:37='<EOF>',<EOF>,5:0]

Parse Tree:
state (
 "state"
 "("
  <Error>""Foo""
  <Error>")"
  <Error>"{"
  <Error>"int"
  <Error>"x"
  <Error>":"
  <Error>"0x0"
  <Error>";"
  <Error>"}"
)

What am I doing wrong?

[The-Futurist]

StringLiteralToken

Your parser says it expects a StringLiteralToken but as the token log shows, a RegularStringLiteralToken is what the lexer produced.