improvement: filter expression verifier (#2243)

* Add verifier for filter expressions

* Test verifier for filter expressions

Author: ken-kost

lib/ash/resource/dsl.ex

@@ -1631,6 +1631,7 @@ defmodule Ash.Resource.Dsl do
     Ash.Resource.Verifiers.VerifyIdentityFields,
     Ash.Resource.Verifiers.VerifyPrimaryReadActionHasNoArguments,
     Ash.Resource.Verifiers.VerifySelectedByDefault,
+    Ash.Resource.Verifiers.VerifyFilterExpressions,
     Ash.Resource.Verifiers.EnsureAggregateFieldIsAttributeOrCalculation,
     Ash.Resource.Verifiers.ValidateRelationshipAttributes,
     Ash.Resource.Verifiers.NoReservedFieldNames,

lib/ash/resource/verifiers/verify_filter_expressions.ex

@@ -0,0 +1,45 @@
+defmodule Ash.Resource.Verifiers.VerifyFilterExpressions do
+  @moduledoc """
+  Raises an error if a filter expression references an undefined argument.
+  """
+  use Spark.Dsl.Verifier
+
+  alias Spark.Error.DslError
+
+  @impl true
+  def verify(dsl) do
+    module = Spark.Dsl.Verifier.get_persisted(dsl, :module)
+
+    dsl
+    |> Ash.Resource.Info.actions()
+    |> Enum.each(fn action ->
+      verify_action_filter!(module, action)
+    end)
+
+    :ok
+  end
+
+  defp verify_action_filter!(module, %{filter: filter} = action) when not is_nil(filter) do
+    argument_keys = action.arguments |> Enum.map(& &1.name) |> MapSet.new()
+
+    Ash.Expr.walk_template(filter, fn
+      {:_arg, field} = expr ->
+        field = if is_binary(field), do: String.to_atom(field), else: field
+
+        if MapSet.member?(argument_keys, field) do
+          expr
+        else
+          raise DslError,
+            module: module,
+            message:
+              "Filter expression references undefined argument `#{field}`. Available arguments: #{inspect(MapSet.to_list(argument_keys))}",
+            path: [:actions, action.name, :filter]
+        end
+
+      other ->
+        other
+    end)
+  end
+
+  defp verify_action_filter!(_module, _action), do: :ok
+end

test/resource/verify_filter_expressions_test.exs

@@ -0,0 +1,52 @@
+defmodule Ash.Test.Resource.VerifyFilterExpressionsTest do
+  @moduledoc false
+  use ExUnit.Case, async: true
+
+  import Ash.Test.Helpers
+  alias Spark.Error.DslError
+
+  test "Filter expression with undefined argument raises an error" do
+    assert_raise DslError,
+                 ~r/Filter expression references undefined argument `undefined_arg`/,
+                 fn ->
+                   defposts do
+                     actions do
+                       read :example_action do
+                         argument :valid_arg, :string
+                         filter expr(some_field == ^arg(:undefined_arg))
+                       end
+                     end
+                   end
+                 end
+  end
+
+  test "Filter expression with valid argument does not raise an error" do
+    post =
+      defposts do
+        actions do
+          read :example_action do
+            argument :valid_arg, :string
+            filter expr(some_field == ^arg(:valid_arg))
+          end
+        end
+      end
+
+    action = Ash.Resource.Info.action(post, :example_action)
+    assert action.name == :example_action
+  end
+
+  test "Filter expression with valid string argument does not raise an error" do
+    post =
+      defposts do
+        actions do
+          read :example_action do
+            argument :valid_arg, :string
+            filter expr(some_field == ^arg("valid_arg"))
+          end
+        end
+      end
+
+    action = Ash.Resource.Info.action(post, :example_action)
+    assert action.name == :example_action
+  end
+end