Send DND info to windows that requested visible in MultitaskingView

Author: leolost2605

lib/DragDropAction.vala

@@ -55,6 +55,15 @@ namespace Gala {
          */
         public signal void destination_crossed (Clutter.Actor destination, bool hovered);
 
+        /**
+         * Emitted on the source when we are hovering over a destination.
+         *
+         * @param destination The destination actor that we are hovering over
+         * @param x           The x coordinate relative to the destination actor
+         * @param y           The y coordinate relative to the destination actor
+         */
+        public signal void destination_motion (Clutter.Actor destination, float x, float y);
+
         /**
          * The source has been clicked, but the movement was not larger than
          * the drag threshold. Useful if the source is also activatable.
@@ -341,7 +350,7 @@ namespace Gala {
                         last_y = y;
 
                         var stage = actor.get_stage ();
-                        var actor = stage.get_actor_at_pos (Clutter.PickMode.REACTIVE, (int) x, (int) y);
+                        var actor = stage.get_actor_at_pos (NONE, (int) x, (int) y);
                         DragDropAction action = null;
                         // if we're allowed to bubble and this actor is not a destination, check its parents
                         if (actor != null && (action = get_drag_drop_action (actor)) == null && allow_bubbling) {
@@ -352,8 +361,12 @@ namespace Gala {
                         }
 
                         // didn't change, no need to do anything
-                        if (actor == hovered)
+                        if (actor == hovered) {
+                            if (hovered != null) {
+                                destination_motion (hovered, x - hovered.x, y - hovered.y);
+                            }
                             return Clutter.EVENT_STOP;
+                        }
 
                         if (action == null) {
                             // apparently we left ours if we had one before
@@ -436,12 +449,12 @@ namespace Gala {
         }
 
         private void finish () {
+            drag_end (hovered);
+
             // make sure they reset the style or whatever they changed when hovered
             emit_crossed (hovered, false);
 
             cleanup ();
-
-            drag_end (hovered);
         }
 
         private void cleanup () {

src/DBus.vala

@@ -14,6 +14,19 @@ public class Gala.DBus {
     public static void init (WindowManagerGala _wm, NotificationsManager notifications_manager, ScreenshotManager screenshot_manager) {
         wm = _wm;
 
+        Bus.own_name (
+            SESSION, "io.elementary.gala", NONE,
+            (connection) => {
+                try {
+                    connection.register_object ("/io/elementary/gala", WindowDragProvider.get_instance ());
+                } catch (Error e) {
+                    warning (e.message);
+                }
+            },
+            () => {},
+            () => critical ("Could not acquire name")
+        );
+
         Bus.own_name (BusType.SESSION, "org.pantheon.gala", BusNameOwnerFlags.NONE,
             (connection) => {
                 if (instance == null)

src/ShellClients/PanelWindow.vala

@@ -61,6 +61,11 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
         hide_tracker.show.connect (show);
     }
 
+    public void request_visible_in_multitasking_view () {
+        visible_in_multitasking_view = true;
+        actor.add_action (new DragDropAction (DESTINATION, "multitaskingview-window"));
+    }
+
     private void hide () {
         gesture_controller.goto (1);
     }

src/ShellClients/ShellClientsManager.vala

@@ -191,7 +191,7 @@ public class Gala.ShellClientsManager : Object, GestureTarget {
             return;
         }
 
-        panel_windows[window].visible_in_multitasking_view = true;
+        panel_windows[window].request_visible_in_multitasking_view ();
     }
 
     public void make_centered (Meta.Window window) requires (!is_itself_positioned (window)) {

src/Widgets/MultitaskingView/WindowClone.vala

@@ -117,6 +117,8 @@ public class Gala.WindowClone : ActorTarget, RootTarget {
         } else {
             drag_action = new DragDropAction (DragDropActionType.SOURCE, "multitaskingview-window");
             drag_action.drag_begin.connect (drag_begin);
+            drag_action.destination_crossed.connect (destination_crossed);
+            drag_action.destination_motion.connect (destination_motion);
             drag_action.drag_end.connect (drag_end);
             drag_action.drag_canceled.connect (drag_canceled);
             drag_action.actor_clicked.connect (actor_clicked);
@@ -511,6 +513,22 @@ public class Gala.WindowClone : ActorTarget, RootTarget {
         return this;
     }
 
+    private void destination_crossed (Clutter.Actor destination, bool hovered) {
+        if (!(destination is Meta.WindowActor)) {
+            return;
+        }
+
+        if (hovered) {
+            WindowDragProvider.get_instance ().notify_enter (window.get_id ());
+        } else {
+            WindowDragProvider.get_instance ().notify_leave ();
+        }
+    }
+
+    private void destination_motion (Clutter.Actor destination, float x, float y) {
+        WindowDragProvider.get_instance ().notify_motion (x, y);
+    }
+
     /**
      * Depending on the destination we have different ways to find the correct destination.
      * After we found one we destroy ourselves so the dragged clone immediately disappears,
@@ -538,6 +556,8 @@ public class Gala.WindowClone : ActorTarget, RootTarget {
             }
 
             return;
+        } else if (destination is Meta.WindowActor) {
+            WindowDragProvider.get_instance ().notify_dropped ();
         }
 
         bool did_move = false;

src/WindowDragProvider.vala

@@ -0,0 +1,35 @@
+/*
+ * Copyright 2025 elementary, Inc. (https://elementary.io)
+ * SPDX-License-Identifier: GPL-3.0-or-later
+ *
+ * Authored by: Leonhard Kargl <[email protected]>
+ */
+
+[DBus (name = "io.elementary.desktop.wm.WindowDragProvider")]
+public class Gala.WindowDragProvider : Object {
+    private static GLib.Once<WindowDragProvider> instance;
+    public static WindowDragProvider get_instance () {
+        return instance.once (() => { return new WindowDragProvider (); });
+    }
+
+    public signal void enter (uint64 window_id);
+    public signal void motion (int x, int y);
+    public signal void leave ();
+    public signal void dropped ();
+
+    internal void notify_enter (uint64 window_id) {
+        enter (window_id);
+    }
+
+    internal void notify_motion (float x, float y) {
+        motion ((int) x, (int) y);
+    }
+
+    internal void notify_leave () {
+        leave ();
+    }
+
+    internal void notify_dropped () {
+        dropped ();
+    }
+}

src/meson.build

@@ -16,6 +16,7 @@ gala_bin_sources = files(
     'SessionManager.vala',
     'SuperScrollAction.vala',
     'WindowAttentionTracker.vala',
+    'WindowDragProvider.vala',
     'WindowListener.vala',
     'WindowManager.vala',
     'WindowStateSaver.vala',