ifdyndnsd/flake.nix at main · astro/ifdyndnsd · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
{
  inputs = {
    utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = { self, nixpkgs, utils }:
    let
      systems = [
        "i686-linux"
        "x86_64-linux"
        #"armv6l-linux"
        #"armv7l-linux"
        "aarch64-linux"
        #"riscv64-linux"
      ];
    in utils.lib.eachSystem systems (system:
      let
        pkgs = nixpkgs.legacyPackages."${system}";

      in rec {
        # `nix build`
        packages.ifdyndnsd = pkgs.rustPlatform.buildRustPackage {
          pname = "ifdyndnsd";
          version = (
            pkgs.lib.importTOML ./Cargo.toml
          ).package.version + "-" + self.lastModifiedDate;
          # Filter src to avoid unnecessary rebuilds
          src = pkgs.runCommand "ifdyndnsd-src" {} ''
            mkdir $out
            ln -s ${./src} $out/src
            ln -s ${./Cargo.toml} $out/Cargo.toml
            ln -s ${./Cargo.lock} $out/Cargo.lock
          '';
          cargoLock.lockFile = ./Cargo.lock;
        };
        defaultPackage = packages.ifdyndnsd;

        checks = packages // {
          nixos-test =
            let
              pkgs = import nixpkgs {
                inherit system;
                overlays = [ self.overlay ];
              };
            in
              pkgs.callPackage ./nixos-test.nix {};
        };

        # `nix run`
        apps.ifdyndnsd = utils.lib.mkApp { drv = packages.ifdyndnsd; };
        defaultApp = apps.ifdyndnsd;

        # `nix develop`
        devShell = pkgs.mkShell {
          nativeBuildInputs = with defaultPackage;
            nativeBuildInputs ++ buildInputs
            ++ (with pkgs; [ cargo-edit clippy rust-analyzer rustfmt ]);
        };
      }) // {
        overlay = final: prev: { inherit (self.packages.${prev.stdenv.system}) ifdyndnsd; };

        nixosModule = {
          imports = [ ./nixos-module.nix ];

          nixpkgs.overlays = [
            self.overlay
          ];
        };
      };
}