Update/Override nested Listings

[hozzer]

I'm aiming to use Pkl to better template our current ECS Task Definitions. My idea was to have the following:

1. TaskDefinition module
2. Extend the TaskDefinition module for defining service level variables (name, image, etc..)
3. Amend the service file for defining environment level variables (cpu, memory, environment, etc).

Note: A service called foo could be deployed in multiple environments where the requirements for cpu and memory differ. Certain environment variables will also differ per environment the service is deployed to.

The following works as expected.

Task.pkl

open module TD

class TaskDefinition {
  family: String
  image: String
  cpu: Int
  memory: Int
  containerDefinitions: Listing<ContainerDefinition>
}

class ContainerDefinition {
  name: String
  image: String
  cpu: Int
  memory: Int
  environment: Listing<Environment>
}

class Environment {
  name: String
  value: String
}

taskDefinition: TaskDefinition

hidden defaultTaskDefinition: TaskDefinition = new {
  family = "foo"
  image = "foo:latest"
  cpu = 1024
  memory = 2048
  containerDefinitions {
    new {
      name = "app"
      image = "app:latest"
      cpu = 512
      memory = 1024
      environment {
        new {
            name = "LOG_LEVEL"
            value = "INFO"
        }
      }
    }
  }
}

Bar.pkl

extends "Task.pkl"

hidden barTaskDefinition = (defaultTaskDefinition) {
    family = "bar"
}

dev.pkl

amends "Bar.pkl"

taskDefinition = (barTaskDefinition) {
    image = "bar:1.0.0" 
}

It was easy enough to follow the docs for updating the env property but how can I update values like cpu and memory within the containerDefintion? And going one step further, how could I update (or add) values like LOG_LEVEL within the environment?

I've messed around with Member Predicates ([[…​]]) but I can't figure out how to get the nested Listings in scope.

EDIT: I figured out how to update a nested Listing by referencing the index but I still can't figure out the syntax for using the Member Predicates so I can update a specific element:
dev.pkl

amends "Bar.pkl"

taskDefinition = (barTaskDefinition) {
    image = "bar:1.0.0" 
    containerDefinitions {
    [0] {
      name = "web"
      image = "app:latest"
      cpu = 512
      memory = 1024
      environment {
        [0] {
            name = "LOG_LEVEL"
            value = "skladjfjklasdf"
        }
      }
    }
  }
}

amends "Bar.pkl"

taskDefinition = (barTaskDefinition) {
    image = "bar:1.0.0" 
    containerDefinitions {
    [0] {
      name = "web"
      image = "app:latest"
      cpu = 512
      memory = 1024
      environment {
        [[name == "LOG_LEVEL"]] {
            value = "DEBUG"
        }
      }
    }
  }
}

The latter doesn't update the LOG_LEVEL name value pair.

[bioball]

In that member predicate, name is resolving to the outer name. You'll need to qualify it with this.name.

For example:

amends "Bar.pkl"

taskDefinition = (barTaskDefinition) {
  image = "bar:1.0.0" 
  containerDefinitions {
    [0] {
      name = "web"
      image = "app:latest"
      cpu = 512
      memory = 1024
      environment {
        [[this.name == "LOG_LEVEL"]] {
            value = "DEBUG"
        }
      }
    }
  }
}