How to create autonumbering or auto-incrementing fields?

[jugaadi]

Expected output(yaml):

res1:
# Each resource needs to be given a unique identifier. Ex. An auto-incrementing number within the scope of the doc
    x-rid: 1 
    type: object
    properties:
        prop1: 
# Each property needs to be given a unique identifier. Ex. An auto-incrementing number wiithin the scope of the resource(parent)
            x-pid: 1
            type: string
        prop2: 
            x-pid: 2
            type: string
        prop3: 
            x-pid: 3
            type: boolean
res2:
    x-rid: 2
    type: object
    properties:
        prop1: 
            x-pid: 1
            type: number
        prop2: 
            x-pid: 2
            type: boolean

[myitcv]

The query extension will make things like this more elegant but here is one way using v0.4.0:

package x

input: {
	res1: {
		type: "object"
		properties: {
			prop1: {
				type: "string"
			}
			prop2: {
				type: "string"
			}
			prop3: {
				type: "boolean"
			}
		}
	}
	res2: {
		type: "object"
		properties: {
			prop1: {
				type: "number"
			}
			prop2: {
				type: "boolean"
			}
		}
	}
}

output: {
	for i, pair in ([ for k, v in input {[k, v]}]) {
		(pair[0]): {
			"x-rid": i + 1
			pair[1]
			for i2, pair2 in ([ for k, v in pair[1].properties {[k, v]}]) {
				properties: (pair2[0]): "x-pid": i2 + 1
			}
		}
	}
}

That gives:

$ cue eval input.cue
input: {
    res1: {
        type: "object"
        properties: {
            prop1: {
                type: "string"
            }
            prop2: {
                type: "string"
            }
            prop3: {
                type: "boolean"
            }
        }
    }
    res2: {
        type: "object"
        properties: {
            prop1: {
                type: "number"
            }
            prop2: {
                type: "boolean"
            }
        }
    }
}
output: {
    res1: {
        "x-rid": 1
        type:    "object"
        properties: {
            prop1: {
                type:    "string"
                "x-pid": 1
            }
            prop2: {
                type:    "string"
                "x-pid": 2
            }
            prop3: {
                type:    "boolean"
                "x-pid": 3
            }
        }
    }
    res2: {
        "x-rid": 2
        type:    "object"
        properties: {
            prop1: {
                type:    "number"
                "x-pid": 1
            }
            prop2: {
                type:    "boolean"
                "x-pid": 2
            }
        }
    }
}

[cueckoo]

This discussion has been migrated to cue-lang/cue#1002.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.