fix(read): Improve handling of Key UDA for empty mapping

There were several issues uncovered by those test cases:
- The path and location information of the error message pointed to the parent node,
  not the node that was triggering an error. So if the error was for the 5th entry in
  a list, the user would be unhelpfully and confusingly pointed to the beginning of
  the list and not the offending node;
- Getting a YAML scalar node that was null would return 'null', not a D null value;
  This might need to be handled differently in the future if we need to distinguish
  between actual null and empty strings;
- Finally, empty mapping are parsed as null scalar by default by D-YAML, which makes
  sense as D-YAML does not know what structure to expect, but we do, so we need to
  explicitly handle the null case as an empty object;

Author: Geod24

source/configy/read.d

@@ -782,15 +782,31 @@ package FR.Type parseField (alias FR)
             string key = getUDAs!(FR.Ref, Key)[0].name;
             return node.mapping().map!(
                 (Node.Pair pair) {
-                    if (pair.value.nodeID != NodeID.mapping)
-                        throw new TypeConfigException(
-                            "sequence of " ~ pair.value.nodeTypeString(),
-                            "sequence of mapping (array of objects)",
-                            path, Location.get(node));
-
-                    return pair.value.parseMapping!(StructFieldRef!E)(
-                        path.addPath(pair.key.as!string),
-                        E.init, ctx, key.length ? [ key: pair.key ] : null);
+                    scope npath = path.addPath(pair.key.as!string);
+                    // Normal / expected path
+                    if (pair.value.nodeID == NodeID.mapping)
+                        return pair.value.parseMapping!(StructFieldRef!E)(npath,
+                            E.init, ctx, key.length ? [ key: pair.key ] : null);
+
+                    // It might be a single entry, e.g.
+                    // ---
+                    // values:
+                    // morevalues:
+                    //   key: value
+                    // ---
+                    // In this instance, `values` is an empty mapping but might be
+                    // interpreted as a scalar.
+                    if (pair.value.type() == NodeType.null_) {
+                        string[string] aa;
+                        Node empty = aa;
+                        // Ugly hack to keep the location information
+                        __traits(getMember, empty, "startMark_") = pair.value.startMark();
+                        return empty.parseMapping!(StructFieldRef!E)(npath,
+                            E.init, ctx, key.length ? [ key: pair.key ] : null);
+                    }
+
+                    throw new TypeConfigException(pair.value.nodeTypeString(),
+                            "mapping", npath, Location.get(pair.value));
                 }).array();
         }
         else

source/configy/test.d

@@ -986,3 +986,51 @@ ds:
     catch (ConfigException exc)
         assert(exc.toString() == "/dev/null(1:11): es.enabled: Expected to be a value of type bool, but is a scalar");
 }
+
+unittest {
+    static struct ImageConfig {
+        // Only this field is required
+        public string name;
+        public string containerfile = "Containerfile";
+        public @Optional string[] tags;
+    }
+
+    static struct ImageConfig2 {
+        // Both fields are required
+        public string name;
+        public string file;
+    }
+
+    static struct Config {
+        public @Optional @Key("name") ImageConfig[]  images;
+        public @Optional @Key("name") ImageConfig2[] images2;
+    }
+
+    auto c = parseConfigString!Config(`images:
+  foo/bar/root:
+    containerfile: path/Containerfile
+    tags: [ "latest" ]
+  far/boo/runner:
+`, "/dev/null");
+
+    assert(c.images[0].name == "foo/bar/root");
+    assert(c.images[0].containerfile == "path/Containerfile");
+    assert(c.images[1].name == "far/boo/runner");
+
+    try parseConfigString!Config(`images:
+  foo/bar/root:
+    containerfile: path/Containerfile
+    tags: [ "latest" ]
+  far/boo/runner: [ 1, 2, 3]
+`, "/dev/null");
+    catch (ConfigException exc)
+        assert(exc.toString() == "/dev/null(4:18): images.far/boo/runner: Expected to be mapping, but is a sequence");
+
+        try parseConfigString!Config(`images2:
+  foo/bar/root:
+    file: path/Containerfile
+  far/boo/runner:
+`, "/dev/null");
+    catch (ConfigException exc)
+        assert(exc.toString() == "/dev/null(3:17): images2.far/boo/runner.file: Required key was not found in configuration or command line arguments");
+}