Fade out on shutdown

Author: lenemter

src/DBusInterfaces/LoginManager.vala

@@ -0,0 +1,13 @@
+/*
+ * SPDX-License-Identifier: GPL-3.0-or-later
+ * SPDX-FileCopyrightText: 2025 elementary, Inc. (https://elementary.io)
+ */
+
+[DBus (name = "org.freedesktop.login1.Manager")]
+public interface Gala.LoginManager : Object {
+    public signal void prepare_for_sleep (bool about_to_suspend);
+    public signal void prepare_for_shutdown (bool about_to_shutdown);
+
+    public abstract GLib.ObjectPath get_session (string session_id) throws GLib.Error;
+    public abstract UnixInputStream inhibit (string what, string who, string why, string mode) throws GLib.Error;
+}

src/ShutdownManager.vala

@@ -0,0 +1,52 @@
+/*
+ * SPDX-License-Identifier: GPL-3.0-or-later
+ * SPDX-FileCopyrightText: 2025 elementary, Inc. (https://elementary.io)
+ */
+
+public class Gala.ShutdownManager : Object {
+    public ScreenShield screen_shield { private get; construct; }
+
+    private LoginManager? login_manager;
+    private UnixInputStream? inhibitor;
+
+    public ShutdownManager (ScreenShield screen_shield) {
+        Object (screen_shield: screen_shield);
+    }
+
+    construct {
+        setup_dbus_interface.begin ();
+    }
+
+    private async void setup_dbus_interface () {
+        try {
+            login_manager = yield Bus.get_proxy (BusType.SYSTEM, "org.freedesktop.login1", "/org/freedesktop/login1");
+            inhibit_shutdown ();
+
+            login_manager.prepare_for_shutdown.connect ((about_to_shutdown) => {
+                if (!about_to_shutdown) {
+                    return;
+                }
+
+                screen_shield.activate (300, remove_inhibitor);
+            });
+        } catch (Error e) {
+            warning ("Couldn't get login manager: %s", e.message);
+        }
+    }
+
+    private void inhibit_shutdown () requires (login_manager != null && inhibitor == null) {
+        try {
+            inhibitor = login_manager.inhibit ("shutdown", "Pantheon", "Pantheon needs to play shutdown animation", "delay");
+        } catch (Error e) {
+            warning ("Couldn't inhibit shutdown, no shutdown animation will be player: %s", e.message);
+        }
+    }
+
+    private void remove_inhibitor () requires (inhibitor != null) {
+        try {
+            inhibitor.close ();
+        } catch (Error e) {
+            warning ("Couldn't remove shutdown inhibitor: %s", e.message);
+        }
+    }
+}

src/WindowManager.vala

@@ -72,6 +72,8 @@ namespace Gala {
 
         public ScreenSaverManager? screensaver { get; private set; }
 
+        public ShutdownManager shutdown_manager { get; private set; }
+
         private HotCornerManager? hot_corner_manager = null;
 
         public WindowTracker? window_tracker { get; private set; }
@@ -285,6 +287,8 @@ namespace Gala {
             // is set to NONE when we are in locked mode
             screensaver.active_changed.connect (update_input_area);
 
+            shutdown_manager = new ShutdownManager (screen_shield);
+
             FilterManager.init (this);
 
             /*keybindings*/

src/meson.build

@@ -14,6 +14,7 @@ gala_bin_sources = files(
     'ScreenshotManager.vala',
     'SessionLocker.vala',
     'SessionManager.vala',
+    'ShutdownManager.vala',
     'SuperScrollAction.vala',
     'WindowAttentionTracker.vala',
     'WindowListener.vala',
@@ -33,6 +34,7 @@ gala_bin_sources = files(
     'ColorFilters/ColorblindnessCorrectionEffect.vala',
     'ColorFilters/FilterManager.vala',
     'ColorFilters/MonochromeEffect.vala',
+    'DBusInterfaces/LoginManager.vala',
     'Dialogs/AccessDialog.vala',
     'Dialogs/CloseDialog.vala',
     'Dialogs/InhibitShortcutsDialog.vala',