added examples, fixed readme

Author: dcuartielles

README.md

@@ -1,2 +1,116 @@
 # embryo
-State machine for EIT Manufacturing's EMBRYO educational metal press machine.
+
+## Description
+
+Step by step construction of a state machine for EIT Manufacturing's EMBRYO educational metal press machine.
+
+## Installation
+
+### First Method
+
+1. Navigate to the Releases page.
+2. Download the latest release.
+3. Extract the zip file in your Arduino's Sketchbook
+4. In the Arduino IDE, navigate to File > Sketchbook > EMBRYO-X.Y.Z
+
+## Features
+
+- ### Official dependencies
+
+    Code examples depend on the official EduIntro library.
+
+- ### Easy to use
+
+    It is simple, basic and very easy to understand. Just import the code collection in your Sketchbook and try out the different examples.
+
+- ### Complete package for the EMBRYO machine
+
+    Learn how to use the machine from scratch and step by step build a reliable state machine that will give you access to all of its capabilities.
+
+- ### Intuitive syntax
+
+    The code has a simple and intuitive syntax to handle variables and functions.
+
+- ### Give back
+
+    EMBRYO is free for everyone. Everyone can download and use it in their projects, assignments or anywhere for free.
+
+## Components and functions
+
+This is an example of how code can be built iteratively around a certain machine but slowly adding improvements to the core software. Here a list of components of the code
+
+  - ### Architecture
+    Includes information about the system itself, the pinouts to the connected sensors and actuators, and constructs to navigate through them
+
+  - ### Comm Functions
+    Functions dedicated to send and receive informaiton via Serial port
+
+  - ### Data Functions
+    Handling of the information from sensors, arranging into easy to compare arrays, etc
+
+  - ### States
+    Definitions of names of states to make the code easier to read
+        
+## General code structure
+
+There are many examples implemented in this repository. Below are shown some of the examples.
+
+  - ### 03 Machine Status Serial Control
+    In this example, the machine offers a bi-directional communication port to the computer for you to send commands to it and collect information in real time. The main loop responds to the structure:
+
+``` C++
+void loop() {
+  // Check the inputs
+  readInputs();
+
+  // Serial terminal
+  serialCheck();
+
+  // Print out the inputs if there is an event
+  if (inputEvent()) {
+    printInputs();
+  }
+
+  // Copy arrays of inputs to check state changes
+  copyInputs();
+}
+```
+
+## Versions
+
+### v0.0.1 (Current Stable version)
+
+#### April, 2021
+
+* Initial release of examples
+
+## Contributing
+
+If you want to contribute to this project:
+
+- Report bugs and errors
+- Ask for enhancements
+- Create issues and pull requests
+- Tell others about this code
+- Contribute new protocols
+
+Please read [CONTRIBUTING.md](https://github.com/AghaSaad04/EduIntro/blob/master/CONTRIBUTING.md) for details on our code of conduct, and the process for submitting pull requests to us.
+
+## Credits
+
+Created and maintained by D. Cuartielles, Malmo, 2021
+
+Based on previous work by:
+
+- F. Troya, Malmo, 2020
+- [Arduino community](https://www.arduino.cc)
+
+## Current stable version
+
+**number:** v0.0.1
+
+**codename:** Jokkmokk
+
+## License
+
+This library is licensed under [GPLv3](https://www.gnu.org/licenses/quick-guide-gplv3.html).

src/00_Machine_Status/00_Machine_Status.ino

@@ -0,0 +1,70 @@
+/*
+   EMBRYO Control system v2.0
+
+   Machine control using an event driven approach and designing
+   a state machine around the different inputs and outputs
+
+   Test 00: Machine Status
+
+   This example checks the different inputs and outputs, as
+   well as it establishes the different mechanisms for reading
+   all inputs and actiating all outputs
+
+   This code is in the public domain
+
+   2021 D. Cuartielles
+
+*/
+
+// Include the machine's architecture
+#include "architecture.h"
+
+// Include the sensor / actuator handling library
+#include <EduIntro.h>
+
+// Shall we debug the code?
+const int DEBUG = true;
+
+// Array to store input values
+int inputValuesOld[NUM_PINS_DIGITAL + NUM_PINS_ANALOG];
+int inputValues[NUM_PINS_DIGITAL + NUM_PINS_ANALOG];
+
+// Array to store the output values
+int outputValues[NUM_PINS_OUTPUT];
+
+void setup() {
+  // Initialise serial communication
+  Serial.begin(115200);
+
+  // Do not start until computer is connected
+  while (!Serial) {};
+
+  // Status prints
+  if (DEBUG) {
+    Serial.print("Size of digital input array: ");
+    Serial.println(NUM_PINS_DIGITAL);
+    Serial.print("Size of analog input array: ");
+    Serial.println(NUM_PINS_ANALOG);
+    Serial.print("Size of output array: ");
+    Serial.println(NUM_PINS_OUTPUT);
+  }
+
+  // Declare inputs and outputs as such
+  for (int i = 0; i < NUM_PINS_DIGITAL; i++)
+    pinMode(INPUTS_DIGITAL[i], INPUT);
+  for (int i = 0; i < NUM_PINS_OUTPUT; i++)
+    pinMode(OUTPUTS[i], OUTPUT);
+}
+
+void loop() {
+  // Check the inputs
+  readInputs();
+
+  // Printout the inputs if there is an event
+  if (inputEvent()) {
+    printInputs();
+  }
+
+  // Copy arrays of inputs to check state changes
+  copyInputs();
+}

src/00_Machine_Status/architecture.h

@@ -0,0 +1,48 @@
+// Machine architecture
+// * Inputs
+const int PIN_BUTTON_LEFT = 6;     
+const int PIN_BUTTON_RIGHT = 5;    
+const int PIN_BUTTON_UP = 7;       
+const int PIN_BUTTON_DOWN = 2;     
+
+const int PIN_END_STOP = A2;       
+const int PIN_END_STOP_MOTOR = 3;  
+
+const int PIN_BUTTON_INIT = 4;     
+const int PIN_BUTTON_EMERGENCY = 9;
+const int PIN_POT = A0;            
+
+// * Outputs
+const int PIN_BUZZER = A1;         
+
+const int PIN_LED =  A3;           
+const int PIN_LED_EMERGENCY = 8;   
+const int PIN_MOTOR_DIR = 11;      
+const int PIN_MOTOR_STEP = 10;
+
+const int INPUTS_DIGITAL[] = {
+  PIN_BUTTON_LEFT,
+  PIN_BUTTON_RIGHT,
+  PIN_BUTTON_UP,
+  PIN_BUTTON_DOWN,
+  PIN_END_STOP,
+  PIN_END_STOP_MOTOR,
+  PIN_BUTTON_INIT,
+  PIN_BUTTON_EMERGENCY
+};
+
+const int INPUTS_ANALOG[] = {
+  PIN_POT
+};
+
+const int OUTPUTS[] = {
+  PIN_BUZZER,
+  PIN_LED,
+  PIN_LED_EMERGENCY,
+  PIN_MOTOR_DIR,
+  PIN_MOTOR_STEP
+};
+
+const int NUM_PINS_DIGITAL = sizeof(INPUTS_DIGITAL) / sizeof(INPUTS_DIGITAL[0]);
+const int NUM_PINS_ANALOG = sizeof(INPUTS_ANALOG) / sizeof(INPUTS_ANALOG[0]);
+const int NUM_PINS_OUTPUT = sizeof(OUTPUTS) / sizeof(OUTPUTS[0]);

src/00_Machine_Status/data_functions.ino

@@ -0,0 +1,36 @@
+void copyInputs() {
+  // Copy all values one by one
+  for (int i = 0; i < NUM_PINS_DIGITAL + NUM_PINS_ANALOG; i++)
+    inputValuesOld[i] = inputValues[i];
+}
+
+void printInputs() {
+  // Print out all values separated by blank spaces
+  for (int i = 0; i < NUM_PINS_DIGITAL + NUM_PINS_ANALOG; i++) {
+    Serial.print(inputValues[i]);
+    Serial.print(" ");
+  }
+  
+  Serial.println();
+}
+
+boolean inputEvent() {
+  boolean result = false;
+
+  // Check all values one by one
+  for (int i = 0; i < NUM_PINS_DIGITAL + NUM_PINS_ANALOG; i++)
+    if (inputValues[i] != inputValuesOld[i])
+      result = true;
+
+  return result;
+}
+
+void readInputs() {
+  // Read digital inputs
+  for (int i = 0; i < NUM_PINS_DIGITAL; i++)
+    inputValues[i] = digitalRead(INPUTS_DIGITAL[i]);
+
+  // Read analog inputs
+  for (int i = 0; i < NUM_PINS_ANALOG; i++)
+    inputValues[NUM_PINS_DIGITAL + i] = analogRead(INPUTS_ANALOG[i]);
+}

src/01_Machine_Status_Button_States/01_Machine_Status_Button_States.ino

@@ -0,0 +1,93 @@
+/*
+   EMBRYO Control system v2.0
+
+   Machine control using an event driven approach and designing
+   a state machine around the different inputs and outputs
+
+   Test 01: Machine Status Button States
+
+   This example checks the different inputs and outputs, as
+   well as it establishes the different mechanisms for reading
+   all inputs and actiating all outputs. In this case we check
+   for buttons to be PRESSED, RELEASED, and HELD
+
+   The main difference between this example and the previous
+   one is the use of the EduIntro library to detect button
+   states and encode them. Note that the library considers
+   all buttons to be pulled up, which is not the case, thus
+   the code (check it out and see)
+
+   This code is in the public domain
+
+   2021 D. Cuartielles
+
+*/
+
+// Include the machine's architecture
+#include "architecture.h"
+#include "states.h"
+
+// Include the sensor / actuator handling library
+#include <EduIntro.h>
+
+// Shall we debug the code?
+const int DEBUG = true;
+
+// Array to store input values
+int inputValuesOld[NUM_PINS_DIGITAL + NUM_PINS_ANALOG];
+int inputValues[NUM_PINS_DIGITAL + NUM_PINS_ANALOG];
+
+// Array to store the output values
+int outputValues[NUM_PINS_OUTPUT];
+
+// Array for all of the buttons
+// unfortunately this cannot be declared automatically
+// like with   
+//  for (int i = 0; i < NUM_PINS_DIGITAL; i++)
+//    inputButtons[i] = new Button(INPUTS_DIGITAL[i]);
+// and theefore cannot be automated :-(
+Button inputButtons[] {
+  Button(INPUTS_DIGITAL[0], PULL_DOWN),
+  Button(INPUTS_DIGITAL[1], PULL_DOWN),
+  Button(INPUTS_DIGITAL[2], PULL_DOWN),
+  Button(INPUTS_DIGITAL[3], PULL_DOWN),
+  Button(INPUTS_DIGITAL[4], PULL_DOWN),
+  Button(INPUTS_DIGITAL[5], PULL_DOWN),
+  Button(INPUTS_DIGITAL[6], PULL_DOWN),
+  Button(INPUTS_DIGITAL[7], PULL_UP),
+};
+
+void setup() {
+  // Initialise serial communication
+  Serial.begin(115200);
+
+  // Do not start until computer is connected
+  while (!Serial) {};
+
+  // Status prints
+  if (DEBUG) {
+    Serial.print("Size of digital input array: ");
+    Serial.println(NUM_PINS_DIGITAL);
+    Serial.print("Size of analog input array: ");
+    Serial.println(NUM_PINS_ANALOG);
+    Serial.print("Size of output array: ");
+    Serial.println(NUM_PINS_OUTPUT);
+  }
+
+  // Declare outputs as such
+  for (int i = 0; i < NUM_PINS_OUTPUT; i++)
+    pinMode(OUTPUTS[i], OUTPUT);
+}
+
+void loop() {
+  // Check the inputs
+  readInputs();
+
+  // Printout the inputs if there is an event
+  if (inputEvent()) {
+    printInputs();
+  }
+
+  // Copy arrays of inputs to check state changes
+  copyInputs();
+}