build.gradle

/*
 * Copyright Hyperledger Besu contributors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except in compliance with
 * the License. You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on
 * an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the
 * specific language governing permissions and limitations under the License.
 *
 * SPDX-License-Identifier: Apache-2.0
 */

plugins {
  // Apply the java-library plugin for API and implementation separation.
  id 'java-library'
  alias libs.plugins.git.versioning
  alias libs.plugins.spotless
  alias libs.plugins.besu.plugin.distribution
  alias libs.plugins.errorprone
}

version = "0.0.0-SNAPSHOT"

gitVersioning.apply {
  refs {
    tag("\\d+\\.\\d+\\.\\d+") {
      version = "\${ref}"
    }
    branch("main") {
      version = "\${ref}-SNAPSHOT"
    }
    branch(".+") {
      version = "\${ref}-SNAPSHOT"
    }
  }
  rev {
    version = "\${commit.short}-SNAPSHOT"
  }
}

repositories {
  // Use Maven Central for resolving dependencies.
  mavenCentral()
}

besuPlugin {
  besuVersion = libs.versions.besu.asProvider().get()
}

dependencies {
  errorprone libs.errorprone.core

  // Use JUnit Jupiter for testing.
  testImplementation libs.junit.jupiter
  testImplementation libs.assertj.core
  testImplementation 'org.mockito:mockito-core'
  testImplementation 'org.mockito:mockito-junit-jupiter'

  testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

// Apply a specific Java toolchain to ease working on different environments.
java {
  toolchain {
    languageVersion = JavaLanguageVersion.of(21)
  }
}

tasks.named('jar') {
  manifest {
    attributes(
      'Implementation-Title': project.name,
      'Implementation-Version': project.version,
      )
  }
}

tasks.named('test') {
  // Use JUnit Platform for unit tests.
  useJUnitPlatform()
}

// Integration test source set and task
sourceSets {
  integrationTest {
    java.srcDir 'src/integrationTest/java'
    resources.srcDir 'src/integrationTest/resources'
    compileClasspath += sourceSets.main.output + sourceSets.test.output
    runtimeClasspath += sourceSets.main.output + sourceSets.test.output
  }
}

configurations {
  integrationTestImplementation.extendsFrom testImplementation
  integrationTestRuntimeOnly.extendsFrom testRuntimeOnly
}

dependencies {
  integrationTestImplementation libs.testcontainers
  integrationTestImplementation libs.testcontainers.junit.jupiter
}

tasks.register('integrationTest', Test) {
  description = 'Runs integration tests.'
  group = 'verification'
  testClassesDirs = sourceSets.integrationTest.output.classesDirs
  classpath = sourceSets.integrationTest.runtimeClasspath
  dependsOn distZip
  distZip.outputs.upToDateWhen { false }
  useJUnitPlatform()
  outputs.upToDateWhen { false } // Always re-run; Docker container state is not tracked by Gradle
}

spotless {
  java {
    importOrder('org.hyperledger', 'java', '')
    removeUnusedImports()
    googleJavaFormat()
    licenseHeaderFile(layout.projectDirectory.file("gradle/spotless/java.license.template"))
  }
  // spotless check applied to build.gradle (groovy) files
  groovyGradle {
    target '*.gradle'
    greclipse('4.31').configFile(layout.projectDirectory.file('gradle/spotless/greclipse.properties'))
    endWithNewline()
  }
}