nixconfig/flake.nix at main · draescherl/nixconfig · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
{
  description = "NixOS configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    noctalia = {
      url = "github:noctalia-dev/noctalia";
    };
    mangowm = {
      url = "github:mangowm/mango";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixvirt = {
      url = "github:AshleyYakeley/NixVirt";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      zen-browser,
      noctalia,
      mangowm,
      nixvirt,
      ...
    }:
    let
      # Helper function to create a system configuration
      mkSystem =
        {
          system,
          hostname,
          username,
          extraModules ? [ ],
        }:
        nixpkgs.lib.nixosSystem {
          specialArgs = {
            inherit system hostname username;
            zen = zen-browser.packages.${system}.default;
            noctalia = noctalia.packages.${system}.default;
          };
          modules = [
            # Host-specific configuration
            ./hosts/${hostname}/configuration.nix

            # Common modules shared across all systems
            ./modules/fonts.nix
            ./modules/login.nix
            ./modules/programs.nix
            ./modules/security.nix
            ./modules/system.nix
            ./modules/theme.nix
            ./modules/users.nix
            ./modules/virtualisation.nix
            mangowm.nixosModules.mango
          ]
          ++ extraModules; # Host-specific modules
        };
    in
    {
      nixosConfigurations = {
        # Desktop configuration
        desktop = mkSystem {
          system = "x86_64-linux";
          hostname = "desktop";
          username = "lucas";
          extraModules = [
            ./modules/bluetooth.nix
            ./modules/desktops/niri.nix
            ./modules/desktops/sway.nix
            ./modules/gaming.nix
            ./modules/keyd.nix
            ./modules/nvidia.nix
          ];
        };

        # Work laptop configuration
        tuxedo = mkSystem {
          system = "x86_64-linux";
          hostname = "tuxedo";
          username = "lucas";
          extraModules = [
            ./modules/bluetooth.nix
            ./modules/desktops/niri.nix
            ./modules/desktops/sway.nix
            ./modules/keyd.nix
            ./modules/power.nix
            ./modules/work.nix
            ./modules/sandbox/host.nix
            nixvirt.nixosModules.default
          ];
        };
      };
    };
}