proselint/flake.nix at main · drainpixie/proselint · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
{
	inputs = {
		nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";

		hooks = {
			url = "github:cachix/git-hooks.nix";
			inputs.nixpkgs.follows = "nixpkgs";
		};

		uv = {
			url = "github:pyproject-nix/uv2nix";
			inputs = {
				nixpkgs.follows = "nixpkgs";
				pyproject-nix.follows = "pyproject";
			};
		};

		pyproject = {
			url = "github:pyproject-nix/pyproject.nix";
			inputs.nixpkgs.follows = "nixpkgs";
		};

		build-systems = {
			url = "github:pyproject-nix/build-system-pkgs";
			inputs = {
				uv2nix.follows = "uv";
				nixpkgs.follows = "nixpkgs";
				pyproject-nix.follows = "pyproject";
			};
		};
	};

	outputs = {
		uv,
		self,
		nixpkgs,
		...
	}: let
		inherit (nixpkgs) lib;
		inherit (import ./nix/helpers.nix {inherit self nixpkgs overlay;}) forAllSystems;

		workspace = uv.lib.workspace.loadWorkspace {workspaceRoot = ./.;};
		overlay = workspace.mkPyprojectOverlay {sourcePreference = "wheel";};

		importWithAttrs = path:
			forAllSystems (attrs:
					import path {
						inherit workspace self lib;
						inherit (attrs) pkgs system python pythonSet;
					});
	in {
		devShells = importWithAttrs ./nix/dev-shells.nix;
		packages = importWithAttrs ./nix/packages.nix;
		checks = importWithAttrs ./nix/checks.nix;
		apps = importWithAttrs ./nix/apps.nix;
	};
}