nix/flake.nix at 4214820064ea97a21787a4396eda857437690ae9 · c0d3h01/nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
{
  description = "NixOS flake configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default";
    disko.url = "github:nix-community/disko";
    home-manager.url = "github:nix-community/home-manager";
    sops-nix.url = "github:Mic92/sops-nix";
    spicetify-nix.url = "github:Gerg-L/spicetify-nix";
    nur.url = "github:nix-community/NUR";
    nixvim.url = "github:nix-community/nixvim";
    stylix.url = "github:nix-community/stylix";
  };

  outputs = {
    self,
    nixpkgs,
    systems,
    ...
  } @ inputs: let
    # Supported systems
    supportedSystems = ["x86_64-linux"];
    primarySystem = builtins.head supportedSystems;

    # Helper to generate per-system attributes
    eachSystem = nixpkgs.lib.genAttrs supportedSystems;

    # Package set with overlays and config
    mkPkgs = system:
      import nixpkgs {
        inherit system;
        config.allowUnfree = true;
        overlays = [
          inputs.nur.overlays.default
        ];
      };

    mkFormatter = system:
      import ./formatter.nix {
        inherit self;
        pkgs = mkPkgs system;
      };
  in {
    nixosConfigurations.c0d3h01 = nixpkgs.lib.nixosSystem {
      system = primarySystem;
      specialArgs = {
        inherit inputs self;
      };
      modules = [
        ./modules/nixos
        inputs.home-manager.nixosModules.home-manager
        {
          home-manager = {
            useGlobalPkgs = true;
            useUserPackages = true;
            backupFileExtension = "backup";
            extraSpecialArgs = {
              inherit inputs self;
            };
            users.c0d3h01.imports = [./modules/home];
          };
        }
      ];
    };

    homeConfigurations.c0d3h01 = inputs.home-manager.lib.homeManagerConfiguration {
      pkgs = mkPkgs primarySystem;
      extraSpecialArgs = {
        inherit inputs self;
      };
      modules = [./modules/home];
    };

    devShells = eachSystem (system: {
      default = let
        pkgs = mkPkgs system;
      in
        import ./shell.nix {
          inherit pkgs;
          formatter = (mkFormatter system).formatter;
        };
    });

    formatter = eachSystem (system:
      (mkFormatter system).formatter);

    checks = eachSystem (system: {
      formatting = (mkFormatter system).check;
    });
  };
}