How to overwrite with default value from outside a class

[dkyanakiev]

Hi everyone.

I'm experimenting with Pkl hoping to use it to generate some of our Prometheus alerts since we have a lot of copy paste happening.

My idea is to bundle my alerts into modules and just amend them where change needs to happen (for example a different env)

I'm experimenting a lot but general idea is like this

// alerts: Listing<Alert>
class Alerts {
  name: String
  rules: Listing<SingleAlert>

  hidden def_chan: String
}

class SingleAlert {
  name: String?
  expr: String?
  `for`: String?
  
  annotations = new Mapping { 
    ["channel"] = "#chanel #tmp-channel"
    ["users"] = "@me"
  }

  labels = new Mapping {}
  // default_channel: String
  
}

groups =  new Alerts{
  rules = new SingleAlert{
  }
}

And I have another file alerts.pkl obviously that calls it

amends "basealert.pkl"
groups {
    name = "test"
    def_chan = "#ha"
    rules = new {
        new SingleAlert {
            name = "first-test-alert"
            expr = "if > 0"
            `for` = "5m"
            annotations {
                ["alert_msg"] = "this alert is firing"
            }
            labels {
                ["team"] = "team-alfa"
                ["severity"] = "warning"
            }
        }   
    }
}

What I am trying to do is set defaults for various things but lets say for the annotations channel and users

I want those to be global inside my alerts.pkl and unless specifieded inside the alerts and overwriting it, to use the global default..
So far I still cant figure it out - I tried to open the class, expand it.. use constants but cant exactly achieve when I want and it seems like It should be a simple use case. Anyone who can help?

[odenix]

I think this is how it's done in Pkl. The main trick is to leverage Listing.default by setting rules.default in basealerts.pkl and using new { instead of new SingleAlert { in alerts.pkl:

channelDefault: String = "#chanel #tmp-channel"

usersDefault: String = "@me"

groups: Alerts = new {
  rules {
    default {
      annotations {
        ["channel"] = channelDefault
        ["users"] = usersDefault
      }
    }
  }
}

class Alerts {
  name: String
  rules: Listing<SingleAlert>
}

class SingleAlert {
  name: String?
  expr: String?
  `for`: String?
  
  annotations: Mapping<String, String>
  labels: Mapping<String, String>
}

amends "basealert.pkl"
groups {
  name = "test"
  rules {
    new {
      name = "first-test-alert"
      expr = "if > 0"
      `for` = "5m"
      annotations {
        ["alert_msg"] = "this alert is firing"
      }
      labels {
        ["team"] = "team-alfa"
        ["severity"] = "warning"
      }
    }   
  }
}

[dkyanakiev]

Holy cow, this actually works. Thanks a lot.

I actually tried almost the same thing but the part I never got properly is actually the way you have the defaults in your example

channelDefault: String = "#chanel #tmp-channel"
usersDefault: String = "@me"

I tried so many random things but never managed to make the defaults to overwrite them...
Thanks a bunch!