cutefetch/default.nix at main · cybardev/cutefetch · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
{
  pkgs,
  lib ? pkgs.lib,
}: let
  author = "cybardev";
  pname = "cutefetch";
  version = "3.1.2";
in
  pkgs.stdenvNoCC.mkDerivation {
    inherit pname;
    inherit version;

    src = ./.;

    nativeBuildInputs = [pkgs.makeWrapper];

    installPhase = ''
      runHook preInstall
      chmod +x ${pname}
      mkdir -p "$out/bin"
      cp ${pname} "$out/bin/"
      runHook postInstall
    '';

    postInstall = with pkgs; ''
      wrapProgram "$out/bin/${pname}" \
        --prefix PATH : ${
        lib.makeBinPath (
          [coreutils]
          ++ lib.optionals pkgs.stdenvNoCC.hostPlatform.isLinux [
            networkmanager
            xorg.xprop
            xorg.xdpyinfo
          ]
        )
      }
    '';

    meta = {
      description = "Tiny coloured fetch script with cute little animals";
      homepage = "https://github.com/${author}/${pname}";
      license = lib.licenses.gpl3Only;
      mainProgram = pname;
      platforms = lib.platforms.all;
    };
  }