bzmenu/flake.nix at main · e-tho/bzmenu · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{
  description = "Launcher-driven Bluetooth manager for Linux";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        overlays = [ (import rust-overlay) ];

        pkgs = import nixpkgs {
          inherit system overlays;
        };
      in
      {
        packages.default = pkgs.rustPlatform.buildRustPackage {
          pname = "bzmenu";
          version = self.shortRev or self.dirtyShortRev or "unknown";

          src = ./.;

          cargoLock = {
            lockFile = ./Cargo.lock;
          };

          nativeBuildInputs = with pkgs; [
            pkg-config
          ];

          buildInputs = with pkgs; [
            dbus.dev
          ];

          doCheck = true;
          CARGO_BUILD_INCREMENTAL = "false";
          RUST_BACKTRACE = "full";

          meta = {
            description = "Launcher-driven Bluetooth manager for Linux";
            homepage = "https://github.com/e-tho/bzmenu";
            license = pkgs.lib.licenses.gpl3Plus;
            maintainers = [
              {
                github = "e-tho";
              }
            ];
            mainProgram = "bzmenu";
          };
        };

        devShells.default =
          with pkgs;
          mkShell {
            nativeBuildInputs = [
              pkg-config
              (rust-bin.stable.latest.default.override {
                extensions = [ "rust-src" ];
              })
            ];

            buildInputs = [
              dbus.dev
            ];

            inherit (self.packages.${system}.default) CARGO_BUILD_INCREMENTAL RUST_BACKTRACE;
          };
      }
    );
}