CP-312083: [xapi] Expose received LLDP neighbour on PIF_metrics

Monitor_dbcalls now reads iface_stats.lldp_neighbor from /dev/shm/network_stats, encodes it as a (system-name, port-id, port-description) map, and writes it to PIF_metrics.lldp_neighbor for the matching PIF on the host. A per-device cache (mirroring the pif/bond caches) ensures the database is only updated when the neighbour changes; an empty map is written when no neighbour is seen.

Author: changlei-li

ocaml/xapi/monitor_dbcalls.ml

@@ -22,6 +22,17 @@ module D = Debug.Make (struct let name = "monitor_dbcalls" end)
 
 open D
 
+(* Encode a received LLDP neighbour as a (key, value) map for
+   PIF_metrics.lldp_neighbor, omitting fields that were not advertised. *)
+let lldp_map_of_rx (rx : Network_stats.lldp_rx) : (string * string) list =
+  List.filter_map
+    (fun (k, v) -> Option.map (fun x -> (k, x)) v)
+    [
+      ("system-name", rx.Network_stats.system_name)
+    ; ("port-id", rx.Network_stats.port_id)
+    ; ("port-description", rx.Network_stats.port_description)
+    ]
+
 let get_pif_and_bond_changes () =
   (* Read fresh PIF information from networkd. *)
   let open Network_stats in
@@ -42,7 +53,14 @@ let get_pif_and_bond_changes () =
           ; pif_device_id= stat.device_id
           }
         in
-        Hashtbl.add pifs_tmp pif.pif_name pif
+        Hashtbl.add pifs_tmp pif.pif_name pif ;
+        Hashtbl.replace lldp_neighbor_tmp dev
+          (match stat.lldp_neighbor with
+          | Some rx ->
+              lldp_map_of_rx rx
+          | None ->
+              []
+          )
       )
     )
     stats ;
@@ -52,8 +70,12 @@ let get_pif_and_bond_changes () =
   let bond_changes =
     get_updates_map ~before:bonds_links_up_cached ~after:bonds_links_up_tmp
   in
+  (* Check if any received LLDP neighbour has changed since our last reading. *)
+  let lldp_changes =
+    get_updates_map ~before:lldp_neighbor_cached ~after:lldp_neighbor_tmp
+  in
   (* Return lists of changes. *)
-  (pif_changes, bond_changes)
+  (pif_changes, bond_changes, lldp_changes)
 
 let set_pif_changes ?except () =
   with_lock pifs_cached_m (fun _ ->
@@ -66,15 +88,22 @@ let set_bond_changes ?except () =
         ~target:bonds_links_up_cached ()
   )
 
+let set_lldp_changes ?except () =
+  with_lock lldp_neighbor_cached_m (fun _ ->
+      transfer_map ?except ~source:lldp_neighbor_tmp
+        ~target:lldp_neighbor_cached ()
+  )
+
 (* This function updates the database for all the slowly changing properties
  * of host memory, VM memory, PIFs, and bonds.
  *)
 let pifs_update_fn () =
-  let pif_changes, bond_changes = get_pif_and_bond_changes () in
+  let pif_changes, bond_changes, lldp_changes = get_pif_and_bond_changes () in
   Server_helpers.exec_with_new_task "updating PIFs" (fun __context ->
       let host = Helpers.get_localhost ~__context in
       let issues = ref [] in
       let keeps = ref [] in
+      let keeps_lldp = ref [] in
       List.iter
         (fun (bond, links_up) ->
           try
@@ -112,6 +141,31 @@ let pifs_update_fn () =
           set_pif_changes ()
         with e -> issues := e :: !issues
       ) ;
+      List.iter
+        (fun (dev, neighbor) ->
+          try
+            match
+              Db.PIF.get_records_where ~__context
+                ~expr:
+                  (And
+                     ( Eq (Field "host", Literal (Ref.string_of host))
+                     , Eq (Field "device", Literal dev)
+                     )
+                  )
+            with
+            | (_, pif_rec) :: _ ->
+                let metrics = pif_rec.API.pIF_metrics in
+                if Db.is_valid_ref __context metrics then
+                  Db.PIF_metrics.set_lldp_neighbor ~__context ~self:metrics
+                    ~value:neighbor
+            | [] ->
+                ()
+          with e ->
+            issues := e :: !issues ;
+            keeps_lldp := dev :: !keeps_lldp
+        )
+        lldp_changes ;
+      set_lldp_changes ~except:!keeps_lldp () ;
       List.iter
         (function
           | Db_exn.Read_missing_uuid _ ->

ocaml/xapi/monitor_dbcalls_cache.ml

@@ -30,6 +30,16 @@ let bonds_links_up_cached : (string, int) Hashtbl.t = Hashtbl.create 10
 
 let bonds_links_up_tmp : (string, int) Hashtbl.t = Hashtbl.create 10
 
+(* A cache mapping PIF (device) names to their received LLDP neighbour, encoded
+   as a (key, value) map. *)
+let lldp_neighbor_cached_m : Mutex.t = Mutex.create ()
+
+let lldp_neighbor_cached : (string, (string * string) list) Hashtbl.t =
+  Hashtbl.create 10
+
+let lldp_neighbor_tmp : (string, (string * string) list) Hashtbl.t =
+  Hashtbl.create 10
+
 (* A cache mapping vm_uuids to actual memory. *)
 let vm_memory_cached_m : Mutex.t = Mutex.create ()
 
@@ -60,6 +70,10 @@ let clear_cache_for_pif ~pif_name =
   with_lock pifs_cached_m (fun _ ->
       Hashtbl.remove pifs_cached pif_name ;
       Hashtbl.remove pifs_tmp pif_name
+  ) ;
+  with_lock lldp_neighbor_cached_m (fun _ ->
+      Hashtbl.remove lldp_neighbor_cached pif_name ;
+      Hashtbl.remove lldp_neighbor_tmp pif_name
   )
 
 (** [clear_cache_for_vm] removes any current cache for VM with [vm_uuid],
@@ -86,6 +100,8 @@ let clear_cache () =
   safe_clear ~cache:pifs_cached ~tmp:pifs_tmp ~lock:pifs_cached_m ;
   safe_clear ~cache:bonds_links_up_cached ~tmp:bonds_links_up_tmp
     ~lock:bonds_links_up_cached_m ;
+  safe_clear ~cache:lldp_neighbor_cached ~tmp:lldp_neighbor_tmp
+    ~lock:lldp_neighbor_cached_m ;
   safe_clear ~cache:vm_memory_cached ~tmp:vm_memory_tmp ~lock:vm_memory_cached_m ;
   with_lock host_memory_m (fun _ ->
       host_memory_free_cached := Int64.zero ;