Help me fix this "Redundant input, expecting EOF but found: {"

[meditto]

Hello everyone, I hope you're doing good. I'm new to DSLs and I'm trying to do something like this

Model User {
    id int
    name  string
}

My languim file looks like this

grammar TestLanguage
hidden(WS, SL_COMMENT, ML_COMMENT)

Model:
    'Model' name=MODEL_NAME '{'
        (columns+=Column)*
    '}';
 
Column:
    name=COLUMN_NAME (type=ID)? (identifiers=ID)?;

terminal WS: /\s+/;
terminal MODEL_NAME: /[A-Z][a-zA-Z]*/;
terminal COLUMN_NAME: /[a-zA-Z][a-zA-Z_]*/;
terminal ID: /[a-zA-Z][\w]*/;

terminal ML_COMMENT: /\/\*[\s\S]*?\*\//;
terminal SL_COMMENT: /\/\/[^\n\r]*/;

But I'm getting this error

[msujew]

Hi @meddjelaili, thank you for your question.

What version of Langium are you using? As far as I can tell, your grammar shouldn't even compile due to a bug in version 0.2.0 (#294).

Anyway there are a few issues in your grammar that result from the lexer as well as an ambiguity issue coming from your Column rule. The ID terminal can never be parsed, since its shadowed by the COLUMN_NAME and MODEL_NAME terminals, as they mostly match the same input. Additionally, when encountering something like Model NAME { id string }, the parser will never know whether the string is the type of the previous id column, or the name property of a new column, you will need a separator of some sorts for that.

Anyway, this is a fixed grammar for version 0.2.0 of Langium:

grammar TestLanguage
hidden(WS, SL_COMMENT, ML_COMMENT)

MainModel:
    'Model' name=ID '{'
        (columns+=Column (',' columns+=Column)*)?
    '}';
 
Column:
    name=ID (type=ID)? (identifiers=ID)?;

terminal WS: /\s+/;
terminal ID: /[a-zA-Z][\w]*/;

terminal ML_COMMENT: /\/\*[\s\S]*?\*\//;
terminal SL_COMMENT: /\/\/[^\n\r]*/;

It parses this input perfectly:

Model MAIN {
    id int,
    name string
}

If you want the MainModel ast object to always have a capitalized name, you shouldn't accomplish this using a terminal which only starts with capital letters (as this will lead to opaque parser errors), but rather an additional semantic validation, for which you can supply custom messages.

[meditto]

Hi, @msujew Thanks for the detailed answer, I can see the issue with my grammar now. I'm using version 0.2.0 and it seems to compile successfully. I tried the fixed grammar and yes it is working perfectly. Thank you again for the amazing work.