jindong/jindong-compose/build.gradle.kts at a9ca33737384da73fd615035a4e6a5ce57972a7a · compose-jindong/jindong · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
/*
 * Copyright (C) 2026 compose-jindong
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
    alias(libs.plugins.kotlinMultiplatform)
    alias(libs.plugins.android.kotlin.multiplatform.library)
    alias(libs.plugins.compose.compiler)
    alias(libs.plugins.vanniktech.mavenPublish)
    alias(libs.plugins.kotest)
    alias(libs.plugins.ksp)
    alias(libs.plugins.binaryCompatibilityValidator)
}

apiValidation {
    @OptIn(kotlinx.validation.ExperimentalBCVApi::class)
    klib {
        enabled = true
    }
}

group = "io.github.compose-jindong"
version = "1.1.1"

kotlin {
    androidLibrary {
        namespace = "io.github.compose.jindong"
        compileSdk = libs.versions.android.compileSdk.get().toInt()
        minSdk = libs.versions.android.minSdk.get().toInt()

        compilations.configureEach {
            compileTaskProvider.configure {
                compilerOptions {
                    jvmTarget.set(JvmTarget.JVM_17)
                }
            }
        }
    }
    iosX64()
    iosArm64()
    iosSimulatorArm64()

    sourceSets {
        commonMain.dependencies {
            api(project(":jindong-core"))
            implementation(libs.compose.runtime)
            implementation(libs.kotlinx.coroutines.core)
        }

        androidMain.dependencies {
            val composeBom = project.dependencies.platform(libs.androidx.compose.bom)
            implementation(composeBom)
            implementation(libs.androidx.compose.ui)
        }

        commonTest.dependencies {
            implementation(libs.kotest.framework.engine)
            implementation(libs.kotest.assertions.core)
            implementation(libs.compose.ui.test)
            implementation(libs.kotlinx.coroutines.test)
        }
    }
}

mavenPublishing {
    publishToMavenCentral()

    signAllPublications()

    coordinates(group.toString(), "jindong-compose", version.toString())

    pom {
        name = "Jindong Compose"
        description = "Declarative Haptic Feedback Library using Compose Runtime for Kotlin Multiplatform"
        inceptionYear = "2026"
        url = "https://github.com/compose-jindong/jindong"
        licenses {
            license {
                name = "Apache-2.0"
                url = "https://www.apache.org/licenses/LICENSE-2.0"
            }
        }
        developers {
            developer {
                id = "l2hyunwoo"
                name = "Hyunwoo Lee"
            }
            developer {
                id = "wisemuji"
                name = "Suhyeon Kim"
            }
        }
        scm {
            url = "https://github.com/compose-jindong/jindong"
            connection = "scm:git:git://github.com/compose-jindong/jindong.git"
            developerConnection = "scm:git:ssh://github.com/compose-jindong/jindong.git"
        }
    }
}