Added support for EKS

Author: andrejatcastai

examples/onboarding-with-existing-eks-cluster/main.tf

@@ -0,0 +1,55 @@
+data "aws_eks_cluster" "eks" {
+  name = var.eks_cluster_name
+}
+
+data "aws_vpc" "eks_vpc" {
+  id = data.aws_eks_cluster.eks.vpc_config[0].vpc_id
+}
+
+data "aws_subnets" "eks_subnets" {
+  filter {
+    name   = "vpc-id"
+    values = [data.aws_vpc.eks_vpc.id]
+  }
+}
+
+data "aws_subnet" "eks_subnet" {
+  for_each = toset(data.aws_subnets.eks_subnets.ids)
+  id       = each.value
+}
+
+locals {
+  # Get all subnet CIDR blocks for reserved subnets
+  subnet_cidrs = [for s in data.aws_subnet.eks_subnet : s.cidr_block]
+}
+
+module "castai_omni_cluster" {
+  source = "../.."
+
+  k8s_provider    = "eks"
+  api_url         = var.castai_api_url
+  api_token       = var.castai_api_token
+  organization_id = var.organization_id
+  cluster_id      = var.cluster_id
+  cluster_name    = var.eks_cluster_name
+  cluster_region  = var.eks_cluster_region
+
+  api_server_address    = data.aws_eks_cluster.eks.endpoint
+  pod_cidr              = data.aws_eks_cluster.eks.kubernetes_network_config[0].service_ipv4_cidr
+  service_cidr          = data.aws_eks_cluster.eks.kubernetes_network_config[0].service_ipv4_cidr
+  reserved_subnet_cidrs = local.subnet_cidrs
+}
+
+module "castai_aws_edge_location" {
+  source = "github.com/castai/terraform-castai-omni-edge-location-aws"
+
+  cluster_id      = var.cluster_id
+  organization_id = var.organization_id
+  region          = "eu-west-1"
+
+  tags = {
+    ManagedBy = "terraform"
+  }
+
+  depends_on = [module.castai_omni_cluster]
+}

examples/onboarding-with-existing-eks-cluster/providers.tf

@@ -0,0 +1,54 @@
+terraform {
+  required_version = ">= 1.11"
+
+  required_providers {
+    castai = {
+      source  = "castai/castai"
+      version = ">= 8.3.0"
+    }
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 5.0"
+    }
+    helm = {
+      source  = "hashicorp/helm"
+      version = ">= 3.1.1"
+    }
+    null = {
+      source  = "hashicorp/null"
+      version = ">= 3.2.4"
+    }
+    external = {
+      source  = "hashicorp/external"
+      version = ">= 2.3.5"
+    }
+  }
+}
+
+provider "aws" {
+  region = var.eks_cluster_region
+}
+
+provider "helm" {
+  kubernetes = {
+    host                   = data.aws_eks_cluster.eks.endpoint
+    cluster_ca_certificate = base64decode(data.aws_eks_cluster.eks.certificate_authority[0].data)
+    exec = {
+      api_version = "client.authentication.k8s.io/v1beta1"
+      command     = "aws"
+      args = [
+        "eks",
+        "get-token",
+        "--cluster-name",
+        data.aws_eks_cluster.eks.name,
+        "--region",
+        var.eks_cluster_region
+      ]
+    }
+  }
+}
+
+provider "castai" {
+  api_token = var.castai_api_token
+  api_url   = var.castai_api_url
+}

examples/onboarding-with-existing-eks-cluster/tf.vars.example

@@ -0,0 +1,8 @@
+gke_project_id       = "<place-holder>"
+gke_cluster_location = "<place-holder>"
+gke_cluster_name     = "<place-holder>"
+
+castai_api_url   = "https://api.cast.ai"
+castai_api_token = "<place-holder>"
+cluster_id       = "<place-holder>"
+organization_id  = "<place-holder>"

examples/onboarding-with-existing-eks-cluster/variables.tf

@@ -0,0 +1,31 @@
+variable "eks_cluster_region" {
+  description = "EKS cluster region"
+  type        = string
+}
+
+variable "eks_cluster_name" {
+  description = "EKS Cluster Name"
+  type        = string
+}
+
+variable "castai_api_url" {
+  description = "Cast AI API URL"
+  type        = string
+  default     = "https://api.cast.ai"
+}
+
+variable "castai_api_token" {
+  description = "Cast AI API Token"
+  type        = string
+  sensitive   = true
+}
+
+variable "organization_id" {
+  description = "Cast AI Organization ID"
+  type        = string
+}
+
+variable "cluster_id" {
+  description = "Cast AI Cluster ID"
+  type        = string
+}

examples/onboarding-with-existing-gke-cluster/main.tf

@@ -27,6 +27,7 @@ data "google_compute_subnetwork" "gke_subnet" {
 module "castai_omni_cluster" {
   source = "../.."
 
+  k8s_provider    = "gke"
   api_url         = var.castai_api_url
   api_token       = var.castai_api_token
   organization_id = var.organization_id

main.tf

@@ -8,10 +8,14 @@ locals {
   omni_agent_release     = "omni-agent"
   omni_agent_chart       = "omni-agent"
   castai_helm_repository = "https://castai.github.io/helm-charts"
+
+  # Select the appropriate set_values based on k8s_provider
+  set_values = var.k8s_provider == "gke" ? module.liqo_helm_values_gke[0].set_values : module.liqo_helm_values_eks[0].set_values
 }
 
-# Compute Liqo Helm chart configuration
-module "liqo_helm_values" {
+# GKE-specific Liqo Helm chart configuration
+module "liqo_helm_values_gke" {
+  count  = var.k8s_provider == "gke" ? 1 : 0
   source = "./modules/gke"
 
   image_tag             = local.liqo_image_tag
@@ -24,6 +28,20 @@ module "liqo_helm_values" {
   reserved_subnet_cidrs = var.reserved_subnet_cidrs
 }
 
+# EKS-specific Liqo Helm chart configuration
+module "liqo_helm_values_eks" {
+  count  = var.k8s_provider == "eks" ? 1 : 0
+  source = "./modules/eks"
+
+  image_tag             = local.liqo_image_tag
+  cluster_name          = var.cluster_name
+  cluster_region        = var.cluster_region
+  api_server_address    = var.api_server_address
+  pod_cidr              = var.pod_cidr
+  service_cidr          = var.service_cidr
+  reserved_subnet_cidrs = var.reserved_subnet_cidrs
+}
+
 # Liqo Helm Release
 resource "helm_release" "liqo" {
   name             = local.liqo_release_name
@@ -35,7 +53,7 @@ resource "helm_release" "liqo" {
   cleanup_on_fail  = true
   wait             = true
 
-  set = module.liqo_helm_values.set_values
+  set = local.set_values
 }
 
 # Wait for Liqo network resources to be ready before proceeding

modules/eks/main.tf

@@ -0,0 +1,70 @@
+locals {
+  pools_cidrs = ["10.0.0.0/8", "192.168.0.0/16", "172.16.0.0/12", var.service_cidr]
+
+  basic_set_values = [
+    {
+      name  = "tag"
+      value = var.image_tag
+    },
+    {
+      name  = "apiServer.address"
+      value = var.api_server_address
+    },
+    {
+      name  = "discovery.config.clusterID"
+      value = var.cluster_name
+    },
+    {
+      name  = "discovery.config.clusterLabels.liqo\\.io/provider"
+      value = "eks"
+    },
+    {
+      name  = "discovery.config.clusterLabels.topology\\.kubernetes\\.io/region"
+      value = var.cluster_region
+    },
+    {
+      name  = "ipam.podCIDR"
+      value = var.pod_cidr
+    },
+    {
+      name  = "ipam.serviceCIDR"
+      value = var.service_cidr
+    },
+    {
+      name  = "telemetry.enabled"
+      value = "false"
+    }
+  ]
+
+  pools_set_values = [
+    for idx, cidr in local.pools_cidrs : {
+      name  = "ipam.pools[${idx}]"
+      value = cidr
+    }
+  ]
+
+  reserved_subnets_set_values = [
+    for idx, cidr in var.reserved_subnet_cidrs : {
+      name  = "ipam.reservedSubnets[${idx}]"
+      value = cidr
+    }
+  ]
+
+  eks_specific_set_values = [
+    {
+      name  = "networking.fabric.config.fullMasquerade"
+      value = "true"
+    },
+    {
+      name  = "networking.gatewayTemplates.server.service.annotations.service\\.beta\\.kubernetes\\.io/aws-load-balancer-type"
+      value = "nlb"
+    }
+  ]
+
+  all_set_values = concat(
+    local.basic_set_values,
+    local.pools_set_values,
+    local.reserved_subnets_set_values,
+    local.eks_specific_set_values
+  )
+}

modules/eks/outputs.tf

@@ -0,0 +1,4 @@
+output "set_values" {
+  description = "All Helm set values for liqo configuration"
+  value       = local.all_set_values
+}

modules/eks/variables.tf

@@ -0,0 +1,35 @@
+variable "image_tag" {
+  description = "Docker image tag"
+  type        = string
+}
+
+variable "cluster_name" {
+  description = "EKS cluster name"
+  type        = string
+}
+
+variable "cluster_region" {
+  description = "EKS region for topology labels"
+  type        = string
+}
+
+variable "api_server_address" {
+  description = "Kubernetes API server address"
+  type        = string
+}
+
+variable "pod_cidr" {
+  description = "Pod CIDR for IPAM configuration"
+  type        = string
+}
+
+variable "service_cidr" {
+  description = "Service CIDR for IPAM configuration"
+  type        = string
+}
+
+variable "reserved_subnet_cidrs" {
+  description = "List of subnet CIDRs for IPAM reserved subnets"
+  type        = list(string)
+  default     = []
+}

modules/eks/versions.tf

@@ -0,0 +1,3 @@
+terraform {
+  required_version = ">= 1.11"
+}