Initial Commit

Author: duplidev

.gitignore

@@ -0,0 +1,22 @@
+# eclipse
+bin
+*.launch
+.settings
+.metadata
+.classpath
+.project
+
+# idea
+out
+*.ipr
+*.iws
+*.iml
+.idea
+
+# gradle
+build
+.gradle
+
+# other
+eclipse
+run

1.7.10/build.gradle

@@ -0,0 +1,20 @@
+/** The root of the build. Exposed for flexibility, but you shouldn't edit it
+    unless you have to. Edit project.gradle instead. */
+
+buildscript {
+	repositories {
+		mavenCentral()
+		maven {
+			name = "forge"
+			url = "https://maven.minecraftforge.net/"
+		}
+		maven {
+			url = "https://jitpack.io"
+		}
+	}
+	dependencies {
+		classpath 'com.github.GTNewHorizons:ForgeGradle:1.2.11'
+	}
+}
+
+apply from: "buildscript/forge-1.7.gradle"

1.7.10/buildscript/forge-1.7-mixin.gradle

@@ -0,0 +1,55 @@
+
+/** Applying this file in a Forge build will imbue it with the powers of Mixin. */
+
+repositories {
+	maven {
+		name = 'sponge'
+		url = 'https://repo.spongepowered.org/maven/'
+	}
+}
+
+def embedMixin = !project.hasProperty("nomixin");
+
+if(!embedMixin){
+	project.version += "+nomixin"
+}
+
+dependencies {
+	if(embedMixin){
+		embed('org.spongepowered:mixin:0.7.11-SNAPSHOT'){
+			setTransitive false
+		}
+	} else {
+		compile('org.spongepowered:mixin:0.7.11-SNAPSHOT'){
+			setTransitive false
+		}
+	}
+}
+
+ext.outRefMapFile = "mixins.cloudmc.refmap.json"
+
+jar {
+	manifest {
+        attributes (
+			'MixinConfigs': "mixins.cloudmc.json",
+            'TweakClass': 'org.spongepowered.asm.launch.MixinTweaker',
+            'TweakOrder': 0,
+			
+			// If these two are not set, Forge will not detect the mod, it will only run the mixins
+            'FMLCorePluginContainsFMLMod': 'true',
+            'ForceLoadAsMod': 'true',
+		)
+	}
+	
+	from outRefMapFile;
+}
+
+def outSrgFile = "${tasks.compileJava.temporaryDir}/outSrg.srg"
+
+afterEvaluate {
+    tasks.compileJava.options.compilerArgs += ["-AreobfSrgFile=${tasks.reobf.srg}", "-AoutSrgFile=${outSrgFile}", "-AoutRefMapFile=${outRefMapFile}"];
+}
+
+reobf {
+    addExtraSrgFile outSrgFile
+}

1.7.10/buildscript/forge-1.7.gradle

@@ -0,0 +1,62 @@
+/** Common code for Forge 1.7.10 builds */
+
+apply plugin: 'forge'
+
+version = "1.3.2"
+group = "dev.cloudmc"
+archivesBaseName = "cloudmc"
+
+minecraft {
+    version = "${project.minecraft_version}-${project.forge_version}"
+    runDir = "run"
+	replace '@VERSION@', project.version
+}
+
+sourceCompatibility = 1.8
+targetCompatibility = 1.8
+
+configurations {
+    embed
+    compile.extendsFrom(embed)
+	shade
+    compile.extendsFrom(shade)
+}
+
+if(project.enable_mixin.toBoolean()) {
+	apply from: "buildscript/forge-1.7-mixin.gradle"
+}
+
+project.ext.override_dependencies = false
+
+jar {
+    from(sourceSets.main.output);
+
+    // embed libraries in jar
+    from configurations.embed.collect {
+        exclude '**/LICENSE', '**/LICENSE.txt'
+        it.isDirectory() ? it : zipTree(it)
+    }
+	
+	configurations.shade.each { dep ->
+        from(project.zipTree(dep)){
+            exclude '**/LICENSE', '**/LICENSE.txt', 'META-INF', 'META-INF/**'
+        }
+    }
+}
+
+processResources {
+    // This will ensure that this task is redone when the versions or any
+	// user-defined properties change.
+    inputs.property "version", version
+    inputs.property "mcversion", project.minecraft.version
+	inputs.properties project.ext.getProperties()
+
+    filesMatching('*.info') {
+        expand project.properties
+    }
+}
+
+// Ensures that the encoding of source files is set to UTF-8, see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
+tasks.withType(JavaCompile) {
+    options.encoding = "UTF-8"
+}

1.7.10/gradle/wrapper/gradle-wrapper.jar

@@ -0,0 +1,5 @@
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-4.4.1-bin.zip
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists