cronboard/flake.nix at main · antoniorodr/cronboard · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
{
  description = "A terminal-based dashboard for managing cron jobs";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        python = pkgs.python313;

        textual-autocomplete = python.pkgs.buildPythonPackage {
          pname = "textual-autocomplete";
          version = "4.0.6";
          pyproject = true;

          src = pkgs.fetchPypi {
            pname = "textual_autocomplete";
            version = "4.0.6";
            hash = "sha256-K6Lw12e+RIDsrLPksTDPBzQOAzw1APxCT+2RJdJ6RYY=";
          };

          build-system = [ python.pkgs.hatchling ];
          dependencies = with python.pkgs; [
            textual
            typing-extensions
          ];

          meta = with pkgs.lib; {
            description = "Autocomplete component for Textual TUI apps";
            homepage = "https://github.com/darrenburns/textual-autocomplete";
            license = licenses.mit;
          };
        };

        cronboard = python.pkgs.buildPythonApplication {
          pname = "cronboard";
          version = builtins.elemAt (builtins.match ".*version = \"([^\"]+)\".*" (builtins.readFile ./pyproject.toml)) 0;
          pyproject = true;

          src = ./.;

          build-system = [ python.pkgs.setuptools ];

          dependencies = with python.pkgs; [
            bcrypt
            cron-descriptor
            croniter
            paramiko
            python-crontab
            textual
            tomlkit
            textual-autocomplete
          ];

          meta = with pkgs.lib; {
            description = "A terminal-based dashboard for managing cron jobs";
            homepage = "https://github.com/antoniorodr/cronboard";
            license = licenses.mit;
            mainProgram = "cronboard";
            platforms = platforms.unix;
            maintainers = [ ];
          };
        };
      in
      {
        packages = {
          default = cronboard;
          inherit
            cronboard
            textual-autocomplete
            ;
        };

        apps.default = {
          type = "app";
          program = "${cronboard}/bin/cronboard";
        };

        devShells.default = pkgs.mkShell {
          packages = [
            (python.withPackages (
              ps:
              with ps;
              [
                bcrypt
                cron-descriptor
                croniter
                paramiko
                python-crontab
                textual
                tomlkit
                pytest
                pytest-cov
                pytest-mock
                pytest-asyncio
                textual-dev
              ]
              ++ [
                cron-descriptor
                textual-autocomplete
              ]
            ))
          ];
        };
      }
    );
}