Run more checks to ensure otpauth URI is valid

Author: samueltardieu

lib/nimble_totp.ex

@@ -140,9 +140,79 @@ defmodule NimbleTOTP do
   @typedoc "Options for `valid?/3`."
   @type validate_option() :: {:since, time() | nil}
 
+  @doc """
+  Generate the URI to be encoded in the QR code. Contrary to NimbleTOTP.otpauth_uri/2,
+  this function can return an error if the label or the issuer are not well-formed.
+  Also, it ensures that the issuer, when present, is placed twice in the resulting URI,
+  as recommended by the
+  [reference documentation](https://github.com/google/google-authenticator/wiki/Key-Uri-Format).
+
+  ## Examples
+
+      iex> NimbleTOTP.otpauth("alice", "abcd", issuer: "Acme")
+      {:ok, "otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Acme"}
+
+      iex> NimbleTOTP.otpauth("alice", "abcd")
+      {:ok, "otpauth://totp/alice?secret=MFRGGZA"}
+
+      iex> NimbleTOTP.otpauth("Acme:alice", "abcd")
+      {:ok, "otpauth://totp/Acme:alice?secret=MFRGGZA&issuer=Acme"}
+
+      iex> NimbleTOTP.otpauth("Wonderland:alice", "abcd", issuer: "Acme")
+      {:error, :issuer_mismatch}
+
+      iex> NimbleTOTP.otpauth("Acme:Alice:Wonderland", "abcd")
+      {:error, :too_many_colons}
+  """
+  @spec otpauth(String.t(), String.t(), keyword()) :: {:ok, String.t()} | {:error, atom}
+  def otpauth(label, secret, uri_params \\ []) when is_binary(label) and is_binary(secret) do
+    with {:ok, label, uri_params} <- label_and_issuer(label, uri_params),
+         do: {:ok, otpauth_uri(label, secret, uri_params)}
+  end
+
+  @spec label_and_issuer(String.t(), keyword()) :: {:ok, String.t(), keyword()} | {:error, atom}
+  defp label_and_issuer(label, uri_params) do
+    from_label =
+      case String.split(label, ":") do
+        [label] -> {:ok, label, nil}
+        [issuer, label] -> {:ok, label, issuer}
+        _ -> {:error, :too_many_colons}
+      end
+
+    from_uri_params =
+      with {:ok, issuer} <- Keyword.fetch(uri_params, :issuer),
+           [issuer] <- String.split(issuer, ":") do
+        {:ok, issuer}
+      else
+        :error -> {:ok, nil}
+        _ -> {:error, :too_many_colons}
+      end
+
+    with {:ok, label, issuer_label} <- from_label,
+         {:ok, issuer} <- from_uri_params do
+      case {label, issuer_label || issuer, issuer} do
+        {label, nil, nil} ->
+          {:ok, label, uri_params}
+
+        {label, issuer, nil} ->
+          {:ok, "#{issuer}:#{label}", Keyword.put(uri_params, :issuer, issuer)}
+
+        {label, issuer, issuer} ->
+          {:ok, "#{issuer}:#{label}", uri_params}
+
+        _ ->
+          {:error, :issuer_mismatch}
+      end
+    end
+  end
+
   @doc """
   Generate the URI to be encoded in the QR code.
 
+  This function will not fail even if the label is not well-formed (e.g., contains
+  multiple colons), or if the issuer present in the label and the one given in the
+  keyword do not match. Use NimbleTOTP.otpauth/2 if you need stricter control.
+
   ## Examples
 
       iex> NimbleTOTP.otpauth_uri("Acme:alice", "abcd", issuer: "Acme")