axidev-osk/flake.nix at main · axide-dev/axidev-osk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
{
  description = "Axidev OSK on-screen keyboard";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      supportedSystems = [ "x86_64-linux" ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = import nixpkgs { inherit system; };
          python = pkgs.python3;
          axidev-io = python.pkgs.buildPythonPackage {
            pname = "axidev-io";
            version = "0.7.4";
            pyproject = true;
            src = ./vendor/axidev-io-python;

            nativeBuildInputs = with pkgs; [
              pkg-config
              python.pkgs.setuptools
              python.pkgs.wheel
            ];

            buildInputs = with pkgs; [
              libinput
              systemd
              libxkbcommon
            ];

            doCheck = false;
          };
        in
        rec {
          default = axidev-osk;

          axidev-osk = python.pkgs.buildPythonApplication {
            pname = "axidev-osk";
            version = "0.17.3";
            pyproject = true;
            src = self;

            nativeBuildInputs = with pkgs; [
              python.pkgs.setuptools
              python.pkgs.wheel
            ];

            propagatedBuildInputs = [
              axidev-io
              python.pkgs.pyside6
            ];

            buildInputs = with pkgs; [
              qt6.qtwayland
              kdePackages.layer-shell-qt
              libinput
              systemd
              libxkbcommon
            ];

            postInstall = ''
              install -Dm0644 packaging/linux/resources/70-axidev-io-uinput.rules \
                $out/lib/udev/rules.d/70-axidev-io-uinput.rules
            '';

            doCheck = false;

            meta = with pkgs.lib; {
              description = "On-screen keyboard overlay with real key emission";
              homepage = "https://github.com/axide-dev/axidev-osk";
              license = licenses.gpl3Only;
              mainProgram = "axidev-osk";
              platforms = platforms.linux;
            };
          };
        });

      devShells = forAllSystems (system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              python3
              python3Packages.pyside6
              qt6.qtwayland
              kdePackages.layer-shell-qt
              libinput
              systemd
              libxkbcommon
              pkg-config
              gcc
            ];
          };
        });

      nixosModules.default = import ./packaging/nix/module.nix self;
    };
}