SemVerTools/build.gradle.kts at 74019f3574590c131810419a190ce5c935ebe0ad · eldoriarpg/SemVerTools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
import net.ltgt.gradle.errorprone.CheckSeverity
import net.ltgt.gradle.errorprone.errorprone

plugins {
    java
    `maven-publish`
    id("org.cadixdev.licenser") version "0.6.1"
    id("net.ltgt.errorprone") version "3.0.1"
    id("me.champeau.jmh") version "0.6.8"
    id("de.chojo.publishdata") version "1.4.0"
}

group = "de.eldoria"
version = "1.0.0-alpha"

repositories {
    mavenCentral()
}

dependencies {
    compileOnly("org.jetbrains", "annotations", "24.0.0")

    annotationProcessor("com.uber.nullaway", "nullaway", "0.10.9")
    errorprone("com.google.errorprone", "error_prone_core", "2.18.0")
    errorproneJavac("com.google.errorprone", "javac", "9+181-r4173-1")

    testImplementation("org.junit.jupiter", "junit-jupiter-api", "5.9.2")
    testImplementation("org.junit.jupiter", "junit-jupiter-params", "5.9.2")
    testRuntimeOnly("org.junit.jupiter", "junit-jupiter-engine", "5.9.2")
}

java {
    withSourcesJar()
    withJavadocJar()
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(11))
    }
}

tasks {
    test {
        useJUnitPlatform()
    }

    compileJava {
        options.encoding = "UTF-8"
        if (!name.toLowerCase().contains("test")
            && !name.toLowerCase().contains("jmh")
        ) {
            options.errorprone.apply {
                check("NullAway", CheckSeverity.ERROR)
                option("NullAway:AnnotatedPackages", "de.eldoria.semvertools")
            }
        }
    }

    compileTestJava{
        options.encoding = "UTF-8"
    }

    javadoc {
        (options as StandardJavadocDocletOptions).tags?.add("apiNote:a:API Note")
    }
}

license {
    header(project.file("HEADER.txt"))
}

publishData {
    useEldoNexusRepos()
    publishComponent("java")
}

publishing {
    publications.create<MavenPublication>("maven") {
        publishData.configurePublication(this)
    }

    repositories {
        maven {
            authentication {
                credentials(PasswordCredentials::class) {
                    username = System.getenv("NEXUS_USERNAME")
                    password = System.getenv("NEXUS_PASSWORD")
                }
            }

            name = "EldoNexus"
            url = uri(publishData.getRepository())
        }
    }
}