build.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */

plugins {
    id 'java-test-fixtures'
    id 'org.apache.grails.buildsrc.properties'
    id 'org.apache.grails.buildsrc.dependency-validator'
    id 'org.apache.grails.gradle.grails-plugin'
    id 'org.apache.grails.buildsrc.compile'
    id 'org.apache.grails.buildsrc.publish'
    id 'org.apache.grails.buildsrc.sbom'
    id 'org.apache.grails.gradle.grails-code-style'
    id 'org.apache.grails.gradle.grails-jacoco'
}

version = projectVersion
group = 'org.apache.grails'

ext {
    gormApiDocs = true
    pomTitle = 'GORM for MongoDB'
    pomDescription = 'Provides a GORM Object Mapping implementations for the MongoDB Document Database'
}

dependencies {

    implementation platform(project(':grails-bom'))
    testFixturesImplementation platform(project(':grails-bom'))

    api project(':grails-data-mongodb-core'), {
        // api: needed as classes should also be available when compiling apps. eg. MongoEntity
        // impl: MongoDatastore, MongoDbDataStoreSpringInitializer
        if (excludeUnusedTransDeps) {
            // API dependencies in grails-data-mongodb
            //exclude group: 'org.apache.grails.data', module: 'grails-data-mongodb-bson' // Needed at runtime downstream (BsonPersistentEntityCodec)
            exclude group: 'org.apache.grails.data', module: 'grails-datastore-core'
            exclude group: 'org.apache.grails.data', module: 'grails-datamapping-core'
            exclude group: 'org.apache.grails.data', module: 'grails-datamapping-support'
            //exclude group: 'org.mongodb', module: 'bson' // Needed downstream for compiling MongoEntity
            //exclude group: 'org.mongodb', module: 'mongodb-driver-core' // MongoClientSettings
            //exclude group: 'org.mongodb', module: 'mongodb-driver-sync' // MongoClient
            exclude group: 'org.springframework', module: 'spring-context'
        }
    }

    implementation project(':grails-datamapping-support'), {
        // impl: ConfigSupport
        if (excludeUnusedTransDeps) {
            // API dependencies in grails-datamapping-support
            exclude group: 'org.apache.grails.data', module: 'grails-datastore-core'
            //exclude group: 'org.apache.grails.data, module: 'grails-datamapping-core' // AbstractDatastorePersistenceContextInterceptor
            exclude group: 'org.apache.grails', module: 'grails-core'
            exclude group: 'org.springframework', module: 'spring-context'
            exclude group: 'org.springframework', module: 'spring-core'
        }
    }
    implementation 'org.springframework:spring-beans', {
        // impl: BeanDefinitionRegistry
    }
    implementation 'org.springframework:spring-context', {
        // impl: ConfigurableApplicationContext
    }
    implementation 'org.springframework:spring-core', {
        // impl: PropertyResolver
    }
    implementation 'org.springframework:spring-tx', {
        // impl: PlatformTransactionManager
    }

    compileOnly 'org.apache.groovy:groovy' // Provided as this is a Grails plugin
    compileOnly project(':grails-core'), { // Provided as this is a Grails plugin
        // api: GrailsPlugin
        // impl: DomainClassArtefactHandler, GrailsClass, GrailsPlugin, Metadata
    }

    runtimeOnly project(':grails-data-mongodb-ext'), {
        // Include MongoDB groovy extensions for applications
    }

    testFixturesApi project(':grails-core'), {
        // api: Config
        // impl: PropertySourcesConfig
    }
    testFixturesApi project(':grails-data-mongodb-core'), {
        // api: MongoDatastore
    }
    testFixturesApi 'org.mongodb:mongodb-driver-sync', {
        // api: MongoClient
    }

    testFixturesImplementation 'org.springframework:spring-core', {
        // impl: PropertyResolver
    }
    testFixturesImplementation 'org.springframework.boot:spring-boot', {
        // impl: PropertySourceLoader
    }
    testFixturesImplementation 'org.spockframework:spock-core'

    testFixturesCompileOnly 'org.apache.groovy:groovy'
}

def disabledTasks = ['bootRun', 'bootTestRun']
disabledTasks.each { taskName ->
    tasks.named(taskName) {
        enabled = false
    }
}

tasks.named('groovydoc') {
    source += sourceSets.testFixtures.allSource
}

apply {
    from rootProject.layout.projectDirectory.file('gradle/mongodb-test-config.gradle')
    from rootProject.layout.projectDirectory.file('gradle/docs-config.gradle')
    from rootProject.layout.projectDirectory.file('gradle/grails-extension-gradle-config.gradle')
}