mod-deps.dang

"""
Dagger dependencies for a Go SDK module.
"""
type ModDeps {
  """
  Workspace-relative path of the module root.
  """
  let path: String!

  """
  Workspace containing this module.
  """
  let ws: Workspace!

  """
  Return dependency names when present, otherwise dependency sources.
  """
  pub list: [String!]! {
    polyfill.workspace(ws).moduleSource(path).config.dependencies
  }

  """
  Add a Dagger dependency to dagger.json.
  """
  pub add(source: String!, name: String! = ""): Changeset! {
    polyfill.workspace(ws).moduleSource(path).config.withDependency(source, name).fork.changes
  }

  """
  Remove a Dagger dependency from dagger.json by name or source.
  """
  pub remove(name: String!): Changeset! {
    polyfill.workspace(ws).moduleSource(path).config.withoutDependency(name).fork.changes
  }

  """
  Update one dependency by name or source, or update all remote dependencies in
  dagger.json.
  """
  pub update(name: String! = ""): Changeset! {
    polyfill.workspace(ws).moduleSource(path).config.withUpdatedDependencies(name).fork.changes
  }
}