Fix diff-hl-resolved-reference-revision for Hg and Bzr with buffer-local diff-hl-reference-revision.

**Problem**:
`diff-hl-resolved-reference-revision` fails to work correctly when `diff-hl-reference-revision` is set as a buffer-local variable.

Example:
```emacs-lisp
(setq-local diff-hl-reference-revision "test-rev")
```

**Cause**:
When the implementation for backends like Hg (and similarly Bzr) uses `with-temp-buffer`, buffer-local variables from the original buffer context are not accessible. Consequently, `diff-hl-reference-revision` evaluates to `nil` within the temporary buffer.

For 'Hg as an exmaple,
```emacs-lisp
(with-temp-buffer
  (vc-hg-command (current-buffer) 0 nil
                 "identify" "-r" diff-hl-reference-revision
                 "-i")
  ...)
```

This leads to an incorrect command being executed:
*   **Expected hg command**: `hg --config ui.report_untrusted=0 identify -r test-rev -i .`
*   **Actual hg command**: `hg --config ui.report_untrusted=0 identify -r -i .`

**Fix**:
To resolve this, the value of `diff-hl-reference-revision` is now copied into a non-buffer-local variable (e.g., `original-diff-hl-reference-revision`) *before* entering the `with-temp-buffer` block. This non-buffer-local variable is then used within the temporary buffer context, ensuring the correct revision is always passed to the underlying version control command.

**Tests**:
I have tested it in my hg repo. Also added a test in `diff-hl-test.el`.

Author: whhone

diff-hl.el

@@ -1442,19 +1442,25 @@ CONTEXT-LINES is the size of the unified diff context, defaults to 0."
    ((eq backend 'Git)
     (vc-git--rev-parse diff-hl-reference-revision))
    ((eq backend 'Hg)
-    (with-temp-buffer
-      (vc-hg-command (current-buffer) 0 nil
-                     "identify" "-r" diff-hl-reference-revision
-                     "-i")
-      (goto-char (point-min))
-      (buffer-substring-no-properties (point) (line-end-position))))
+    ;;  Preserve the potentially buffer-local `diff-hl-reference-revision`
+    ;;  inside the `with-temp-buffer`.
+    (let ((original-diff-hl-reference-revision diff-hl-reference-revision))
+      (with-temp-buffer
+        (vc-hg-command (current-buffer) 0 nil
+                       "identify" "-r" original-diff-hl-reference-revision
+                       "-i")
+        (goto-char (point-min))
+        (buffer-substring-no-properties (point) (line-end-position)))))
    ((eq backend 'Bzr)
-    (with-temp-buffer
-      (vc-bzr-command (current-buffer) 0 nil
-                      "log" "--log-format=template" "--template-str='{revno}'"
-                      "-r" diff-hl-reference-revision)
-      (goto-char (point-min))
-      (buffer-substring-no-properties (point) (line-end-position))))
+    ;;  Preserve the potentially buffer-local `diff-hl-reference-revision`
+    ;;  inside the `with-temp-buffer`.
+    (let ((original-diff-hl-reference-revision diff-hl-reference-revision))
+      (with-temp-buffer
+        (vc-bzr-command (current-buffer) 0 nil
+                        "log" "--log-format=template" "--template-str='{revno}'"
+                        "-r" original-diff-hl-reference-revision)
+        (goto-char (point-min))
+        (buffer-substring-no-properties (point) (line-end-position)))))
    (t
     diff-hl-reference-revision)))
 

test/diff-hl-test.el

@@ -223,6 +223,20 @@
 Diff finished."
                  (buffer-substring (point) (point-max))))))))
 
+(diff-hl-deftest diff-hl-resolved-reference-revision-buffer-local-hg ()
+  (diff-hl-test-in-source
+   (setq-local diff-hl-reference-revision "test-rev")
+   (condition-case err
+       (progn
+         (diff-hl-resolved-reference-revision 'Hg)
+         (ert-fail "Expected an error to be signaled but none was."))
+     ;; We don't have a hg repo, but we can use the error message to verify the
+     ;; underlying command.
+     (error
+      (should (string-match-p
+               (regexp-quote "identify -r test-rev -i .")
+               (error-message-string err)))))))
+
 (provide 'diff-hl-test)
 
 ;;; diff-hl-test.el ends here