CP-312082: [xapi] Push LLDP config to networkd in Nm.bring_pif_up

When bringing up the NIC of a managed physical PIF, build the networkd LLDP
record from the XAPI database and include it in the interface configuration
passed to networkd, replacing the previous hard-coded 'lldp = None'.

The effective state resolves the configuration matrix: PIF.lldp_mode of
enabled/disabled overrides pool.lldp_enabled, and 'enabled' additionally sets
'force' so networkd overrides its NIC-driver blocklist. The chassis id, system
name and description are taken from the host, and the multicast address from
pool.lldp_multicast_address.

For bond members, the bond master is plugged then the lldp settings of physical
PIFs can take effect.

Signed-off-by: Changlei Li <changlei.li@citrix.com>

Author: changlei-li

ocaml/xapi/nm.ml

@@ -119,6 +119,42 @@ let determine_other_config ~__context pif_rc net_rc =
   (pool_oc |> Listext.update_assoc net_oc |> Listext.update_assoc pif_oc)
   @ additional
 
+(* Build the LLDP configuration to push to networkd for the NIC of a managed
+   physical PIF. The effective state follows the configuration matrix: an
+   explicit PIF.lldp_mode of enabled/disabled overrides the pool-wide
+   pool.lldp_enabled, and 'enabled' additionally sets 'force' to override the
+   networkd driver blocklist. *)
+let determine_lldp ~__context pif_rc =
+  let pool = Helpers.get_pool ~__context in
+  let host = pif_rc.API.pIF_host in
+  let enabled, force =
+    match pif_rc.API.pIF_lldp_mode with
+    | `enabled ->
+        (true, true)
+    | `disabled ->
+        (false, false)
+    | `default ->
+        (Db.Pool.get_lldp_enabled ~__context ~self:pool, false)
+  in
+  let address =
+    match Db.Pool.get_lldp_multicast_address ~__context ~self:pool with
+    | `nearestbridge ->
+        Nearest_bridge
+    | `nearestnontpmrbridge ->
+        Nearest_non_tpmr_bridge
+    | `nearestcustomerbridge ->
+        Nearest_customer_bridge
+  in
+  Some
+    {
+      force
+    ; chassis_id= Db.Host.get_uuid ~__context ~self:host
+    ; system_name= Db.Host.get_name_label ~__context ~self:host
+    ; system_description= Db.Host.get_name_description ~__context ~self:host
+    ; enabled
+    ; address= [address]
+    }
+
 let create_bond ~__context bond mtu persistent =
   (* Get all information we need from the DB before doing anything that may drop our
      	 * management connection *)
@@ -144,6 +180,7 @@ let create_bond ~__context bond mtu persistent =
           ; ethtool_settings
           ; ethtool_offload
           ; persistent_i= persistent
+          ; lldp= determine_lldp ~__context (Db.PIF.get_record ~__context ~self:pif)
           }
         in
         (device, bridge, config)
@@ -436,6 +473,7 @@ let rec create_bridges ~__context pif_rc net_rc =
             ; ethtool_settings
             ; ethtool_offload
             ; persistent_i= persistent
+            ; lldp= determine_lldp ~__context pif_rc
             }
           )
         ]

ocaml/xapi/xapi_pif.ml

@@ -961,26 +961,38 @@ let set_primary_address_type ~__context ~self ~primary_address_type =
   Monitor_dbcalls_cache.clear_cache_for_pif
     ~pif_name:(Db.PIF.get_device ~__context ~self)
 
-(* LLDP is only configurable on managed physical PIFs that are not bond
-   slaves; bond masters, VLAN, tunnel and SR-IOV PIFs are excluded. *)
+(* LLDP is configurable on any managed physical PIF, i.e. a standalone
+   physical NIC or a bond member NIC. Bond masters, VLAN, tunnel and SR-IOV
+   PIFs are excluded, as they do not represent a physical NIC. *)
 let assert_lldp_configurable ~__context ~self =
   Xapi_pif_helpers.assert_pif_is_managed ~__context ~self ;
   let pif_rec = Db.PIF.get_record ~__context ~self in
   match Xapi_pif_helpers.get_pif_type pif_rec with
-  | Xapi_pif_helpers.Physical _ when pif_rec.API.pIF_bond_slave_of = Ref.null ->
+  | Xapi_pif_helpers.Physical _ ->
       ()
   | _ ->
       raise
         (Api_errors.Server_error
            (Api_errors.pif_is_not_physical, [Ref.string_of self])
         )
 
+(* LLDP runs on the physical NIC. A standalone physical PIF is plugged
+   directly; a bond member's configuration is applied by (re)plugging the
+   bond master, which brings its member NICs up. *)
+let pif_to_plug_for_lldp ~__context ~self =
+  match Db.PIF.get_bond_slave_of ~__context ~self with
+  | bond when bond <> Ref.null ->
+      Db.Bond.get_master ~__context ~self:bond
+  | _ ->
+      self
+
 let set_lldp_mode ~__context ~self ~value ~force =
   assert_lldp_configurable ~__context ~self ;
   if force || Db.PIF.get_lldp_mode ~__context ~self <> value then (
     Db.PIF.set_lldp_mode ~__context ~self ~value ;
+    let to_plug = pif_to_plug_for_lldp ~__context ~self in
     Helpers.call_api_functions ~__context (fun rpc session_id ->
-        Client.Client.PIF.plug ~rpc ~session_id ~self
+        Client.Client.PIF.plug ~rpc ~session_id ~self:to_plug
     )
   )
 

ocaml/xapi/xapi_pool.ml

@@ -3860,13 +3860,16 @@ let set_igmp_snooping_enabled ~__context ~self ~value =
 let set_lldp_enabled ~__context ~self ~value ~force =
   if force || Db.Pool.get_lldp_enabled ~__context ~self <> value then (
     Db.Pool.set_lldp_enabled ~__context ~self ~value ;
-    (* LLDP applies only to managed physical PIFs that are not bond slaves. *)
+    (* LLDP runs on physical NICs. Standalone physical PIFs are plugged
+       directly; bonded NICs are (re)configured by plugging the bond master.
+       Both apply the per-PIF PIF.lldp_mode against the new pool setting. *)
     let pifs =
       Db.PIF.get_all_records ~__context
       |> List.filter (fun (_, r) ->
              r.API.pIF_managed
-             && r.API.pIF_physical
-             && r.API.pIF_bond_slave_of = Ref.null
+             && (r.API.pIF_physical && r.API.pIF_bond_slave_of = Ref.null
+                || r.API.pIF_bond_master_of <> []
+                )
          )
       |> List.map fst
     in