Split formatting tasks into separate plugin

Author: sanjana2505006

build-logic/plugins/build.gradle

@@ -62,6 +62,10 @@ gradlePlugin {
             id = 'org.apache.grails.gradle.grails-code-style'
             implementationClass = 'org.apache.grails.buildsrc.GrailsCodeStylePlugin'
         }
+        register('grailsFormat') {
+            id = 'org.apache.grails.gradle.grails-format'
+            implementationClass = 'org.apache.grails.buildsrc.GrailsFormatPlugin'
+        }
         register('groovydocEnhancer') {
             id = 'org.apache.grails.buildsrc.groovydoc-enhancer'
             implementationClass = 'org.apache.grails.buildsrc.GroovydocEnhancerPlugin'

build-logic/plugins/src/main/groovy/org/apache/grails/buildsrc/GrailsCodeStylePlugin.groovy

@@ -25,16 +25,12 @@ import groovy.transform.CompileStatic
 
 import org.gradle.api.Plugin
 import org.gradle.api.Project
-import org.gradle.api.file.Directory
 import org.gradle.api.plugins.quality.Checkstyle
 import org.gradle.api.plugins.quality.CheckstyleExtension
 import org.gradle.api.plugins.quality.CheckstylePlugin
 import org.gradle.api.plugins.quality.CodeNarc
 import org.gradle.api.plugins.quality.CodeNarcExtension
 import org.gradle.api.plugins.quality.CodeNarcPlugin
-import org.gradle.api.tasks.Copy
-import org.gradle.process.ExecSpec
-import org.apache.tools.ant.taskdefs.condition.Os
 
 @CompileStatic
 class GrailsCodeStylePlugin implements Plugin<Project> {
@@ -52,18 +48,11 @@ class GrailsCodeStylePlugin implements Plugin<Project> {
     void apply(Project project) {
         initExtension(project)
         configureCodeStyle(project)
-        registerFormattingTasks(project)
-        doNotApplyStylingToTests(project)
     }
 
     private static void initExtension(Project project) {
         def gce = project.extensions.create('grailsCodeStyle', GrailsCodeStyleExtension)
 
-        // Unfortunately, the codenarc plugin is still using a non-lazy property.
-        // Rather than rewrite the plugin to use afterEvaluate,
-        // this plugin uses properties to override the configuration location by default
-
-
         gce.checkstyleDirectory.set(project.provider {
             def directory = project.hasProperty(CHECKSTYLE_DIR_PROPERTY) ?
                     project.rootProject.layout.projectDirectory.dir(project.property(CHECKSTYLE_DIR_PROPERTY) as String) :
@@ -111,25 +100,6 @@ class GrailsCodeStylePlugin implements Plugin<Project> {
         }
     }
 
-    private static void doNotApplyStylingToTests(Project project) {
-        if (project.tasks.names.contains('checkstyleTest')) {
-            project.tasks.named('checkstyleTest') {
-                it.enabled = false // Do not check test sources at this time
-            }
-        }
-
-        project.afterEvaluate {
-            // Do not check test sources at this time
-            ['codenarcIntegrationTest', 'codenarcTest'].each { testTaskName ->
-                if (project.tasks.names.contains(testTaskName)) {
-                    project.tasks.named(testTaskName) {
-                        it.enabled = false
-                    }
-                }
-            }
-        }
-    }
-
     private static void configureCodeStyle(Project project) {
         configureCheckstyle(project)
         configureCodenarc(project)
@@ -197,88 +167,4 @@ class GrailsCodeStylePlugin implements Plugin<Project> {
             )
         }
     }
-
-    private static void registerFormattingTasks(Project project) {
-        if (project == project.rootProject) {
-            project.tasks.register('installGitHooks', Copy) {
-                it.group = 'verification'
-                it.description = 'Installs the git pre-commit hook for automatic code formatting'
-                it.from(project.rootProject.layout.projectDirectory.file('etc/hooks/pre-commit'))
-                it.into(project.rootProject.layout.projectDirectory.dir('.git/hooks'))
-                it.fileMode = 0755
-            }
-        }
-
-        project.tasks.register('formatCode') {
-            it.group = 'verification'
-            it.description = 'Formats Java and Groovy source files using the IntelliJ command line formatter'
-
-            it.doLast {
-                String ideaHome = (project.findProperty('idea.home') ?: System.getenv('IDEA_HOME')) as String
-                String executable = Os.isFamily(Os.FAMILY_WINDOWS) ? 'format.bat' : 'format.sh'
-                File formatExec = null
-
-                if (ideaHome) {
-                    formatExec = new File(ideaHome, "bin/$executable")
-                } else {
-                    // Try common paths on macOS
-                    if (Os.isFamily(Os.FAMILY_MAC)) {
-                        def commonPaths = [
-                                "/Applications/IntelliJ IDEA.app/Contents/bin/$executable",
-                                "/Applications/IntelliJ IDEA CE.app/Contents/bin/$executable"
-                        ]
-                        for (path in commonPaths) {
-                            File f = new File(path)
-                            if (f.exists()) {
-                                formatExec = f
-                                break
-                            }
-                        }
-                    }
-
-                    if (formatExec == null && !Os.isFamily(Os.FAMILY_WINDOWS)) {
-                        // On Linux/Mac, try to find 'idea' in PATH
-                        try {
-                            def out = new ByteArrayOutputStream()
-                            project.exec { ExecSpec exec ->
-                                exec.commandLine 'which', 'idea'
-                                exec.standardOutput = out
-                                exec.ignoreExitValue = true
-                            }
-                            def path = out.toString().trim()
-                            if (path) {
-                                formatExec = new File(new File(path).parentFile, executable)
-                            }
-                        } catch (Exception ignored) { }
-                    }
-                }
-
-                if (formatExec == null || !formatExec.exists()) {
-                    project.logger.error("IntelliJ formatter executable not found.")
-                    project.logger.error("Please set 'idea.home' property or IDEA_HOME environment variable to your IntelliJ installation directory.")
-                    project.logger.error("Example: ./gradlew formatCode -Pidea.home=/Applications/IntelliJ\\ IDEA.app/Contents")
-                    throw new RuntimeException("IntelliJ formatter executable not found.")
-                }
-
-                def filesToFormat = project.findProperty('formatFiles')
-                def settingsFile = project.rootProject.file('.idea/codeStyles/Project.xml')
-
-                if (!settingsFile.exists()) {
-                    throw new RuntimeException("IntelliJ code style settings not found at ${settingsFile.absolutePath}")
-                }
-
-                project.exec { ExecSpec exec ->
-                    exec.commandLine formatExec.absolutePath
-                    exec.args '-s', settingsFile.absolutePath
-                    exec.args '-mask', '*.java,*.groovy'
-                    exec.args '-r'
-                    if (filesToFormat) {
-                        exec.args((filesToFormat.toString()).split(','))
-                    } else {
-                        exec.args project.projectDir.absolutePath
-                    }
-                }
-            }
-        }
-    }
 }

build-logic/plugins/src/main/groovy/org/apache/grails/buildsrc/GrailsFormatPlugin.groovy

@@ -0,0 +1,98 @@
+/*
+ *  Licensed to the Apache Software Foundation (ASF) under one
+ *  or more contributor license agreements.  See the NOTICE file
+ *  distributed with this work for additional information
+ *  regarding copyright ownership.  The ASF licenses this file
+ *  to you under the Apache License, Version 2.0 (the
+ *  "License"); you may not use this file except in compliance
+ *  with the License.  You may obtain a copy of the License at
+ *
+ *    https://www.apache.org/licenses/LICENSE-2.0
+ *
+ *  Unless required by applicable law or agreed to in writing,
+ *  software distributed under the License is distributed on an
+ *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+ *  KIND, either express or implied.  See the License for the
+ *  specific language governing permissions and limitations
+ *  under the License.
+ */
+package org.apache.grails.buildsrc
+
+import groovy.transform.CompileStatic
+import org.gradle.api.Plugin
+import org.gradle.api.Project
+import org.gradle.api.tasks.Copy
+import org.gradle.process.ExecSpec
+import org.gradle.process.ExecOperations
+import javax.inject.Inject
+import org.apache.tools.ant.taskdefs.condition.Os
+
+@CompileStatic
+class GrailsFormatPlugin implements Plugin<Project> {
+
+    @Override
+    void apply(Project project) {
+        registerFormattingTasks(project)
+    }
+
+    private static void registerFormattingTasks(Project project) {
+        if (project == project.rootProject) {
+            project.tasks.register('installGitHooks', Copy) {
+                it.group = 'verification'
+                it.description = 'Installs the git pre-commit hook for automatic code formatting'
+                it.from(project.rootProject.layout.projectDirectory.file('etc/hooks/pre-commit'))
+                it.into(project.rootProject.layout.projectDirectory.dir('.git/hooks'))
+                it.fileMode = 0755
+            }
+        }
+
+        ExecOperationsSupport execSupport = project.objects.newInstance(ExecOperationsSupport)
+        def ideaExecProvider = project.providers.gradleProperty('idea.exec')
+                .orElse(Os.isFamily(Os.FAMILY_WINDOWS) ? 'format.bat' : 'idea')
+        def formatFilesProvider = project.providers.gradleProperty('formatFiles')
+        def rootProjectDir = project.rootProject.projectDir
+        def projectDir = project.projectDir
+
+        project.tasks.register('formatCode') { task ->
+            task.group = 'verification'
+            task.description = 'Formats Java and Groovy source files using the IntelliJ command line formatter'
+
+            task.doLast {
+                String ideaExec = ideaExecProvider.get()
+                def filesToFormat = formatFilesProvider.getOrNull()
+                def settingsFile = new File(rootProjectDir, '.idea/codeStyles/Project.xml')
+
+                if (!settingsFile.exists()) {
+                    throw new RuntimeException("IntelliJ code style settings not found at ${settingsFile.absolutePath}")
+                }
+
+                try {
+                    execSupport.execOperations.exec { ExecSpec exec ->
+                        exec.commandLine ideaExec
+                        if (ideaExec == 'idea') {
+                            exec.args 'format'
+                        }
+                        exec.args '-s', settingsFile.absolutePath
+                        exec.args '-mask', '*.java,*.groovy'
+                        exec.args '-r'
+                        if (filesToFormat) {
+                            exec.args((filesToFormat.toString()).split(','))
+                        } else {
+                            exec.args projectDir.absolutePath
+                        }
+                    }
+                } catch (Exception e) {
+                    task.logger.error("IntelliJ formatter failed to execute.")
+                    task.logger.error("Please ensure IntelliJ command line tools are installed and available on your PATH.")
+                    task.logger.error("See: https://www.jetbrains.com/help/idea/working-with-the-ide-features-from-command-line.html")
+                    throw new RuntimeException("IntelliJ formatter failed. See logs for details.", e)
+                }
+            }
+        }
+    }
+}
+
+interface ExecOperationsSupport {
+    @Inject
+    ExecOperations getExecOperations()
+}

build.gradle

@@ -16,7 +16,7 @@
  */
 
 plugins {
-    id 'org.apache.grails.gradle.grails-code-style'
+    id 'org.apache.grails.gradle.grails-format'
 }
 
 import java.time.Instant
@@ -31,10 +31,9 @@ import org.apache.tools.ant.taskdefs.condition.Os
 ext {
     isReproducibleBuild = System.getenv("SOURCE_DATE_EPOCH") != null
     buildInstant = java.util.Optional.ofNullable(System.getenv("SOURCE_DATE_EPOCH"))
-            .filter { s -> !s.isEmpty() }
-            .map { s -> Long.parseLong(s as String) }
-            .map { l -> Instant.ofEpochSecond(l as Long) }
-            .orElseGet { Instant.now() }
+            .map(Long::parseLong)
+            .map(Instant::ofEpochSecond)
+            .orElseGet(Instant::now)
     formattedBuildDate = System.getenv("SOURCE_DATE_EPOCH") ?
             DateTimeFormatter.ISO_INSTANT.format(buildInstant) :
             DateTimeFormatter.ISO_DATE.format(LocalDate.ofInstant(buildInstant as Instant, ZoneOffset.UTC))