CMakeLists.txt

# Copyright 2022 Proyectos y Sistemas de Mantenimiento SL (eProsima).
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

###############################################################################
# CMake build rules for DDS Router Submodule
###############################################################################
cmake_minimum_required(VERSION 3.5)

# Done this to set machine architecture and be able to call cmake_utils
enable_language(CXX)

###############################################################################
# Find package cmake_utils
###############################################################################
# Package cmake_utils is required to get every cmake macro needed
find_package(cmake_utils REQUIRED)

###############################################################################
# Project
###############################################################################
# Configure project by info set in project_settings.cmake
# - Load project_settings variables
# - Read version
# - Set installation paths
configure_project()

# Call explicitly project
project(
    ${MODULE_NAME}
    VERSION
        ${MODULE_VERSION}
    DESCRIPTION
        ${MODULE_DESCRIPTION}
    LANGUAGES
        CXX
)

###############################################################################
# C++ Project
###############################################################################
# Configure CPP project for dependencies and required flags:
# - Set CMake Build Type
# - Set C++ version
# - Set shared libraries by default
# - Find external packages and thirdparties
# - Activate Code coverage if flag CODE_COVERAGE
# - Activate Address sanitizer build if flag ASAN_BUILD
# - Activate Thread sanitizer build if flag TSAN_BUILD
# - Configure log depending on LOG_INFO flag and CMake type
configure_project_cpp()

# Compile C++ library
compile_library(
    "${PROJECT_SOURCE_DIR}/src/cpp" # Source directory
    "${PROJECT_SOURCE_DIR}/include" # Include directory
)

###############################################################################
# Test
###############################################################################
# Compile tests if CMake options requires it
compile_test_library(
    "${PROJECT_SOURCE_DIR}/test" # Test directory
)

###############################################################################
# Resources
###############################################################################
file(READ "${PROJECT_SOURCE_DIR}/../resources/configurations/ddsrouter_config_schema.json"
    DDSROUTER_CONFIG_SCHEMA_CONTENT)

# Split into <=16000-char chunks to work around MSVC C2026 string literal size limit.
# Adjacent string literals are concatenated by the compiler.
string(LENGTH "${DDSROUTER_CONFIG_SCHEMA_CONTENT}" _schema_len)
set(_chunk_size 16000)
set(DDSROUTER_CONFIG_SCHEMA_CHUNKS "")
set(_offset 0)
while(_offset LESS _schema_len)
    string(SUBSTRING "${DDSROUTER_CONFIG_SCHEMA_CONTENT}" ${_offset} ${_chunk_size} _chunk)
    string(APPEND DDSROUTER_CONFIG_SCHEMA_CHUNKS "    R\"json(${_chunk})json\"\n")
    math(EXPR _offset "${_offset} + ${_chunk_size}")
endwhile()

configure_file(
    "${PROJECT_SOURCE_DIR}/include/ddsrouter_yaml/DdsRouterConfigSchema.hpp.in"
    "${CMAKE_CURRENT_BINARY_DIR}/include/ddsrouter_yaml/DdsRouterConfigSchema.hpp"
    @ONLY
)

target_include_directories(${MODULE_NAME} PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
)

###############################################################################
# Packaging
###############################################################################
# Install package
eprosima_packaging()