nix/modules/home-manager/firefox.nix at 06d571bc9728d276f3a57b41a345770dafd30fcb · catppuccin/nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
{ catppuccinLib }:
{ config, lib, ... }:
let
  inherit (lib)
    attrNames
    foldl'
    hasAttr
    importJSON
    toSentenceCase
    mapAttrs
    mkIf
    mkOption
    optional
    getAttrFromPath
    setAttrByPath
    types
    ;

  inherit (config.catppuccin) sources;
  themes = importJSON "${sources.firefox}/themes.json";

  mkFirefoxModule =
    {
      name,
      prettyName ? toSentenceCase name,
      hmModulePath ? [
        "programs"
        name
      ],
    }:
    let
      modulePath = [
        "catppuccin"
        name
      ];

      getAttrStringFromPath = lib.concatStringsSep ".";

      cfg = getAttrFromPath modulePath config;
      firefoxCfg = getAttrFromPath hmModulePath config;

      mkProfileOptions =
        {
          forceDefault ? false,
          enableDefault ? null,
        }:
        catppuccinLib.mkCatppuccinOption (
          {
            inherit name;
            accentSupport = true;
          }
          // (lib.optionalAttrs (enableDefault != null) {
            default = enableDefault;
          })
        )
        // {
          force = mkOption {
            type = types.bool;
            default = forceDefault;
            description = "Forcibly override any existing configuration for Firefox Color.";
            example = true;
          };
        };
    in
    {
      options =
        (setAttrByPath modulePath (
          (mkProfileOptions { })
          // {
            profiles = mkOption {
              type = types.attrsOf (
                types.submodule {
                  options = mkProfileOptions {
                    enableDefault = cfg.enable;
                    forceDefault = cfg.force;
                  };
                  config = {
                    flavor = lib.mkDefault cfg.flavor;
                    accent = lib.mkDefault cfg.accent;
                  };
                }
              );
              default = mapAttrs (_: _: { }) firefoxCfg.profiles;
              defaultText = "<profiles declared in `${getAttrStringFromPath hmModulePath}.profiles`>";
              description = "Catppuccin settings for ${prettyName} profiles.";
            };
          }
        ))
        # home-manager browser config
        // (setAttrByPath hmModulePath {
          profiles = mkOption {
            type = types.attrsOf (
              types.submodule (
                { name, ... }:
                let
                  profile = cfg.profiles.${name} or { enable = false; };
                in
                {
                  config = mkIf profile.enable {
                    extensions = {
                      settings."FirefoxColor@mozilla.com" = {
                        inherit (profile) force;
                        settings = {
                          firstRunDone = true;
                          theme = themes.${profile.flavor}.${profile.accent};
                        };
                      };
                    };
                  };
                }
              )
            );
          };
        });

      config = {
        warnings = foldl' (
          acc: name:
          acc
          ++
            optional (!(hasAttr name firefoxCfg.profiles))
              "${prettyName} profile '${name}' is defined in '${getAttrStringFromPath modulePath}', but not '${getAttrStringFromPath hmModulePath}'. This will have no effect."
        ) [ ] (attrNames cfg.profiles);
      };
    };
in
{
  imports = map mkFirefoxModule [
    { name = "firefox"; }
    {
      name = "librewolf";
      prettyName = "LibreWolf"; # W in LibreWolf is uppercase
    }
    { name = "floorp"; }
  ];
}