test: Reproduce (KeyError) key :to_tenant not found in: nil (#309)

Author: moxley

test/gf_test.exs

@@ -0,0 +1,75 @@
+defmodule GF.Test do
+  use ExUnit.Case
+
+  test "basic" do
+    group =
+      GF.Group
+      |> Ash.Changeset.for_create(:create, %{abbreviation: "TG", name: "Test Group"})
+      |> Ash.create!(authorize?: false)
+
+    Ash.DataLayer.Simple.set_data(GF.Group, [group])
+
+    event =
+      GF.Event
+      |> Ash.Changeset.for_create(:create, %{title: "Test Event"}, tenant: group.id)
+      |> Ash.create!(authorize?: false)
+
+    assert event.id
+
+    Ash.DataLayer.Simple.set_data(GF.Event, [event])
+
+    assert Ash.get!(GF.Event, event.id, authorize?: false)
+
+    member =
+      GF.Member
+      |> Ash.Changeset.for_create(
+        :create,
+        %{email: "test@example.com", name: "Test Member", status: :active},
+        tenant: group.id
+      )
+      |> Ash.create!(authorize?: false)
+
+    actor =
+      GF.Member
+      |> Ash.Changeset.for_create(
+        :create,
+        %{email: "actor@example.com", name: "Actor Member", status: :inactive},
+        tenant: group.id
+      )
+      |> Ash.create!(authorize?: false)
+
+    Ash.DataLayer.Simple.set_data(GF.Member, [member, actor])
+
+    attendee =
+      GF.Attendee
+      |> Ash.Changeset.for_create(:create, %{event_id: event.id, member_id: member.id})
+      |> Ash.create!(authorize?: false)
+
+    Ash.DataLayer.Simple.set_data(GF.Attendee, [attendee])
+
+    assert attendee.id
+
+    {:ok, %{data: data}} =
+      """
+      query GetEvent($id: ID!) {
+        getEvent(id: $id) {
+          id
+          title
+          attendees(filter: {member: {status: {eq: ACTIVE}}}) {
+            id
+            member {
+              id
+              name
+            }
+          }
+        }
+      }
+      """
+      |> Absinthe.run(GF.AshGraphqlSchema,
+        variables: %{"id" => event.id},
+        context: %{actor: actor}
+      )
+
+    assert data["getEvent"]
+  end
+end

test/support/gf/active_member_policy.ex

@@ -0,0 +1,28 @@
+defmodule GF.ActiveMemberPolicy do
+  use Ash.Policy.SimpleCheck
+
+  # This is used when logging a breakdown of how a policy is applied - see Logging below.
+  def describe(_) do
+    "Member is active and has given role"
+  end
+
+  def match?(%_{} = member, %{resource: _resource} = _context, opts) do
+    active? =
+      case member do
+        %{status: :active} -> true
+        _other -> false
+      end
+
+    cond do
+      opts[:role] ->
+        GF.Member.can_take_role_action?(member, opts[:role])
+
+      true ->
+        active?
+    end
+  end
+
+  def match?(_actor, _context, _opts) do
+    false
+  end
+end

test/support/gf/ash_graphql_schema.ex

@@ -0,0 +1,15 @@
+defmodule GF.AshGraphqlSchema do
+  @moduledoc false
+
+  use Absinthe.Schema
+
+  @domains [GF.Domain]
+
+  use AshGraphql, domains: @domains, generate_sdl_file: "priv/gf_schema.graphql"
+
+  query do
+  end
+
+  mutation do
+  end
+end

test/support/gf/attendee.ex

@@ -0,0 +1,51 @@
+defmodule GF.Attendee do
+  @moduledoc """
+  An attendee record for ane event.
+  """
+
+  use Ash.Resource,
+    domain: GF.Domain,
+    data_layer: Ash.DataLayer.Ets,
+    extensions: [AshGraphql.Resource],
+    authorizers: [Ash.Policy.Authorizer]
+
+  require Ash.Query
+  require Ash.Sort
+
+  alias GF.Member
+
+  actions do
+    default_accept(:*)
+    defaults([:create, :update, :read, :destroy])
+  end
+
+  attributes do
+    uuid_primary_key(:id)
+
+    attribute(:event_id, :uuid, public?: true)
+    attribute(:member_id, :uuid, public?: true)
+
+    create_timestamp(:inserted_at)
+    update_timestamp(:updated_at)
+  end
+
+  relationships do
+    belongs_to(:member, Member, public?: true)
+  end
+
+  policies do
+    policy action(:read) do
+      authorize_if(actor_present())
+    end
+  end
+
+  graphql do
+    type :gf_attendee
+  end
+
+  code_interface do
+    define(:get_by_id, action: :read, get_by: :id, not_found_error?: false)
+    define(:create, action: :create)
+    define(:update, action: :update)
+  end
+end

test/support/gf/domain.ex

@@ -0,0 +1,10 @@
+defmodule GF.Domain do
+  use Ash.Domain
+
+  resources do
+    resource(GF.Event)
+    resource(GF.Attendee)
+    resource(GF.Group)
+    resource(GF.Member)
+  end
+end

test/support/gf/event.ex

@@ -0,0 +1,55 @@
+defmodule GF.Event do
+  @moduledoc """
+  Event Ash resource.
+  """
+
+  use Ash.Resource,
+    domain: GF.Domain,
+    data_layer: Ash.DataLayer.Ets,
+    extensions: [AshGraphql.Resource]
+
+  require Ash.Query
+
+  alias GF.Attendee
+
+  attributes do
+    uuid_primary_key(:id)
+
+    attribute(:description, :string, public?: true)
+    attribute(:group_id, :uuid, public?: false)
+
+    attribute(:start_at, :utc_datetime, public?: true)
+    attribute(:title, :string, public?: true)
+
+    create_timestamp(:inserted_at, public?: true)
+    update_timestamp(:updated_at, public?: true)
+  end
+
+  multitenancy do
+    strategy(:attribute)
+    attribute(:group_id)
+    global?(true)
+  end
+
+  actions do
+    default_accept(:*)
+    defaults([:create, :read, :update, :destroy])
+  end
+
+  relationships do
+    has_many(:attendees, Attendee, public?: true)
+  end
+
+  graphql do
+    type :gf_event
+
+    queries do
+      get :get_event, :read
+    end
+  end
+
+  code_interface do
+    define(:get_by_id, action: :read, get_by: :id, not_found_error?: false)
+    define(:create, action: :create)
+  end
+end

test/support/gf/group.ex

@@ -0,0 +1,35 @@
+defmodule GF.Group do
+  @moduledoc "An Ash-managed GroupFlow Group (customer)"
+
+  use Ash.Resource,
+    domain: GF.Domain,
+    data_layer: Ash.DataLayer.Ets,
+    extensions: [AshGraphql.Resource]
+
+  @type t :: %__MODULE__{}
+
+  # Attributes are the simple pieces of data that exist on your resource
+  attributes do
+    uuid_primary_key(:id)
+
+    attribute(:abbreviation, :string, public?: true)
+    attribute(:name, :string, public?: true)
+
+    create_timestamp(:inserted_at, public?: true)
+    update_timestamp(:updated_at, public?: true)
+  end
+
+  actions do
+    default_accept(:*)
+    # Add a set of simple actions. You'll customize these later.
+    defaults([:create, :read, :update, :destroy])
+  end
+
+  graphql do
+    type :group2
+  end
+
+  code_interface do
+    define(:create, action: :create)
+  end
+end