chiri/flake.nix at master · chiriapp/chiri · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
{
  description = "Chiri - a cross-platform CalDAV task management app. Currently in very early alpha!";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      rust-overlay,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };

        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = [
            "rust-src"
            "rust-analyzer"
          ];
          targets = pkgs.lib.optionals pkgs.stdenv.isDarwin [
            "x86_64-apple-darwin"
          ];
        };

        # macOS-specific dependencies for dev shell
        darwinDevDeps =
          with pkgs;
          lib.optionals stdenv.isDarwin [
            libiconv
            apple-sdk_14
          ];

        # Linux-specific dependencies for dev shell
        linuxDevDeps =
          with pkgs;
          lib.optionals stdenv.isLinux [
            webkitgtk_4_1
            gtk3
            libsoup_3
            glib
            gdk-pixbuf
            pango
            cairo
            atk
            libayatana-appindicator
          ];

      in
      {
        packages =
          let
            source = pkgs.callPackage ./nix/package.nix { src = ./.; };
            bin = pkgs.callPackage ./nix/package-bin.nix { };
          in
          {
            default = if pkgs.stdenv.hostPlatform.isDarwin then bin else source;
            source = source;
            bin = bin;
          };

        devShells.default = pkgs.mkShell {
          buildInputs =
            with pkgs;
            [
              # Rust
              rustToolchain
              cargo-tauri

              # Node.js
              nodejs_20
              pnpm

              # Build tools
              pkg-config
              openssl
              cmake
              ninja

              # Tauri dependencies
              libiconv
            ]
            ++ darwinDevDeps
            ++ linuxDevDeps;

          shellHook = ''
            echo "Chiri dev environment"
            echo ""
            echo "commands:"
            echo "  just install    - install dependencies"
            echo "  just dev        - start development server"
            echo "  just build      - build app"
            echo "  nix build       - build app with nix"
            echo ""
            echo "CEF build:"
            echo "  just build-cef  - build with Chromium"
            echo "  just dev-cef    - dev mode with Chromium"
            echo ""
          '';

          # Required for Tauri on macOS
          RUST_BACKTRACE = 1;

          # For pkg-config to find libraries
          PKG_CONFIG_PATH = pkgs.lib.makeSearchPath "lib/pkgconfig" (
            with pkgs;
            [
              openssl.dev
            ]
            ++ linuxDevDeps
          );
        };
      }
    );
}