Speed up assignments of achievements.

If you have payed attention (or tested openwebwork#2709 and openwebwork#2710), then you know
that this takes a long time if there are a large number of users.  Way
to long to be at all reasonable.

This uses techniques like those used for assigning multiple sets to
users, i.e., the `WeBWorK::DB::Schema::NewSQL::Std::insert_records` and
`WeBWorK::DB::Schema::NewSQL::Std::update_records` methods, to speed up
assignment of achievements to users.

This brings the assignment time for 5000 users down from more than 8
minutes, to less than 30 seconds.

Author: drgrice1

lib/WeBWorK/ContentGenerator/Instructor/AchievementList.pm

@@ -196,50 +196,48 @@ sub edit_handler ($c) {
 # Handler for assigning achievements to users
 sub assign_handler ($c) {
 	my $db             = $c->db;
-	my @users          = $db->listUsers;
 	my $overwrite      = $c->param('action.assign.overwrite') eq 'everything';
 	my $scope          = $c->param('action.assign.scope');
 	my @achievementIDs = $scope eq 'all' ? @{ $c->{allAchievementIDs} } : @{ $c->{selectedAchievementIDs} };
 
-	# Enable all achievements
-	my @achievements = $db->getAchievements(@achievementIDs);
+	my @users        = $db->listUsers;
+	my @achievements = $db->getAchievementsWhere({ achievement_id => \@achievementIDs });
 
-	for my $achievement (@achievements) {
-		$achievement->enabled(1);
-		$db->putAchievement($achievement);
-	}
-
-	# Assign globalUserAchievement data, overwriting if necc
+	# Enable all achievements.
+	for my $achievement (@achievements) { $achievement->enabled(1); }
+	$db->{achievement}->update_records(\@achievements) if @achievements;
 
+	# Assign globalUserAchievement data, overwriting if necessary.
+	my (@globalAchievementRecordsToAdd, @globalAchievementRecordsToPut);
+	my %existingGlobalUserAchievements =
+		map { $_->user_id => $_ } $db->getGlobalUserAchievementsWhere({ user_id => \@users });
 	for my $user (@users) {
-		if (not $db->existsGlobalUserAchievement($user)) {
-			my $globalUserAchievement = $db->newGlobalUserAchievement();
-			$globalUserAchievement->user_id($user);
-			$db->addGlobalUserAchievement($globalUserAchievement);
+		my $globalUserAchievement = $db->newGlobalUserAchievement(user_id => $user);
+		if (!$existingGlobalUserAchievements{$user}) {
+			push(@globalAchievementRecordsToAdd, $globalUserAchievement);
 		} elsif ($overwrite) {
-			my $globalUserAchievement = $db->newGlobalUserAchievement();
-			$globalUserAchievement->user_id($user);
-			$db->putGlobalUserAchievement($globalUserAchievement);
+			push(@globalAchievementRecordsToPut, $globalUserAchievement);
 		}
 	}
+	$db->{global_user_achievement}->insert_records(\@globalAchievementRecordsToAdd) if @globalAchievementRecordsToAdd;
+	$db->{global_user_achievement}->update_records(\@globalAchievementRecordsToPut) if @globalAchievementRecordsToPut;
 
-	# Assign userAchievement data, overwriting if necc
-
+	# Assign userAchievement data, overwriting if necessary.
+	my (@userAchievementRecordsToAdd, @userAchievementRecordsToPut);
 	for my $achievementID (@achievementIDs) {
+		my %existingUserAchievements =
+			map { $_->user_id => $_ } $db->getUserAchievementsWhere({ achievement_id => $achievementID });
 		for my $user (@users) {
-			if (not $db->existsUserAchievement($user, $achievementID)) {
-				my $userAchievement = $db->newUserAchievement();
-				$userAchievement->user_id($user);
-				$userAchievement->achievement_id($achievementID);
-				$db->addUserAchievement($userAchievement);
+			my $userAchievement = $db->newUserAchievement(user_id => $user, achievement_id => $achievementID);
+			if (!$existingUserAchievements{$user}) {
+				push(@userAchievementRecordsToAdd, $userAchievement);
 			} elsif ($overwrite) {
-				my $userAchievement = $db->newUserAchievement();
-				$userAchievement->user_id($user);
-				$userAchievement->achievement_id($achievementID);
-				$db->putUserAchievement($userAchievement);
+				push(@userAchievementRecordsToPut, $userAchievement);
 			}
 		}
 	}
+	$db->{achievement_user}->insert_records(\@userAchievementRecordsToAdd) if @userAchievementRecordsToAdd;
+	$db->{achievement_user}->update_records(\@userAchievementRecordsToPut) if @userAchievementRecordsToPut;
 
 	return (1, $c->maketext('Assigned achievements to users.'));
 }
@@ -462,7 +460,7 @@ sub import_handler ($c) {
 		$count++;
 		$allAchievementIDs{$achievement_id} = 1;
 
-		# Assign to usesrs if neccessary
+		# Assign to users if necessary.
 		if ($assign eq "all") {
 			for my $user (@users) {
 				if (not $db->existsGlobalUserAchievement($user)) {