Add pure SPARQL federation example queries for Uniprot

Author: rubensworks

queries/federation/rhea-enzymes-transporters.sparql

@@ -0,0 +1,25 @@
+# Select all Rhea reactions linked to protein sequences (enzymes and transporters) in UniProtKB
+# Datasources: https://sparql.uniprot.org/sparql https://sparql.rhea-db.org/sparql
+
+PREFIX rh: <http://rdf.rhea-db.org/>
+PREFIX up: <http://purl.uniprot.org/core/>
+
+# Query 12
+# Select all Rhea reactions used to annotate enzyme sequences in UniProtKB
+# return the number of UniProtKB entries
+# Federated query using a service to UniProt SPARQL endpoint
+# 
+# This query corresponds to the Rhea website query:
+# https://www.rhea-db.org/rhea?query=uniprot:*
+# 
+SELECT ?uniprotCount ?rhea ?accession ?equation 
+WHERE {
+  { 
+  	SELECT ?rhea (count(?uniprot) as ?uniprotCount) {
+      ?uniprot up:annotation/up:catalyticActivity/up:catalyzedReaction ?rhea . 
+  	}
+  	GROUP BY ?rhea
+  }
+  ?rhea rh:accession ?accession .
+  ?rhea rh:equation ?equation .
+}

queries/federation/rhea-organism.sparql

@@ -0,0 +1,29 @@
+# Select all Rhea reactions used in UniProtKB/Swiss-Prot for a given organism (NCBI taxonomy ID)
+# Datasources: https://sparql.uniprot.org/sparql https://sparql.rhea-db.org/sparql
+
+PREFIX rh: <http://rdf.rhea-db.org/>
+PREFIX up: <http://purl.uniprot.org/core/>
+PREFIX taxon: <http://purl.uniprot.org/taxonomy/>
+PREFIX up: <http://purl.uniprot.org/core/>
+
+# Query 13
+# Select all Rhea reactions used to annotate Escherichia coli (taxid=83333) in UniProtKB/Swiss-Prot
+# return the number of UniProtKB entries
+# 
+# Federated query using a service to UniProt SPARQL endpoint
+# 
+# This query cannot be performed using the Rhea search website
+SELECT ?uniprot ?mnemo ?rhea ?accession ?equation 
+WHERE {
+  { 
+    VALUES (?taxid) { (taxon:83333) }
+    GRAPH <http://sparql.uniprot.org/uniprot> {
+      ?uniprot up:reviewed true . 
+      ?uniprot up:mnemonic ?mnemo . 
+      ?uniprot up:organism ?taxid .
+      ?uniprot up:annotation/up:catalyticActivity/up:catalyzedReaction ?rhea . 
+    }
+  }
+  ?rhea rh:accession ?accession .
+  ?rhea rh:equation ?equation .
+}

settings.json

@@ -72,9 +72,21 @@
       "name": "Wikidata",
       "url": "https://query.wikidata.org/bigdata/ldf"
     },
+    {
+      "name": "Wikidata SPARQL",
+      "url": "https://query.wikidata.org/sparql"
+    },
     {
       "name": "SNCB",
       "url": "https://graph.irail.be/sncb/connections"
+    },
+    {
+      "name": "Uniprot",
+      "url": "https://sparql.uniprot.org/sparql"
+    },
+    {
+      "name": "Rhea",
+      "url": "https://sparql.rhea-db.org/sparql"
     }
   ],
   "prefixes": {