Can't connect (self-assigns IP after 5')

[NdK73]

Hello.

Following directions in other issues, I removed core 2.7.1 and installed your 0.0.3 .
The code I'm compiling is:

#include <ESP8266WiFi.h>

#include <W5500lwIP.h>

// Using GPIO2 as CS
Wiznet5500lwIP eth(2);

void setup ()
{
  Serial.begin(115200);

  Serial.println("");
//  WiFi.mode(WIFI_OFF);

  SPI.begin();
//  SPI.setBitOrder(MSBFIRST);
//  SPI.setDataMode(SPI_MODE0);
  // Slow down because long (~20cm) wires and breadboard
  SPI.setFrequency(10000000); // Works up to 80M

  eth.setDefault(); // use ethernet for default route
  bool r=eth.begin(); // default mtu & mac address
  if(!r) {
    Serial.println("Error initializing eth");
    while(true) delay(1000);
  }
}

void loop ()
{
  delay(5000);
  if(eth.connected()) {
    Serial.print("My IP address: ");
    Serial.println(eth.localIP());
  } else {
    Serial.println("Still unconnected");
  }

}

It prints "Still unconnected" for about 5 minutes, then self-assigns 169.254.205.199 .
The W5500 board is connected correctly (I think: if I try swapping MISO/MOSI, or unconnecting SCLK or CS I get "Error initializing eth").
I left SPI settings commented after trying 'em and noticing they didn't change anything.
I don't see DHCP requests on my LAN.

[d-a-v]

I just tried your sketch and obtained an IP address:

Still unconnected
My IP address: 10.0.1.118
My IP address: 10.0.1.118
My IP address: 10.0.1.118

I also tried with the UDP sketch from the other issue and it works:

SDK:2.2.2-dev(38a443e)/Core:2.7.1-99-g59fe44e7=20701099/lwIP:STABLE-2_1_2_RELEASE/glue:1.2-33-g3d57f60/BearSSL:5c771be

............My IP address: 10.0.1.118
:urn 7
Received packet of size 7 from 10.0.1.8:53569
    (to 10.0.1.118:8888, free heap = 40360 B)
:urd 7, 7, 0
Contents:
cdscsd

with this sketch which is a mix of the Udp demo and your sketch:

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
#include <W5500lwIP.h>

// Using GPIO16 as CS
Wiznet5500lwIP eth(16);
WiFiUDP Udp;

unsigned int localPort = 8888;      // local port to listen on

// buffers for receiving and sending data
char packetBuffer[UDP_TX_PACKET_MAX_SIZE + 1]; //buffer to hold incoming packet,
char  ReplyBuffer[] = "acknowledged\r\n";       // a string to send back

void setup ()
{
  Serial.begin(115200);

  Serial.println("");
//  WiFi.mode(WIFI_OFF);

  SPI.begin();
//  SPI.setBitOrder(MSBFIRST);
//  SPI.setDataMode(SPI_MODE0);
  // Slow down because long (~20cm) wires and breadboard
  SPI.setFrequency(10000000); // Works up to 80M

  eth.setDefault(); // use ethernet for default route
  bool r=eth.begin(); // default mtu & mac address
  if(!r) {
    Serial.println("Error initializing eth");
    while(true) delay(1000);
  }

  // This loop is odd, do not refer to it as a good example.
  // Better example will be provided,
  // why: `delay()` requires changes like in
  // https://github.com/esp8266/Arduino/pull/6212
  // to use the usual loop waiting for dhcp response
  while (!eth.connected())
  {
    Serial.print(".");
    for (int i = 0; i < 500; i++)
        if (eth.connected())
            break;
        else
            delay(1);
  }

  Serial.print("My IP address: ");
  Serial.println(eth.localIP());

  Udp.begin(localPort);
}

void loop ()
{

  // if there's data available, read a packet
  int packetSize = Udp.parsePacket();
  if (packetSize) {
    Serial.printf("Received packet of size %d from %s:%d\n    (to %s:%d, free heap = %d B)\n",
                  packetSize,
                  Udp.remoteIP().toString().c_str(), Udp.remotePort(),
                  Udp.destinationIP().toString().c_str(), Udp.localPort(),
                  ESP.getFreeHeap());

    // read the packet into packetBufffer
    int n = Udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    packetBuffer[n] = 0;
    Serial.println("Contents:");
    Serial.println(packetBuffer);

    // send a reply, to the IP address and port that sent us the packet we received
    Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
    Udp.write(ReplyBuffer);
    Udp.endPacket();
  }

}

/*
  test (shell/netcat):
  --------------------
	  nc -u 192.168.esp.address 8888
*/

@NdK73
Can you run tcpdump on your dhcp server ?
Or Wireshark on your PC, you should see the dhcp request on ethernet.
You can also try to use netdump: Netdump (you need to import the lib from there).
(a better Netdump will be included in the arduino core but it is not yet here)

[NdK73]

Your sketch seems to work (partially) after changing CS from GPIO2 to GPIO16. Tks.
Now I get:

22:40:25.642 -> ....read error?
22:40:27.300 -> 
22:40:27.699 -> My IP address: 192.168.178.38
22:40:28.829 -> read error?
22:40:28.829 -> 

Then a lot of "read error?" messages. But at least this time I saw the DHCP request (tcpdump from my PC) and the IP gets assigned.

UDP rx seems to work:

22:44:28.319 -> Received packet of size 13 from 192.168.178.2:41859
22:44:28.319 ->     (to 192.168.178.38:8888, free heap = 42384 B)
22:44:28.319 -> Contents:
22:44:28.319 -> test message
22:44:28.319 -> 

I'll have to test multicast too (my domotic protocol uses it) as soon as I understand what was wrong in my sketch and fix the "read error?" messages.

PS: thanks for the fast answer and all the work you're doing!

[NdK73]

It stops working (does not get address, but W5500 is recognized by begin() ) if I change CS pin. Tried with GPIO2 and GPIO0 with no luck.
Tested SPI from 1MHz up to 40MHz and the "read error?" messages are still there :(

[d-a-v]

About read error message,
can you edit https://github.com/d-a-v/Arduino/blob/ethernet/cores/esp8266/lwIPIntfDev.h#L306 and replace it with

Serial.println("read error len=%d tot_len=%d?\r\n",(int)len,(int)tot_len);

(look for lwIPIntfDev.h on your computer)

[NdK73]

Done (printf instead of println). It now prints:

23:27:56.647 -> ....read error len=0 tot_len=60?
23:27:58.410 -> My IP address: 192.168.178.38
23:27:59.907 -> read error len=0 tot_len=60?

[d-a-v]

I have three eth modules (w5100, w5500, enc28j60). Every one is heating a lot while working.
Can you double check your power supply ?
Try another one ?
I will check the code to try and understand why it happens (what condition or if the cause can be printed)

[d-a-v]

You can try to replace this line by

if (1) // if ((buffer[0] & 0x01) || memcmp(&buffer[0], _mac_address, 6) == 0)

https://github.com/d-a-v/Arduino/blob/fef264e98589d8ac62e859bfcc978e919e7e6c95/libraries/lwIP_w5500/src/utility/w5500.cpp#L389

Filtering will be anyway done by lwIP. If this removes the issue for you, then I'll check the other drivers.

[NdK73]

My module is not heating abnormally. I only connected 5V line, not the 3v3 one. And it's from the same USB that's powering the D1mini.

With line 389 replaced as given the messages are gone.
Tks again. I hope it gets included soon in mainline core (possibly 2.7.2?).

[d-a-v]

No hope for 2.7.2. It will be 3.0.0 or git head after 2.7.2 is out.
I'll keep the alpha or gamma version updated though (with a better display of what's in them).
No more displayed errors, but everything fine, meaning no transmission error ?
That's great, Thanks for testing and reporting !

[NdK73]

Then I'll keep gamma installed :)
I didn't do much more testing, but there are no more rx errors. Still need to test multicast.
A strange thing I just noticed: this morning it was no more pingable. A quick reset "fixed" it, but it shouldn't be needed. Possibly a problem with DHCP renew? I'll keep pinging it from time to time during the day just to check.

[NdK73]

Problem confirmed: after 3h it's not answering pings any more. Seems unrelated to DHCP renew, since it's set to 10 days.
No messages printed on serial console.

Tks again.

[d-a-v]

I would need to be able to reproduce. What is the running sketch ?

[NdK73]

The one you posted above. Only change: the SPI speed (boosted to 40MHz... Going to try down to 10).