build.gradle

buildscript {
  repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
  }
  dependencies {
    classpath "com.badlogicgames.gdx:gdx-tools:$gdxVersion"
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
  }
}

allprojects {
  apply plugin: 'eclipse'
  apply plugin: 'idea'
}

configure(subprojects) {
  apply plugin: 'java'
  apply plugin: 'kotlin'
  sourceCompatibility = 1.6
}

subprojects {
  version = '0.0.1-SNAPSHOT'
  ext.appName = 'egu2016'
  repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
  }
}

// Clearing Eclipse project data in root folder:
tasks.eclipse.doLast {
  delete '.project'
  delete '.classpath'
  delete '.settings/'
}

// Run `gradle pack` task to generate skin.atlas file at assets/ui.
import com.badlogic.gdx.tools.texturepacker.TexturePacker
task pack << {
  render('./raw/icons/', 100)
  render('./raw/effects/', 70)
  render('./raw/people/', 150)
  // Note that if you need multiple atlases, you can duplicate the
  // TexturePacker.process invocation and change paths to generate
  // additional atlases with this task.
  TexturePacker.process(
    'raw/ui',           // Raw assets path.
    'assets/ui',        // Output directory.
    'skin'              // Name of the generated atlas (without extension).
  )
}

def render(String dirName, size) {
  def root = file(dirName)
  root.listFiles().each {
    def name = it.name.split("\\.")[0]
    runProcess(root, "inkscape -z -w $size -h $size -e ../ui/${name}.png ${name}.svg")
  }
}

def runProcess(dir, String commands) {
  println commands
  def builder = new ProcessBuilder(commands.split(' '))
  builder.inheritIO()
  builder.directory(dir)
  builder.start().waitFor()
}