commons/build.gradle at master · chillenious/commons · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
buildscript {

    repositories {
        jcenter()
    }

    dependencies {
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7"
    }
}

allprojects {

    group = 'com.chillenious.commons'
    version = currentVersion

    apply plugin: 'maven'
    apply plugin: 'maven-publish'
    apply plugin: 'idea'

    apply plugin: 'com.jfrog.bintray'

    ext.publish = true

    bintray {
        user = bintray_user
        key = bintray_api_key
        configurations = ['archives']
        dryRun = false // Whether to run this as dry-run, without deploying
        publish = true //If version should be auto published after an upload
        pkg {
            repo = 'maven'
            name = 'chillenious-commons'
            desc = 'Little bag of tools for Guice based projects'
            websiteUrl = 'https://github.com/chillenious/commons'
            issueTrackerUrl = 'https://github.com/chillenious/commons/issues'
            vcsUrl = 'https://github.com/chillenious/commons.git'
            licenses = ['MIT']
            labels = ['Guice', 'Java', 'jOOQ', 'bibliolabs', 'onespot']
            publicDownloadNumbers = true
        }
    }
}

subprojects {

    apply plugin: 'java'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    idea {
        module {
            downloadSources = true
        }
    }

    task sourceJar(type: Jar) {
        from sourceSets.main.allSource
        classifier = 'sources'
    }

    configurations {
        archives
    }

    artifacts {
        archives sourceJar
    }

    repositories {
        jcenter()
        mavenLocal()
        mavenCentral()
        maven { url "http://clojars.org/repo" }
    }

    buildscript {

        repositories {
            mavenLocal()
            mavenCentral()
            jcenter()
            maven { url "http://clojars.org/repo" }
        }

        dependencies {
            classpath 'org.jfrog.buildinfo:build-info-extractor-gradle:3.0.1'
            classpath 'net.saliman:gradle-properties-plugin:1.4.2'
        }
    }
}

// http://www.gradle.org/docs/current/userguide/gradle_wrapper.html
task wrapper(type: Wrapper) {
    gradleVersion = '2.1'
}

idea.project.ipr {
    withXml { provider ->
        provider.node.component.find { it.@name == 'VcsDirectoryMappings' }.mapping.@vcs = 'Git'
        provider.node.component.find { it.@name == 'ProjectRootManager' }.@"assert-jdk-15" = 'true'
        provider.node.component.find { it.@name == 'ProjectRootManager' }.@languageLevel = 'JDK_1_8'
    }
}