nix/modules/home-manager/firefox/mkFirefoxModule.nix at b141cde085cab511bef7dae2a0c6ee3f0f1d22eb · catppuccin/nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
{
  catppuccinLib,

  name,
  prettyName ? null,
  hmModulePath ? [
    "programs"
    name
  ],
}:
{ config, lib, ... }:

let
  inherit (lib)
    attrNames
    const
    foldl'
    genAttrs
    hasAttr
    importJSON
    toSentenceCase
    optional
    mkIf
    mkOption
    getAttrFromPath
    setAttrByPath
    types
    ;

  getAttrStringFromPath = lib.concatStringsSep ".";

  inherit (config.catppuccin) sources;
  themes = importJSON "${sources.firefox}/themes.json";

  cfg = getAttrFromPath modulePath config;
  firefoxCfg = getAttrFromPath hmModulePath config;

  modulePath = [
    "catppuccin"
    name
  ];
  prettyName' = if prettyName == null then toSentenceCase name else prettyName;

  optionsModule = {
    options =
      catppuccinLib.mkCatppuccinOption {
        inherit name;
        accentSupport = true;
      }
      // {
        force = mkOption {
          type = types.bool;
          default = false;
          description = "Forcibly override any existing configuration for Firefox Color.";
          example = true;
        };
      };
  };

  catppuccinProfilesSubmodule = {
    imports = [ optionsModule ];

    config = lib.mapAttrs (lib.const lib.mkDefault) {
      inherit (cfg)
        enable
        flavor
        accent
        force
        ;
    };
  };

  catppuccinOptions = setAttrByPath modulePath (
    lib.mkOption {
      type = lib.types.submodule {
        imports = [ optionsModule ];

        options = {
          profiles = mkOption {
            type = types.attrsOf (types.submodule catppuccinProfilesSubmodule);
            default = genAttrs (attrNames firefoxCfg.profiles) (const { });
            defaultText = "<profiles declared in `${getAttrStringFromPath hmModulePath}.profiles`>";
            description = "Catppuccin settings for ${prettyName'} profiles.";
          };
        };
      };
      default = { };
      description = "Catppuccin settings for ${prettyName'}.";
    }
  );

  firefoxProfilesSubmodule =
    { name, ... }:

    let
      profile = cfg.profiles.${name} or { enable = false; };
    in

    {
      config = mkIf profile.enable {
        extensions = {
          settings."FirefoxColor@mozilla.com" = {
            inherit (profile) force;
            settings = {
              firstRunDone = true;
              theme = themes.${profile.flavor}.${profile.accent};
            };
          };
        };
      };
    };

  homeOptions = setAttrByPath hmModulePath {
    profiles = mkOption {
      type = types.attrsOf (types.submodule firefoxProfilesSubmodule);
    };
  };
in

{
  options = catppuccinOptions // homeOptions;

  config = {
    warnings = foldl' (
      acc: name:
      acc
      ++
        optional (!(hasAttr name firefoxCfg.profiles))
          "${prettyName'} profile '${name}' is defined in '${getAttrStringFromPath modulePath}', but not '${getAttrStringFromPath hmModulePath}'. This will have no effect."
    ) [ ] (attrNames cfg.profiles);
  };
}