PositionedWindow: Introduce an abstract method for position calculation

Instead of an enum based on which the position is calculated,
introduce an abstract method that should be overridden by subclasses
for position calculation.
This introduces more flexibility in the future while reducing code
complexity.

Author: leolost2605

src/ShellClients/ExtendedBehaviorWindow.vala

@@ -8,6 +8,13 @@
 public class Gala.ExtendedBehaviorWindow : ShellWindow {
     public ExtendedBehaviorWindow (Meta.Window window) {
         var target = new PropertyTarget (CUSTOM, window.get_compositor_private (), "opacity", typeof (uint), 255u, 0u);
-        Object (window: window, position: Position.CENTER, hide_target: target);
+        Object (window: window, hide_target: target);
+    }
+
+    protected override void get_window_position (
+        Mtk.Rectangle window_rect, Mtk.Rectangle monitor_rect, out int x, out int y
+    ) {
+        x = monitor_rect.x + (monitor_rect.width - window_rect.width) / 2;
+        y = monitor_rect.y + (monitor_rect.height - window_rect.height) / 2;
     }
 }

src/ShellClients/PanelWindow.vala

@@ -36,7 +36,7 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
     private int height = -1;
 
     public PanelWindow (WindowManager wm, Meta.Window window, Pantheon.Desktop.Anchor anchor) {
-        Object (wm: wm, anchor: anchor, window: window, position: Position.from_anchor (anchor));
+        Object (wm: wm, window: window, anchor: anchor);
     }
 
     construct {
@@ -46,8 +46,6 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
             }
         });
 
-        notify["anchor"].connect (() => position = Position.from_anchor (anchor));
-
         unowned var workspace_manager = window.display.get_workspace_manager ();
         workspace_manager.workspace_added.connect (update_strut);
         workspace_manager.workspace_removed.connect (update_strut);
@@ -65,15 +63,15 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
         hide_tracker.show.connect (show);
 
         window.size_changed.connect (update_target);
-        notify["position"].connect (update_target);
+        notify["anchor"].connect (update_target);
         update_target ();
 
         var window_actor = (Meta.WindowActor) window.get_compositor_private ();
 
         window_actor.notify["width"].connect (update_clip);
         window_actor.notify["height"].connect (update_clip);
         window_actor.notify["translation-y"].connect (update_clip);
-        notify["position"].connect (update_clip);
+        notify["anchor"].connect (update_clip);
     }
 
     public Mtk.Rectangle get_custom_window_rect () {
@@ -86,7 +84,7 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
         if (height > 0) {
             window_rect.height = height;
 
-            if (position == BOTTOM) {
+            if (anchor == BOTTOM) {
                 var geom = window.display.get_monitor_geometry (window.get_monitor ());
                 window_rect.y = geom.y + geom.height - height;
             }
@@ -177,6 +175,28 @@ public class Gala.PanelWindow : ShellWindow, RootTarget {
         }
     }
 
+    protected override void get_window_position (
+        Mtk.Rectangle window_rect, Mtk.Rectangle monitor_rect, out int x, out int y
+    ) {
+        switch (anchor) {
+            case TOP:
+                x = monitor_rect.x + (monitor_rect.width - window_rect.width) / 2;
+                y = monitor_rect.y;
+                break;
+
+            case BOTTOM:
+                x = monitor_rect.x + (monitor_rect.width - window_rect.width) / 2;
+                y = monitor_rect.y + monitor_rect.height - window_rect.height;
+                break;
+
+            default:
+                warning ("Unsupported anchor %s for PanelWindow", anchor.to_string ());
+                x = 0;
+                y = 0;
+                break;
+        }
+    }
+
     private void update_target () {
         var to_value = anchor == TOP ? -get_custom_window_rect ().height : get_custom_window_rect ().height;
         hide_target = new PropertyTarget (CUSTOM, actor, "translation-y", typeof (float), 0f, (float) to_value);

src/ShellClients/PositionedWindow.vala

@@ -6,35 +6,10 @@
  */
 
 public class Gala.PositionedWindow : Object {
-    public enum Position {
-        TOP,
-        BOTTOM,
-        CENTER;
-
-        public static Position from_anchor (Pantheon.Desktop.Anchor anchor) {
-            if (anchor > 1) {
-                warning ("Position %s not supported yet", anchor.to_string ());
-                return CENTER;
-            }
-
-            return (Position) anchor;
-        }
-    }
-
     public Meta.Window window { get; construct; }
-    /**
-     * This may only be set after the window was shown.
-     * The initial position should only be given in the constructor.
-     */
-    public Position position { get; construct set; }
-    public Variant? position_data { get; construct set; }
 
     private ulong position_changed_id;
 
-    public PositionedWindow (Meta.Window window, Position position, Variant? position_data = null) {
-        Object (window: window, position: position, position_data: position_data);
-    }
-
     construct {
         window.stick ();
 
@@ -45,38 +20,24 @@ public class Gala.PositionedWindow : Object {
         unowned var monitor_manager = window.display.get_context ().get_backend ().get_monitor_manager ();
         monitor_manager.monitors_changed.connect (position_window);
         monitor_manager.monitors_changed_internal.connect (position_window);
-
-        notify["position"].connect (position_window);
-        notify["position-data"].connect (position_window);
     }
 
     private void position_window () {
-        int x = 0, y = 0;
         var window_rect = window.get_frame_rect ();
-        unowned var display = window.display;
-
-        switch (position) {
-            case CENTER:
-                var monitor_geom = display.get_monitor_geometry (display.get_primary_monitor ());
-                x = monitor_geom.x + (monitor_geom.width - window_rect.width) / 2;
-                y = monitor_geom.y + (monitor_geom.height - window_rect.height) / 2;
-                break;
-
-            case TOP:
-                var monitor_geom = display.get_monitor_geometry (display.get_primary_monitor ());
-                x = monitor_geom.x + (monitor_geom.width - window_rect.width) / 2;
-                y = monitor_geom.y;
-                break;
+        var monitor_rect = window.display.get_monitor_geometry (window.display.get_primary_monitor ());
 
-            case BOTTOM:
-                var monitor_geom = display.get_monitor_geometry (display.get_primary_monitor ());
-                x = monitor_geom.x + (monitor_geom.width - window_rect.width) / 2;
-                y = monitor_geom.y + monitor_geom.height - window_rect.height;
-                break;
-        }
+        int x = 0, y = 0;
+        get_window_position (window_rect, monitor_rect, out x, out y);
 
         SignalHandler.block (window, position_changed_id);
         window.move_frame (false, x, y);
         SignalHandler.unblock (window, position_changed_id);
     }
+
+    protected virtual void get_window_position (
+        Mtk.Rectangle window_rect, Mtk.Rectangle monitor_rect, out int x, out int y
+    ) {
+        x = 0;
+        y = 0;
+    }
 }

src/ShellClients/ShellWindow.vala

@@ -17,10 +17,6 @@ public class Gala.ShellWindow : PositionedWindow, GestureTarget {
     private double multitasking_view_progress = 0;
     private int animations_ongoing = 0;
 
-    public ShellWindow (Meta.Window window, Position position, Variant? position_data = null) {
-        base (window, position, position_data);
-    }
-
     public void propagate (UpdateType update_type, GestureAction action, double progress) {
         switch (update_type) {
             case START: