bisq-relay/build.gradle at d355fbf6d67ae7766c75d46213419940e19d6321 · bisq-network/bisq-relay · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
plugins {
    id 'application'
    alias(libs.plugins.shadow)
    alias(libs.plugins.springDependencyManagement)
    alias(libs.plugins.springframeworkBoot)
    alias(libs.plugins.gradleGitProperties)
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

group 'bisq'
version = file("src/main/resources/version.txt").text.trim()

application {
    mainClass = 'bisq.relay.Main'
}

bootJar {
    mainClass = 'bisq.relay.Main'
}

[test, run, bootRun].each { runTask ->
    configure(runTask) {
        systemProperties System.properties
    }
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(25))
    }
}

jar.manifest.attributes(
        "Implementation-Title": project.name,
        "Implementation-Version": version
)

dependencies {
    implementation libs.spring.boot.aop
    implementation libs.spring.boot.actuator
    implementation libs.spring.boot.dependencies
    implementation libs.spring.boot.validation
    implementation libs.spring.boot.web

    implementation libs.resilience4j.micrometer
    implementation libs.resilience4j.spring.boot

    runtimeOnly libs.micrometer.registry.prometheus

    implementation(libs.firebase) {
        exclude group: 'commons-logging', module: 'commons-logging'
    }
    implementation libs.pushy

    implementation libs.apache.commons.lang3

    implementation libs.slf4j.api
    implementation libs.logback.core
    implementation libs.logback.classic

    testImplementation libs.junit.jupiter
    testImplementation libs.resilience4j.spring.boot
    testImplementation libs.spring.boot.aop
    testImplementation libs.spring.boot.test
}

/**
 * Generate META-INF/build-info.properties at build time so /actuator/info shows build info.
 */
springBoot {
    buildInfo {
        properties {
            name = project.name
            version = project.version.toString()
        }
    }
}

/**
 * Configure git-properties so /actuator/info shows git info.
 */
gitProperties {
    keys = ['git.branch', 'git.commit.time', 'git.commit.id']
    failOnNoGitDirectory = false
}

clean.doFirst {
    // Remove the project root level 'bisq-*' scripts and 'lib' dir generated at the end of the assemble task.
    delete fileTree(dir: projectDir, include: ['bisq-relay', 'bisq-relay.bat']), 'lib'
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}