feat: raise at compile time when related resource's domain is missing from schema

Author: nallwhy

lib/ash_graphql.ex

@@ -167,6 +167,11 @@ defmodule AshGraphql do
 
       Enum.each(ash_resources, &Code.ensure_compiled!/1)
 
+      AshGraphql.validate_domains_for_relationships!(
+        ash_resources,
+        Enum.map(domains, &elem(&1, 0))
+      )
+
       schema = __MODULE__
       schema_env = __ENV__
 
@@ -1259,4 +1264,33 @@ defmodule AshGraphql do
         response_metadata: {:my_extension_key, {MyApp.MetadataHandler, :build, []}}
     """
   end
+
+  @doc false
+  def validate_domains_for_relationships!(ash_resources, all_domains) do
+    for resource <- ash_resources,
+        AshGraphql.Resource in Spark.extensions(resource),
+        relationship <- Ash.Resource.Info.public_relationships(resource),
+        AshGraphql.Resource in Spark.extensions(relationship.destination),
+        relationship.destination not in ash_resources do
+      destination_domain = Ash.Resource.Info.domain(relationship.destination)
+
+      domain_hint =
+        if destination_domain do
+          "Add #{inspect(destination_domain)} to your schema's domain list:\n\n" <>
+            "    use AshGraphql, domains: #{inspect(all_domains ++ [destination_domain])}"
+        else
+          "Make sure the domain for #{inspect(relationship.destination)} is included in your schema's domain list."
+        end
+
+      raise """
+            #{inspect(resource)} has a relationship `#{relationship.name}` to #{inspect(relationship.destination)}, \
+            but #{inspect(relationship.destination)}'s domain is not included in this schema.
+
+            #{domain_hint}
+            """
+            |> IO.inspect()
+    end
+
+    :ok
+  end
 end

test/missing_related_domain_test.exs

@@ -0,0 +1,91 @@
+# SPDX-FileCopyrightText: 2020 ash_graphql contributors <https://github.com/ash-project/ash_graphql/graphs/contributors>
+#
+# SPDX-License-Identifier: MIT
+
+defmodule AshGraphql.MissingRelatedDomainTest do
+  use ExUnit.Case, async: false
+
+  # Define ResourceB and DomainB as valid, fully-compiled modules outside of the test.
+  # The test scenario is: both domains are valid, but the schema only registers DomainA.
+
+  alias AshGraphql.MissingRelatedDomainTest.{
+    RelatedDomain,
+    SourceDomain,
+    RelatedResource,
+    SourceResource
+  }
+
+  defmodule RelatedResource do
+    use Ash.Resource,
+      domain: RelatedDomain,
+      extensions: [AshGraphql.Resource]
+
+    graphql do
+      type :missing_test_related_resource
+    end
+
+    actions do
+      default_accept(:*)
+      defaults([:read])
+    end
+
+    attributes do
+      uuid_primary_key(:id)
+    end
+  end
+
+  defmodule RelatedDomain do
+    use Ash.Domain, extensions: [AshGraphql.Domain]
+
+    resources do
+      resource(RelatedResource)
+    end
+  end
+
+  defmodule SourceResource do
+    use Ash.Resource,
+      domain: SourceDomain,
+      extensions: [AshGraphql.Resource]
+
+    graphql do
+      type :missing_test_source_resource
+
+      queries do
+        list :list_source_resources, :read
+      end
+    end
+
+    actions do
+      default_accept(:*)
+      defaults([:read])
+    end
+
+    attributes do
+      uuid_primary_key(:id)
+    end
+
+    relationships do
+      belongs_to(:related, RelatedResource, public?: true)
+    end
+  end
+
+  defmodule SourceDomain do
+    use Ash.Domain, extensions: [AshGraphql.Domain]
+
+    resources do
+      resource(SourceResource)
+    end
+  end
+
+  test "raises at compile time when a related resource's domain is not in the schema" do
+    assert_raise RuntimeError, ~r/RelatedDomain/, fn ->
+      defmodule TestSchemaMissingDomain do
+        use Absinthe.Schema
+
+        # Only SourceDomain is registered — RelatedDomain is intentionally omitted
+        @domains [SourceDomain]
+        use AshGraphql, domains: @domains
+      end
+    end
+  end
+end