mixxx/cmake/modules/Findrubberband.cmake at d57961f0516420903f65b67f3ce88f58fe76b512 · daschuer/mixxx · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
# This file is part of Mixxx, Digital DJ'ing software.
# Copyright (C) 2001-2024 Mixxx Development Team
# Distributed under the GNU General Public Licence (GPL) version 2 or any later
# later version. See the LICENSE file for details.

#[=======================================================================[.rst:
Findrubberband
--------------

Finds the rubberband library.

Imported Targets
^^^^^^^^^^^^^^^^

This module provides the following imported targets, if found:

``rubberband::rubberband``
  The rubberband library

Result Variables
^^^^^^^^^^^^^^^^

This will define the following variables:

``rubberband_FOUND``
  True if the system has the rubberband library.
``rubberband_INCLUDE_DIRS``
  Include directories needed to use rubberband.
``rubberband_LIBRARIES``
  Libraries needed to link to rubberband.
``rubberband_DEFINITIONS``
  Compile definitions needed to use rubberband.

Cache Variables
^^^^^^^^^^^^^^^

The following cache variables may also be set:

``rubberband_INCLUDE_DIR``
  The directory containing ``rubberband/RubberBandStretcher.h``.
``rubberband_LIBRARY``
  The path to the rubberband library.

#]=======================================================================]

find_package(PkgConfig QUIET)
if(PkgConfig_FOUND)
  pkg_check_modules(PC_rubberband QUIET rubberband)
endif()

find_path(rubberband_INCLUDE_DIR
  NAMES rubberband/RubberBandStretcher.h
  HINTS ${PC_rubberband_INCLUDE_DIRS}
  DOC "rubberband include directory")
mark_as_advanced(rubberband_INCLUDE_DIR)

find_library(rubberband_LIBRARY
  NAMES rubberband rubberband-library rubberband-dll
  HINTS ${PC_rubberband_LIBRARY_DIRS}
  DOC "rubberband library"
)
mark_as_advanced(rubberband_LIBRARY)

if(DEFINED PC_rubberband_VERSION AND NOT PC_rubberband_VERSION STREQUAL "")
  set(rubberband_VERSION "${PC_rubberband_VERSION}")
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
  rubberband
  REQUIRED_VARS rubberband_LIBRARY rubberband_INCLUDE_DIR
  VERSION_VAR rubberband_VERSION
)

if(rubberband_FOUND)
  set(rubberband_LIBRARIES "${rubberband_LIBRARY}")
  set(rubberband_INCLUDE_DIRS "${rubberband_INCLUDE_DIR}")
  set(rubberband_DEFINITIONS ${PC_rubberband_CFLAGS_OTHER})

  if(NOT TARGET rubberband::rubberband)
    add_library(rubberband::rubberband UNKNOWN IMPORTED)
    set_target_properties(rubberband::rubberband
      PROPERTIES
        IMPORTED_LOCATION "${rubberband_LIBRARY}"
        INTERFACE_COMPILE_OPTIONS "${PC_rubberband_CFLAGS_OTHER}"
        INTERFACE_INCLUDE_DIRECTORIES "${rubberband_INCLUDE_DIR}"
    )
    is_static_library(rubberband_IS_STATIC rubberband::rubberband)
    if(rubberband_IS_STATIC)
      find_library(SAMPLERATE_LIBRARY samplerate REQUIRED)
      set_property(TARGET rubberband::rubberband APPEND PROPERTY INTERFACE_LINK_LIBRARIES
        ${SAMPLERATE_LIBRARY}
      )
      find_package(FFTW3)
      if (FFTW_FOUND)
        set_property(TARGET rubberband::rubberband APPEND PROPERTY INTERFACE_LINK_LIBRARIES
          FFTW3::fftw3
        )
      endif()
      find_package(Sleef)
      if (Sleef_FOUND)
        set_property(TARGET rubberband::rubberband APPEND PROPERTY INTERFACE_LINK_LIBRARIES
          Sleef::sleef
          Sleef::sleefdft
        )
      endif()
    endif()
  endif()
endif()