[Bug]: iOS app crashing on ref.current.startStreaming on RN > 0.80.0 and fabric=true

[trickyc0d3r]

Version

v2.0.2

Which operating systems have you used?

• Android
• iOS

Environment that reproduces the issue

iPhone 12 Pro, iPhone 13 pro, iPhone 16 Pro Max

Is it reproducible in the example application?

Yes

RTMP Server

any server dosent matter

Reproduction steps

Run app. On screen where <ApiVideoLiveStreamView style={ss.stream} ref={props.stream_ref} camera="front" enablePinchedZoom={true} video={{ fps: 24, resolution: '720p', // Alternatively, you can specify the resolution in pixels: { width: 1280, height: 720 } bitrate: .5 * 1024 * 1024, // # 2 Mbps gopDuration: 1, // 1 second }} audio={{ bitrate: 128000, sampleRate: 44100, isStereo: true, }} isMuted={false} onConnectionSuccess={(data: any, err: any) => { console.log('connection success', { data, err }); //do what you want }} onConnectionFailed={(err: any) => console.log('CONNECTION FAILURE ', err) } onDisconnect={() => { console.log('disconnect'); //do what you want }} onStartStreaming={(data: any, err: any) => { console.log('start streaming', { data, err }); }} /> is visible - there is camera frame with stuck frame. On acting stream_ref.current.startStreaming - app crashing

Expected result

app works fine

Actual result

2025-07-22_21-04-01.4244_+0200-0e8f3cb1d85a6c3c1f596c2a41d4c2626387883e.txt

Additional context

No response

Relevant logs output

[trickyc0d3r]

@BlueBazze @Titozzz any ideas how pass thru this?

[trickyc0d3r]

UPdate. Even example app crashes on ios if react-native newArchEnabled=true ( not works on RN >0.79

[trickyc0d3r]

Problem in audio I guess. in HisinKit

[shubham-testlify]

I am also getting the same issue

[milindsakhare100]

I am also getting the same issue

[trickyc0d3r]

UP @robwalkerco can you help please?

[trickyc0d3r]

Пиздец

[nikitapilgrim]

same pizdec

[k-lpmg]

@trickyc0d3r

The solution in the link is working.

• [Bug]: 'react_native_livestream-Swift.h' file not found. Please add new React Native 0.78.1 support  #100 (comment)

I'll also attach the complete code implementation.

• ios/RNLiveStreamView.mm

// This guard prevent the code from being compiled in the old architecture
#ifdef RCT_NEW_ARCH_ENABLED
#import "RNLiveStreamView.h"

#import <react/renderer/components/ApiVideoLiveStreamView/ComponentDescriptors.h>
#import <react/renderer/components/ApiVideoLiveStreamView/EventEmitters.h>
#import <react/renderer/components/ApiVideoLiveStreamView/Props.h>
#import <react/renderer/components/ApiVideoLiveStreamView/RCTComponentViewHelpers.h>

#import <React/RCTAssert.h>
#import <React/RCTConversions.h>
#import <React/RCTFabricComponentsPlugins.h>


// MARK: Swift classes in ObjC++
#if __has_include(<react_native_livestream/react_native_livestream-Swift.h>)
#import <react_native_livestream/react_native_livestream-Swift.h>
#else
#import "react_native_livestream-Swift.h"
#endif

using namespace facebook::react;

@class RNLiveStreamViewImpl;

@interface RNLiveStreamView () <RCTApiVideoLiveStreamViewViewProtocol>

@end

// MARK: Implementation

@implementation RNLiveStreamView {
    RNLiveStreamViewImpl * _view;
}

// MARK: Initializers

- (instancetype)initWithFrame:(CGRect)frame
{
    self = [super initWithFrame:frame];
    if (self) {
        static const auto defaultProps = std::make_shared<const ApiVideoLiveStreamViewProps>();
        _props = defaultProps;

        _view = [[RNLiveStreamViewImpl alloc] init];
        
        _view.onConnectionSuccess = [self](NSDictionary *dictionary) {
            if (_eventEmitter) {
                ApiVideoLiveStreamViewEventEmitter::OnConnectionSuccess data = {};
                std::static_pointer_cast<const ApiVideoLiveStreamViewEventEmitter>(_eventEmitter)->onConnectionSuccess(data);
            }
        };
        _view.onConnectionFailed = [self](NSDictionary *dictionary) {
            if (_eventEmitter) {
                ApiVideoLiveStreamViewEventEmitter::OnConnectionFailed data = {
                    .code = std::string([[dictionary valueForKey:@"code"] UTF8String]),
                };
                std::static_pointer_cast<const ApiVideoLiveStreamViewEventEmitter>(_eventEmitter)->onConnectionFailed(data);
            }
        };
        _view.onDisconnect = [self](NSDictionary *dictionary) {
            if (_eventEmitter) {
                ApiVideoLiveStreamViewEventEmitter::OnDisconnect data = {};
                std::static_pointer_cast<const ApiVideoLiveStreamViewEventEmitter>(_eventEmitter)->onDisconnect(data);
            }
        };
        
        _view.onStartStreaming = [self](NSDictionary *dictionary) {
            if (_eventEmitter) {
                NSString *error = [dictionary valueForKey:@"error"];
                std::string stdError;
                if (error != nil) {
                    stdError = std::string([error UTF8String]);
                }
                ApiVideoLiveStreamViewEventEmitter::OnStartStreaming data = {
                    .requestId = [[dictionary valueForKey:@"requestId"] intValue],
                    .result = static_cast<bool>([[dictionary valueForKey:@"result"] boolValue]),
                    .error = stdError,
                };
                std::static_pointer_cast<const ApiVideoLiveStreamViewEventEmitter>(_eventEmitter)->onStartStreaming(data);
            }
        };
        
        self.contentView = _view;
   }
   return self;
}

// MARK: Props
- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
{
    const auto &oldViewProps = *std::static_pointer_cast<const ApiVideoLiveStreamViewProps>(_props);
    const auto &newViewProps = *std::static_pointer_cast<const ApiVideoLiveStreamViewProps>(props);

    RNLiveStreamViewImpl *view = (RNLiveStreamViewImpl *)self.contentView;
    
    NSString *newCamera = RCTNSStringFromStringNilIfEmpty(toString(newViewProps.camera));
    if (oldViewProps.camera != newViewProps.camera) {
        [view setCamera:newCamera];
    } else if (view.camera != newCamera) {
        [view setCamera:newCamera];
    }

    NSDictionary *newResolution = @{ @"width" : @(newViewProps.video.resolution.width), @"height" : @(newViewProps.video.resolution.height) };
    NSDictionary *newVideoConfig = @{ @"bitrate" : @(newViewProps.video.bitrate), @"resolution" : newResolution, @"fps" : @(newViewProps.video.fps), @"gopDuration" : @(newViewProps.video.gopDuration)};
    if ((oldViewProps.video.bitrate != newViewProps.video.bitrate) || (oldViewProps.video.fps != newViewProps.video.fps) || (oldViewProps.video.resolution.width != newViewProps.video.resolution.width) || (oldViewProps.video.resolution.height != newViewProps.video.resolution.height) || (oldViewProps.video.gopDuration != newViewProps.video.gopDuration)) {
        [view setVideo:newVideoConfig];
    } else if (view.video != newVideoConfig) {
        [view setVideo:newVideoConfig];
    }
    
    if (oldViewProps.isMuted != newViewProps.isMuted) {
        [view setIsMuted:newViewProps.isMuted];
    } else if (view.isMuted != newViewProps.isMuted) {
        [view setIsMuted:newViewProps.isMuted];
    }
    
    NSString *sampleRate = RCTNSStringFromStringNilIfEmpty(toString(newViewProps.audio.sampleRate));
    NSDictionary *newAudioConfig = @{ @"bitrate" : @(newViewProps.audio.bitrate), @"sampleRate" : @([sampleRate intValue]), @"isStereo" : @(newViewProps.audio.isStereo)};
    if ((oldViewProps.audio.bitrate != newViewProps.audio.bitrate) || (oldViewProps.audio.sampleRate != newViewProps.audio.sampleRate) || (oldViewProps.audio.isStereo != newViewProps.audio.isStereo)) {
        [view setAudio:newAudioConfig];
    } else if (view.audio != newAudioConfig) {
        [view setAudio:newAudioConfig];
    }
    
    if (oldViewProps.zoomRatio != newViewProps.zoomRatio) {
        [view setZoomRatio:newViewProps.zoomRatio];
    } else if (view.zoomRatio != newViewProps.zoomRatio) {
        [view setZoomRatio:newViewProps.zoomRatio];
    }
    
    if (oldViewProps.enablePinchedZoom != newViewProps.enablePinchedZoom) {
        [view setEnablePinchedZoom:newViewProps.enablePinchedZoom];
    } else if (view.enablePinchedZoom != newViewProps.enablePinchedZoom) {
        [view setEnablePinchedZoom:newViewProps.enablePinchedZoom];
    }
    
    [super updateProps:props oldProps:oldProps];
}

- (void)handleCommand:(nonnull const NSString *)commandName args:(nonnull const NSArray *)args {
    RCTApiVideoLiveStreamViewHandleCommand(self, commandName, args);
}

// MARK: RCTComponentViewProtocol

- (void)startStreaming:(NSInteger)requestId streamKey:(NSString *)streamKey url:(NSString *)url
{
    [_view startStreamingWithRequestId:requestId streamKey:streamKey url:url];
}

- (void)stopStreaming
{
    [_view stopStreaming];
}

- (void)setZoomRatioCommand:(float)zoomRatio
{
    [_view setZoomRatioWithZoomRatio:zoomRatio];
}

+ (ComponentDescriptorProvider)componentDescriptorProvider
{
    return concreteComponentDescriptorProvider<ApiVideoLiveStreamViewComponentDescriptor>();
}

@end

Class<RCTComponentViewProtocol> ApiVideoLiveStreamViewCls(void)
{
    return RNLiveStreamView.class;
}

#endif

[BlueBazze]

@BlueBazze @Titozzz any ideas how pass thru this?

Havent touched RN or mobile in years. Sorry.
Looks like a solution has been found.

Great job on the PR.