Add new line between blocks

[ivan-srsen]

For example if we have
import Foo.Bar
alias Foo.Bar

I would like to add a new line so it looks like this
import Foo.Bar

alias Foo.bar

[novaugust]

hey ivan, sourceror doesn't do any rewriting for you. it just gives you the ability to handle manipulating AST with the comments inserted into metadata. you can use it to get the effect you're looking for, but you'll have to do that manipulation yourself =)

[doorgan]

As novaugust mentions, you can do the manipulation yourself.
For instance, to add a newline after every import:

code = """
import Foo.Bar
alias Foo.Bar
"""

ast = Sourceror.parse_string!(code)

{:__block__, [trailing_comments: [], leading_comments: []],
 [
   {:import,
    [
      trailing_comments: [],
      leading_comments: [],
      end_of_expression: [newlines: 1, line: 1, column: 15],
      line: 1,
      column: 1
    ],
    [
      {:__aliases__,
       [
         trailing_comments: [],
         leading_comments: [],
         last: [line: 1, column: 12],
         line: 1,
         column: 8
       ], [:Foo, :Bar]}
    ]},
   {:alias, [trailing_comments: [], leading_comments: [], line: 2, column: 1],
    [
      {:__aliases__,
       [
         trailing_comments: [],
         leading_comments: [],
         last: [line: 2, column: 11],
         line: 2,
         column: 7
       ], [:Foo, :Bar]}
    ]}
 ]}

You can see that the AST contains an end_of_expression metadata field. You can increase it's value to 2 in order to add an additional line break:

modified =
  Macro.postwalk(ast, fn
    {:import, meta, args} ->
      meta = put_in(meta, [:end_of_expression, :newlines], 2)
      {:import, meta, args}

    node ->
      node
  end)

{:__block__, [trailing_comments: [], leading_comments: []],
 [
   {:import,
    [
      trailing_comments: [],
      leading_comments: [],
      end_of_expression: [newlines: 2, line: 1, column: 15],
      line: 1,
      column: 1
    ],
    [
      {:__aliases__,
       [
         trailing_comments: [],
         leading_comments: [],
         last: [line: 1, column: 12],
         line: 1,
         column: 8
       ], [:Foo, :Bar]}
    ]},
   {:alias, [trailing_comments: [], leading_comments: [], line: 2, column: 1],
    [
      {:__aliases__,
       [
         trailing_comments: [],
         leading_comments: [],
         last: [line: 2, column: 11],
         line: 2,
         column: 7
       ], [:Foo, :Bar]}
    ]}
 ]}

modified
|> Sourceror.to_string()
|> IO.puts()

import Foo.Bar

alias Foo.Bar

:ok

Of course you can adapt the code to match whatever you want to modify.

However, keep in mind that:

• Sourceror relies on the Elixir formatter to print the code, so this approach is subject to how the formatter processes newline metadata on any given elixir version
• Because it relies on the formatter, the output will always have at most 2 newlines