Format Integer type as hexadecimal value with output converter

[fleckerbr]

I am currently using Pkl to define hardware information in a programmatically verifiable format and have gotten to the point where I am trying to output the definitions to a YAML file. Since most of the integers I'm working with are commonly referenced by their hexadecimal value, I was hoping to output certain attributes to YAML in hex format (e.g. address and resetValue).

Unfortunately, as far as I can tell there isn't a straightforward way to output numbers in any format other than base-10. Is there something I'm missing or is the only option to write a custom integer to hex conversion function?

(See below for an example of what I'm trying to accomplish)

Pkl Input File

class Field {
    bits: String
    name: String
}

class Register {
    address: UInt
    size: DataSize(this >= 1.b, this <= 2.b)
    readable: Boolean
    writable: Boolean
    resetValue: UInt | Null
    fields: Mapping<String, Types.Field>
}

EXAMPLE_REGISTER: Register = new {
    address = 0x00
    readable = true
    writable = true
    resetValue = null
    fields {
        ["ExampleFieldID"] {
            bits = "B15..0"
            name = "Example Field Name"
        }
    }
}

Desired YAML Output

EXAMPLE_REGISTER:
  address: 0x00
  readable: true
  writable: true
  fields:
    ExampleFieldID:
      bits: "B15..0"
      name: "Example Field Name"

[HT154]

Assuming that you don't want to affect all UInt instances (only Register.address), you can use an output converter like this:

output {
	renderer = new YamlRenderer {
		converters {
			[Register] = (reg) -> reg.toMap().mapValues((k, v) -> if (k == "address") new RenderDirective {
				text = " 0x\(v.toRadixString(16).padStart(2, "0"))"
			} else v)
		}
	}
}

This says:

• When rendering the Register class,
• Convert it to a Map
• For each k/v pair,
• If the key is address, replace it with a RenderDirective that has text 0x<zero-padded hex representation of the value>
• Otherwise do not change the value

Based on your example (with minor edits so it evaluates successfully), this results in:

EXAMPLE_REGISTER:
  address: 0x00
  readable: true
  writable: true
  fields:
    ExampleFieldID:
      bits: B15..0
      name: Example Field Name

[fleckerbr]

Perfect, that seems to be exactly what I was looking for. Thanks for the help 👍

[holzensp]

As a very minor tweak to this as a general pattern, I prefer not to go toMap and iterate, but toDynamic (to avoid triggering a type error when replacing a UInt with a String) and amend;

output {
  renderer = new YamlRenderer {
    converters {
      [Register] = (reg) -> (reg.toDynamic()) {
        address = new RenderDirective { text = " 0x\(reg.address.toRadixString(16).padStart(2, "0"))" }
      }
    }
  }
}