COMP: Add CMake configuration for Qt6 alongside Qt5

Enable building CTK with either Qt 5 or Qt 6 by updating CMake
configuration and Qt component selection:

* Allow `CTK_QT_VERSION` to be 5 or 6 (defaulting to 6 when `Qt6_DIR`
  is defined, otherwise 5), and validate its value.
* Use common Qt APIs for both Qt 5 and Qt 6 where available
  (e.g. `qt_add_resources`, `qt_create_translation`,
  `qt_wrap_cpp`, plugin setup helpers).
* Add required Qt 6 components when building with Qt 6, including
  `Core5Compat`, `StateMachine`, and `OpenGLWidgets`, while preserving
  existing Qt 5 behavior.
* Restrict use of deprecated or Qt 5–only components:

  * Require `XmlPatterns` only with Qt 5.
  * Force `CTK_USE_QTTESTING` OFF with Qt 6, since QtTesting depends on
    `XmlPatterns`.
  * Disable CommandLine Modules components and applications that depend
    on `XmlPatterns` for Qt 6 builds.
  * Disable DICOM Application Hosting plug-ins and example applications
    that depend on QtSOAP for Qt 6 builds.
* Update core, widgets, VTK widgets, and test CMakeLists to link against
  the appropriate Qt 5/Qt 6 targets based on `CTK_QT_VERSION`.

Co-authored-by: Stefan Dinkelacker <s.dinkelacker@dkfz-heidelberg.de>
Co-authored-by: jporcher <jean.porcherot@cea.fr>
Co-authored-by: Hans Johnson <hans-johnson@uiowa.edu>

Author: 4 people

CMake/ctkFunctionGeneratePluginManifest.cmake

@@ -104,7 +104,7 @@ function(ctkFunctionGeneratePluginManifest MANIFEST_QRC_FILEPATH_VAR)
   if(MY_SKIP_QT5_ADD_RESOURCES)
     set(${MANIFEST_QRC_FILEPATH_VAR} ${_manifest_qrc_filepath} PARENT_SCOPE)
   else()
-    if(CTK_QT_VERSION VERSION_EQUAL "5")
+    if(CTK_QT_VERSION MATCHES "^(5|6)$")
       qt_add_resources(_qrc_src ${_manifest_qrc_filepath})
     else()
       message(FATAL_ERROR "Support for Qt${CTK_QT_VERSION} is not implemented")

CMake/ctkMacroBuildPlugin.cmake

@@ -193,7 +193,7 @@ macro(ctkMacroBuildPlugin)
   if(MY_TRANSLATIONS)
     set_source_files_properties(${MY_TRANSLATIONS}
                                 PROPERTIES OUTPUT_LOCATION ${_translations_dir})
-  if(CTK_QT_VERSION VERSION_EQUAL "5")
+  if(CTK_QT_VERSION MATCHES "^(5|6)$")
       qt_create_translation(_plugin_qm_files ${MY_SRCS} ${MY_UI_FORMS} ${MY_TRANSLATIONS})
   else()
     message(FATAL_ERROR "Support for Qt${CTK_QT_VERSION} is not implemented")

CMake/ctkMacroBuildQtPlugin.cmake

@@ -119,6 +119,8 @@ macro(ctkMacroBuildQtPlugin)
   set(compile_flags "-DQT_PLUGIN")
   if(CTK_QT_VERSION VERSION_EQUAL "5")
     set(compile_flags "${compile_flags} -DHAVE_QT5")
+  elseif(CTK_QT_VERSION VERSION_EQUAL "6")
+    set(compile_flags "${compile_flags} -DHAVE_QT6")
   else()
     message(FATAL_ERROR "Support for Qt${CTK_QT_VERSION} is not implemented")
   endif()

CMake/ctkMacroSetupPlugins.cmake

@@ -103,7 +103,7 @@ macro(ctkMacroSetupPlugins )
 
   # Set the variable QT_INSTALLED_LIBRARY_DIR that contains all
   # Qt shared libraries
-  if(CTK_QT_VERSION VERSION_EQUAL "5")
+  if(CTK_QT_VERSION MATCHES "^(5|6)$")
     if(WIN32)
       get_target_property(_qt_moc_executable Qt${CTK_QT_VERSION}::moc LOCATION)
       get_filename_component(QT_INSTALLED_LIBRARY_DIR ${_qt_moc_executable} PATH)

CMake/ctkMacroSetupQt.cmake

@@ -21,12 +21,19 @@
 #! \ingroup CMakeUtilities
 macro(ctkMacroSetupQt)
 
-  if(CTK_QT_VERSION VERSION_EQUAL "5")
+  if(CTK_QT_VERSION MATCHES "^(5|6)$")
     cmake_minimum_required(VERSION 3.20.6)
     find_package(Qt${CTK_QT_VERSION} COMPONENTS Core)
 
     set(CTK_QT_COMPONENTS Core)
 
+    if(CTK_QT_VERSION VERSION_GREATER "5")
+      list(APPEND CTK_QT_COMPONENTS
+        Core5Compat # For QRegExp used in "ctkCommandLineParser.cpp"
+        StateMachine # For QAbstractTransition used in "ctkWorkflowTransitions.h"
+        )
+    endif()
+
     # See https://github.com/commontk/CTK/wiki/Maintenance#updates-of-required-qt-components
 
     if(CTK_LIB_Widgets
@@ -46,7 +53,9 @@ macro(ctkMacroSetupQt)
       OR CTK_LIB_CommandLineModules/Core
       OR CTK_LIB_Scripting/Python/Core_PYTHONQT_WRAP_QTXMLPATTERNS
       )
-      list(APPEND CTK_QT_COMPONENTS XmlPatterns)
+      if(CTK_QT_VERSION VERSION_EQUAL "5")
+        list(APPEND CTK_QT_COMPONENTS XmlPatterns)
+      endif()
     endif()
 
     if(CTK_APP_ctkCommandLineModuleExplorer
@@ -82,6 +91,10 @@ macro(ctkMacroSetupQt)
 
     if(CTK_LIB_Widgets)
       list(APPEND CTK_QT_COMPONENTS OpenGL)
+
+      if(CTK_QT_VERSION VERSION_GREATER "5")
+        list(APPEND CTK_QT_COMPONENTS OpenGLWidgets)
+      endif()
     endif()
 
     if(CTK_APP_ctkCommandLineModuleExplorer
@@ -108,6 +121,10 @@ macro(ctkMacroSetupQt)
 
     if(CTK_BUILD_QTDESIGNER_PLUGINS)
       list(APPEND CTK_QT_COMPONENTS Designer)
+
+      if(CTK_QT_VERSION VERSION_GREATER "5")
+        list(APPEND CTK_QT_COMPONENTS DesignerComponentsPrivate)
+      endif()
     endif()
 
     if(CTK_LIB_XNAT/Core
@@ -118,18 +135,28 @@ macro(ctkMacroSetupQt)
       list(APPEND CTK_QT_COMPONENTS Network)
     endif()
 
-    find_package(Qt5 COMPONENTS ${CTK_QT_COMPONENTS} REQUIRED)
+    if(CTK_QT_VERSION VERSION_EQUAL "5")
+      find_package(Qt5 COMPONENTS ${CTK_QT_COMPONENTS} REQUIRED)
+      mark_as_superbuild(Qt5_DIR) # Qt 5
+
+      set(_major ${Qt5_VERSION_MAJOR})
+      set(_minor ${Qt5_VERSION_MINOR})
+      set(_patch ${Qt5_VERSION_PATCH})
 
-    mark_as_superbuild(Qt5_DIR) # Qt 5
+    elseif(CTK_QT_VERSION VERSION_EQUAL "6")
+      find_package(Qt6 COMPONENTS ${CTK_QT_COMPONENTS} REQUIRED)
+      mark_as_superbuild(Qt6_DIR) # Qt 6
+
+      set(_major ${Qt6_VERSION_MAJOR})
+      set(_minor ${Qt6_VERSION_MINOR})
+      set(_patch ${Qt6_VERSION_PATCH})
+    endif()
 
     # XXX Backward compatible way
     if(DEFINED CMAKE_PREFIX_PATH)
       mark_as_superbuild(CMAKE_PREFIX_PATH) # Qt 5
     endif()
 
-    set(_major ${Qt5_VERSION_MAJOR})
-    set(_minor ${Qt5_VERSION_MINOR})
-    set(_patch ${Qt5_VERSION_PATCH})
 
     ctk_list_to_string(", " "${CTK_QT_COMPONENTS}" comma_separated_module_list)
     message(STATUS "Configuring CTK with Qt ${_major}.${_minor}.${_patch} (using modules: ${comma_separated_module_list})")

CMakeLists.txt

@@ -105,10 +105,18 @@ mark_as_advanced(CTK_SUPERBUILD)
 #-----------------------------------------------------------------------------
 # Qt version
 #
-set(CTK_QT_VERSION "5" CACHE STRING "Expected Qt version")
+if(DEFINED Qt6_DIR)
+  set(_default_qt_major_version "6")
+else()
+  set(_default_qt_major_version "5")
+endif()
+set(CTK_QT_VERSION "${_default_qt_major_version}" CACHE STRING "Expected major Qt version")
 mark_as_advanced(CTK_QT_VERSION)
-set_property(CACHE CTK_QT_VERSION PROPERTY STRINGS 5)
+set_property(CACHE CTK_QT_VERSION PROPERTY STRINGS 5 6)
 mark_as_superbuild(CTK_QT_VERSION)
+if(NOT "${CTK_QT_VERSION}" MATCHES "^(5|6)$")
+  message(FATAL_ERROR "CTK_QT_VERSION must be 5 or 6.")
+endif()
 
 #-----------------------------------------------------------------------------
 # Output directories.
@@ -321,6 +329,14 @@ endif()
 #
 option(CTK_USE_QTTESTING "Enable/Disable QtTesting" OFF)
 mark_as_advanced(CTK_USE_QTTESTING)
+if(NOT CTK_QT_VERSION VERSION_EQUAL "5")
+  # Forcing to OFF as "QtTesting" depends on XmlPatterns Qt component not available with Qt 6
+  if(DEFINED CTK_USE_QTTESTING AND CTK_USE_QTTESTING)
+    unset(CTK_USE_QTTESTING CACHE)
+    set(CTK_USE_QTTESTING OFF)
+    message(WARNING "Forcing option [CTK_USE_QTTESTING] to OFF as QtTesting depends on XmlPatterns Qt component not available with Qt ${CTK_QT_VERSION}")
+  endif()
+endif()
 mark_as_superbuild(CTK_USE_QTTESTING)
 
 #-----------------------------------------------------------------------------
@@ -503,6 +519,7 @@ ctk_lib_option(Visualization/VTK/Core
 ctk_lib_option(Visualization/VTK/Widgets
                "Build the VTK Widgets library" OFF)
 
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_lib_option(CommandLineModules/Core
                "Build the Command Line Module core library" OFF)
 
@@ -521,6 +538,16 @@ ctk_lib_option(CommandLineModules/Backend/LocalProcess
 ctk_lib_option(CommandLineModules/Backend/FunctionPointer
                "Build the Command Line Module back-end for function pointers" OFF)
 
+else()
+  # "CommandLineModules/Core" depends on XmlPatterns Qt component not available with Qt 6
+  set(CTK_LIB_CommandLineModules/Core OFF)
+  set(CTK_LIB_CommandLineModules/Frontend/QtWebKit OFF)
+  set(CTK_LIB_CommandLineModules/Frontend/QtGui OFF)
+  set(CTK_LIB_CommandLineModules/Backend/XMLChecker OFF)
+  set(CTK_LIB_CommandLineModules/Backend/LocalProcess OFF)
+  set(CTK_LIB_CommandLineModules/Backend/FunctionPointer OFF)
+endif()
+
 ctk_lib_option(XNAT/Core
                "Build the XNAT Core library" OFF)
 
@@ -574,6 +601,7 @@ ctk_app_option(ctkDICOMQueryRetrieve
                "Build the DICOM example application" OFF
                CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
 
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_app_option(ctkDICOMHost
                "Build the DICOM application host example application" OFF
                CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES)
@@ -585,6 +613,12 @@ ctk_app_option(ctkExampleHost
 ctk_app_option(ctkExampleHostedApp
                "Build the DICOM example application" OFF
                CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES)
+else()
+  # Host apps depends on "org.commontk.dah.core" which depends on QtSOAP not available with Qt 6
+  set(CTK_APP_ctkDICOMHost OFF)
+  set(CTK_APP_ctkExampleHost OFF)
+  set(CTK_APP_ctkExampleHostedApp OFF)
+endif()
 
 if(FALSE)
 # Since EventBusDemo depends on qxmlrpc that is lacking Qt5 support, it is excluded.
@@ -593,9 +627,14 @@ ctk_app_option(ctkEventBusDemo
                CTK_ENABLE_PluginFramework AND CTK_BUILD_EXAMPLES)
 endif()
 
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_app_option(ctkCommandLineModuleExplorer
                "Build the Command Line Module Explorer" OFF
                CTK_BUILD_EXAMPLES)
+else()
+  # "ctkCommandLineModuleExplorer" depends on "CommandLineModules/Core" which depends on XmlPatterns Qt component not available with Qt 6
+  set(CTK_APP_ctkCommandLineModuleExplorer OFF)
+endif()
 
 # We use the CTKWidgets library together with the Qt Designer plug-in
 # in ctkCommandLineModuleExplorer, so enabling the options here.
@@ -672,6 +711,7 @@ ctk_plugin_option(org.commontk.plugingenerator.ui
                   CTK_APP_ctkPluginGenerator)
 
 # Plug-ins related to DICOM WG23 (Application Hosting)
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_plugin_option(org.commontk.dah.core "Build the org.commontk.dah.core plugin." OFF)
 ctk_plugin_option(org.commontk.dah.hostedapp "Build the org.commontk.dah.hostedapp plugin." OFF
                   CTK_ENABLE_DICOMApplicationHosting)
@@ -681,14 +721,31 @@ ctk_plugin_option(org.commontk.dah.host "Build the org.commontk.dah.host plugin.
 ctk_plugin_option(org.commontk.dah.exampleapp
                   "Build the org.commontk.dah.exampleapp plugin." OFF
                   CTK_APP_ctkExampleHostedApp)
+else()
+  # "org.commontk.dah.core" and its dependent plugins depend on QtSOAP not available with Qt 6
+  set(CTK_PLUGIN_org.commontk.dah.core OFF)
+  set(CTK_PLUGIN_org.commontk.dah.hostedapp OFF)
+  set(CTK_PLUGIN_org.commontk.dah.host OFF)
+  set(CTK_PLUGIN_org.commontk.dah.exampleapp OFF)
+endif()
 
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_plugin_option(org.commontk.dah.cmdlinemoduleapp
                   "Build the org.commontk.dah.cmdlinemoduleapp plugin." OFF
                   CTK_APP_ctkCommandLineModuleApp)
+else()
+  # "org.commontk.dah.cmdlinemoduleapp" depends on "CommandLineModules/Core" which depends on XmlPatterns Qt component not available with Qt 6
+  set(CTK_PLUGIN_org.commontk.dah.cmdlinemoduleapp OFF)
+endif()
 
+if(CTK_QT_VERSION VERSION_EQUAL "5")
 ctk_plugin_option(org.commontk.dah.examplehost
                   "Build the org.commontk.dah.examplehost plugin." OFF
                   CTK_APP_ctkExampleHost)
+else()
+  # "org.commontk.dah.examplehost" depends on "org.commontk.dah.core" which depends on QtSOAP not available with Qt 6
+  set(CTK_PLUGIN_org.commontk.dah.examplehost OFF)
+endif()
 
 # Plug-ins related to the EventBus demo application
 if(FALSE)

Libs/Core/CMakeLists.txt

@@ -129,6 +129,12 @@ set(KIT_target_libraries)
 ctkFunctionGetTargetLibraries(KIT_target_libraries)
 
 list(APPEND KIT_target_libraries Qt${CTK_QT_VERSION}::Core)
+if(CTK_QT_VERSION VERSION_GREATER "5")
+  list(APPEND KIT_target_libraries
+    Qt${CTK_QT_VERSION}::Core5Compat # For QRegExp
+    Qt${CTK_QT_VERSION}::StateMachine # For QAbstractTransition used in "ctkWorkflow" classes
+    )
+endif()
 
 ctkMacroBuildLib(
   NAME ${PROJECT_NAME}

Libs/PluginFramework/Documentation/Snippets/EventAdmin-Intro/files.cmake

@@ -8,7 +8,7 @@ set(_moc_files
 )
 
 foreach(_moc_file ${_moc_files})
-  if(CTK_QT_VERSION VERSION_EQUAL "5")
+  if(CTK_QT_VERSION MATCHES "^(5|6)$")
     qt_wrap_cpp(snippet_src_files EventAdmin-Intro/${_moc_file}
       OPTIONS -f${CMAKE_CURRENT_SOURCE_DIR}/EventAdmin-Intro/${_moc_file})
   else()

Libs/Visualization/VTK/Widgets/target_libraries.cmake

@@ -11,6 +11,9 @@ set(target_libraries
   )
 if(CTK_QT_VERSION VERSION_EQUAL "5")
   list(APPEND target_libraries Qt5Network_LIBRARIES Qt5WebKit_LIBRARIES)
+elseif(CTK_QT_VERSION VERSION_EQUAL "6")
+  # Skip workaround originally introduced to support Qt5.
+  # See 47b34216 ("Add support for Qt5", 2013-09-20)
 else()
   message(FATAL_ERROR "Support for this Qt is not implemented")
 endif()

Libs/Widgets/CMakeLists.txt

@@ -247,6 +247,11 @@ list(APPEND KIT_target_libraries
   Qt${CTK_QT_VERSION}::Xml
   Qt${CTK_QT_VERSION}::OpenGL
   )
+if(CTK_QT_VERSION VERSION_GREATER "5")
+  list(APPEND KIT_target_libraries
+    Qt${CTK_QT_VERSION}::OpenGLWidgets
+    )
+endif()
 
 # A player and a translator must be added for custom Qt widgets
 if(CTK_USE_QTTESTING)