dotnvim/flake.nix at master · crisp-su/dotnvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
{
  description = "Cheng's Neovim (Nixvim) configuration!";

  inputs = {
    nixpkgs.follows = "nixvim/nixpkgs";

    flake-parts.url = "github:hercules-ci/flake-parts/main";

    nixvim.url = "github:nix-community/nixvim/main";
    neovim-nightly-overlay.url = "github:nix-community/neovim-nightly-overlay/master";
  };

  outputs =
    inputs@{
      self,
      flake-parts,
      nixpkgs,
      ...
    }:
    flake-parts.lib.mkFlake { inherit self inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      imports = [
        ./flake/shell.nix
        ./flake/checks.nix
      ];

      flake = {
        nixvimModules.default =
          { pkgs, ... }:
          {
            _module.args.lib' = import ./lib { inherit (pkgs) lib; };

            imports = [
              ./modules/settings
              ./options
              ./config
            ];
          };

        homeModules.default = import ./modules/home-manager.nix {
          inherit inputs self;
        };

        overlays = {
          default = import ./overlays { inherit (nixpkgs) lib; };
        };
      };

      perSystem =
        {
          config,
          system,
          ...
        }:
        let
          pkgs = import nixpkgs {
            inherit system;

            config = {
              allowUnfree = true;
            };

            overlays = [
              inputs.neovim-nightly-overlay.overlays.default
              self.overlays.default
            ];
          };

          nvim = inputs.nixvim.legacyPackages.${system}.makeNixvimWithModule {
            inherit pkgs;
            module = self.nixvimModules.default;
          };
        in
        {
          _module.args.pkgs = pkgs;

          packages = {
            default = nvim;
          };

          apps = {
            default = config.apps.nvim;

            nvim = {
              type = "app";
              program = "${nvim}/bin/nvim";

              meta = {
                description = "Neovim with Cheng's configuration.";
              };
            };

            nixvim-print-init = {
              type = "app";
              program = "${nvim}/bin/nixvim-print-init";

              meta = {
                description = "Debug print generated `init.lua` from Nixvim.";
              };
            };
          };
        };
    };
}