astgrep: support its LSP

Fixes: #4974

Author: mathstuf

autoload/ale/astgrep.vim

@@ -0,0 +1,38 @@
+" Author: Ben Boeckel <[email protected]>
+" Description: A CLI tool for code structural search, lint and rewriting
+
+call ale#Set('astgrep_executable', 'ast-grep')
+
+function! ale#astgrep#GetCommand(buffer) abort
+    return '%e lsp'
+endfunction
+
+function! ale#astgrep#GetProjectRoot(buffer) abort
+    " Try to find nearest sgconfig.yml
+    let l:sgconfig_file = ale#path#FindNearestFile(a:buffer, 'sgconfig.yml')
+
+    if !empty(l:sgconfig_file)
+        return fnamemodify(l:sgconfig_file . '/', ':p:h:h')
+    endif
+
+    return ''
+endfunction
+
+function! ale#astgrep#Define(lang) abort
+    call ale#linter#Define(a:lang, {
+    \   'name': 'astgrep',
+    \   'lsp': 'stdio',
+    \   'executable': {b -> ale#Var(b, 'astgrep_executable')},
+    \   'command': function('ale#astgrep#GetCommand'),
+    \   'project_root': function('ale#astgrep#GetProjectRoot'),
+    \})
+endfunction
+
+function! ale#astgrep#ApplyLanguages() abort
+    for l:lang in g:ale_astgrep_linter_languages
+        call ale#astgrep#Define(l:lang)
+    endfor
+endfunction
+
+let g:ale_astgrep_linter_languages = get(g:, 'ale_astgrep_linter_languages', [])
+call ale#astgrep#ApplyLanguages()

doc/ale-generic.txt

@@ -0,0 +1,42 @@
+===============================================================================
+ALE Generic Integration                                   *ale-generic-options*
+                                                      *ale-integration-generic*
+
+===============================================================================
+Integration Information
+
+  Some tools are not language specific.  This document collects information on
+  ale's support for these tools.
+
+
+===============================================================================
+astgrep                                                   *ale-generic-astgrep*
+
+  `'ast-grep'` is a tool which can detect code patterns and offer fixes based
+  on various languages' abstract syntax trees (ASTs) using tree-sitter.
+
+                                               *ale-options.astgrep_executable*
+                                                     *g:ale_astgrep_executable*
+                                                     *b:ale_astgrep_executable*
+astgrep_executable
+g:ale_astgrep_executable
+  Type: |String|
+  Default: `'ast-grep'`
+
+  This variable can be modified to change the executable path for
+  `ast-grep`.
+
+
+                                         *ale-options.astgrep_linter_languages*
+                                               *g:ale_astgrep_linter_languages*
+astgrep_linter_languages
+g:ale_astgrep_linter_languages
+  Type: |List|
+  Default: `'[]'`
+
+  This variable can be set to a list of languages for which to enable the
+  `ast-grep` linter.
+
+
+===============================================================================
+  vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:

doc/ale.txt

@@ -3485,6 +3485,8 @@ documented in additional help files.
   fountain................................|ale-fountain-options|
   fusionscript............................|ale-fuse-options|
     fusion-lint...........................|ale-fuse-fusionlint|
+  generic.................................|ale-generic-options|
+    astgrep...............................|ale-generic-astgrep|
   git commit..............................|ale-gitcommit-options|
     gitlint...............................|ale-gitcommit-gitlint|
   gleam...................................|ale-gleam-options|

supported-tools.md

@@ -220,6 +220,8 @@ formatting.
   * [proselint](http://proselint.com/)
 * FusionScript
   * [fusion-lint](https://github.com/RyanSquared/fusionscript)
+* Generic
+  * [ast-grep](https://ast-grep.github.io/)
 * Git Commit Messages
   * [gitlint](https://github.com/jorisroovers/gitlint)
 * Gleam

test/linter/test_generic_astgrep.vader

@@ -0,0 +1,23 @@
+Before:
+  " Load the dummy linter; tests will register as needed.
+  call ale#assert#SetUpLinterTest('testft', 'testlinter')
+  " Replace the dummy linter with a defined linter.
+  call ale#linter#Reset()
+  call ale#linter#PreventLoading('python')
+  call ale#astgrep#Define('python')
+
+After:
+  call ale#assert#TearDownLinterTest()
+
+Execute(The default executable path should be correct):
+  AssertLinter 'ast-grep', ale#Escape('ast-grep') . ' lsp'
+
+Execute(The project root should be detected correctly with a configuration file):
+  call ale#test#SetFilename('../test-files/generic/astgrep/subdir/file.py')
+
+  AssertLSPProject ale#path#Simplify(g:dir . '/../test-files/generic/astgrep')
+
+Execute(The project root should be empty when no project files can be detected):
+  call ale#test#SetFilename('../test-files/dummy')
+
+  AssertLSPProject ''